如何为 sas 数据步骤中的每个观察执行一个宏？

Question

假设我允许用户使用通用用户界面编写自己的变量计算宏：

%macro calculate(var_name, var_value);
%* Some user-defined calculation;
%mend calculate;

然后在数据步骤中，我可以使用用户定义的宏计算一个新变量：

data dataset;
    set dataset;
    new_var = %calculate('variable1', variable1); * This doesn't work. It just shows my indication.
run;

其中 variable1 是数据集中的变量。 在这里，我想传入变量名和变量的实际值。 计算完成后，将值放入new_var。

我怎样才能做到这一点？

Answer 1

是否需要使用宏来实现这一点？ 这听起来像是PROC FCMP最有用的情况，因为它允许您定义可以在数据步骤中使用的自己的函数或子例程（fcmp="function compiler"），就像内置的 function 一样。

这是一个简单的例子：

proc fcmp outlib=sasuser.funcs.math;
  function calc(var);
     newvar=log(var); /*user defined stuff here - can be simple or complex*/
     return(newvar);
  endsub;
run;

option cmplib=sasuser.funcs; /*tell SAS where to look for functions*/
data _null_;
  set sashelp.class;
  newvar=calc(height); /*call your new function */
  put newvar=;
run;

Answer 2

您可以完成这项工作，但您可能错误地编写了宏。 您必须记住，SAS 宏本质上是文本预处理器：它们输入您编写的代码和 output 代码以提供给 SAS [1]。

所以这是一个简单的“加法”宏：

%macro calculate (var_name, var_value);
  &var_name + &var_value;
%mend;

data one;
  input a@@;
  b = %calculate(a, 3);
  c = %calculate(a, a);
cards;
1 3 -2 4
;
run;

proc print data=one;
run;

宏工具将用宏生成的代码替换%calculate位，SAS 实际上会看到以下内容：

%macro calculate (var_name, var_value);
  &var_name + &var_value;
%mend;

data one;
  input a@@;
  b = a + 3;
  c = a + a;
cards;
1 3 -2 4
;
run;

proc print data=one;
run;

您可以使用options mprint语句在日志文件中自己查看它

不幸的是，这不会涵盖所有可能的计算。 您可能需要查找PROC FCMP以获取生成可在 DATA 步骤中使用的自定义函数/子例程的方法。

[1] 我知道它比这更复杂，但你可以这样想。

Answer 3

我知道这是一篇较旧的帖子，但我认为值得一提。

这是一个允许使用宏例程的解决方案，就像我们使用 function 一样。 这是在 SAS resolve() function 的帮助下完成的。 “%then”后面的任何内容（在本例中是文本，但可以是数字）对应于我们将放入“真实函数”的 return() 部分的内容。

%macro compare(v1, v2);
  %if &v1 > &v2 %then v1 is greater than v2;
  %else v2 is greater than v1;
%mend;

data check (drop = macroCall);
  input v1 v2;
  macroCall = cats('%compare(', v1, ',', v2, ')');
  result = resolve(macrocall);
  datalines;
1 2
2 1
;

结果：

v1  v2  result
1   2   v2 is greater than v1
2   1   v1 is greater than v2

Answer 4

这是一个常见的混淆点。 问题是 SAS 在任何常规代码之前处理程序中的所有宏代码。 所以当它调用%calculate('variable1', variable1); ，它还不能访问数据集中的数据。

就是说，如果我有一个示例说明%*Some user-defined calculation; .