haskell中的forM和forM_有什么区别？

Question

HLint 建议我使用forM_而不是forM 。 为什么？ 我看到他们有不同的类型签名，但还没有找到一个很好的理由来使用另一个。

forM  :: (Traversable t, Monad m) => t a -> (a -> m b) -> m (t b)
forM_ :: (Foldable t,    Monad m) => t a -> (a -> m b) -> m ()

Answer 1

forM_效率更高，因为它不保存操作的结果。 就这些。 （这仅在使用 monad 时才有意义，因为a -> ()类型的纯 function 并不是特别有用。）

Answer 2

好的，

forM is mapM with its arguments flipped.

forM_ is mapM_ with its arguments flipped.

让我们看看mapM和mapM_：

mapM :: Monad m => (a -> m b) -> [a] -> m [b]

mapM mf xs采用单子 function mf （具有Monad m => (a -> mb)类型）并将其应用于列表xs中的每个元素； 结果是一个单子内的列表。 mapM和mapM_之间的区别在于， mapM返回结果列表，而mapM_返回空结果。 mapM_中每个动作的结果不会被存储。

Answer 3

要了解(A) : forM xs f和(B) : forM_ xs f之间的区别，比较以下之间的区别可能会有所帮助：

-- Equivalent to (A)
do
  r1 <- f x1
  r2 <- f x2
  ...
  rn <- f xn
  return [r1, r2, ..., rn]

-- Equivalent to (B)
do
  _ <- f x1
  _ <- f x2
  ...
  _ <- f xn
  return ()

关键的区别在于forM_忽略了结果r1 , ... rn并且只通过return ()返回一个空结果。 将下划线视为“不关心”的意思...... forM_不关心结果。 然而， forM确实关心结果并通过return [r1, r2, ... rn]将它们作为列表返回。

---

示例 1下面的代码会询问您的姓名 3 次，并打印出表单的结果。

import Control.Monad (forM, forM_)

main = do
  let askName i = do
      putStrLn $ "What's your name (" ++ (show i) ++ ")"
      name <- getLine
      return name
  results <- forM [1,2,3] askName
  putStrLn $ "Results = " ++ show results

使用forM的示例执行：

What's your name? (1)
> James
What's your name? (2)
> Susan
What's your name? (3)
> Alex
Results = ["James", "Susan", "Alex"]

但是，如果我们将forM更改为forM_ ，那么我们将改为：

What's your name? (1)
> James
What's your name? (2)
> Susan
What's your name? (3)
> Alex
Results = ()

---

在你的情况下，linter 告诉你你没有使用你的forM的返回值（你没有foo <- forM xs f ，你可能在一行上有自己的forM xs f ），所以应该使用forM_ 。 例如，当您使用像putStrLn这样的一元操作时，就会发生这种情况。

---

示例 2下面的代码询问您的姓名，然后说“你好”——重复三遍。

import Control.Monad (forM, forM_)

main = do
  let askThenGreet i = do
      putStrLn $ "What's your name (" ++ (show i) ++ ")"
      name <- getLine
      putStrLn $ "Hello! " ++ name
  forM [1,2,3] askThenGreet

使用forM的示例执行：

 What's your name? (1)
> Sarah
Hello! Sarah

What's your name? (2)
> Dick
Hello! Dick

What's your name? (3)
> Peter
Hello! Peter

[(), (), ()]

main的整体结果来自于 formM: [(), (), ()]的结果。 它非常无用且令人讨厌，它出现在控制台中。 但是，如果我们将forM更改为forM_ ，那么我们将改为：

What's your name? (1)
> Sarah
Hello! Sarah

What's your name? (2)
> Dick
Hello! Dick

What's your name? (3)
> Peter
Hello! Peter

随着这种变化，整体结果来自mapM_并且现在是() 。 这不会出现在控制台中（IO monad 的一个怪癖），太棒了！ 此外，通过在此处使用mapM_ ，您的代码的其他读者会更清楚 - 您间接解释/自我记录您不关心结果[r1, ..., rn] = [(), (), ()] – 正确，因为它们在这里没用。