是否可以使用字符串数据类型结构写入/读取文件？

Question

在文件中写一些东西，我使用例如以下代码：

procedure MyProc (... );
const
  BufSize = 65535;
var
  FileSrc, FileDst: TFileStream;
  StreamRead: Cardinal;
  InBuf, OutBuf: Array [0..bufsize] of byte;
begin
  .....
  FileSrc := TFileStream.Create (uFileSrc, fmOpenRead Or fmShareDenyWrite);
  try
    FileDst := TFileStream.Create (uFileTmp, fmCreate);
    try
      StreamRead := 0;
      while ((iCounter < iFileSize) or (StreamRead = Cardinal(BufSize))) 
      begin
        StreamRead := FileSrc.Read (InBuf, BufSize);
        Inc (iCounter, StreamRead);
      end;
    finally
      FileDst.Free;
    end;
  finally
    FileSrc.Free;
  end;
end;

对于I / O文件，我使用字节数组，因此也可以，但是当我使用字符串时，例如声明：

InBuf, OutBuf: string  // in delphi xe2 = unicode string

那不行 从某种意义上说，文件什么都不写。 我已经了解了原因，或者只是想了解了。 我认为问题可能在于为什么字符串只包含指向内存的指针，而不包含静态结构。 正确？ 在这种情况下，有一些解决方案可以解决吗？ 从某种意义上说，是否有可能为我做一些事情，使我可以使用字符串而不是向量来写文件？ 还是我需要使用向量？ 如果可能的话，我可以做吗？ 非常感谢。

Answer 1

使用字符串有两个问题。 首先，您要使用RawByteString ，以确保使用字节大小的字符元素– Unicode字符串的元素宽度为两个字节。 其次，您需要取消引用实际上只是指针的字符串。

但是我不知道为什么您会更喜欢字符串而不是堆栈分配的字节数组。

procedure MyProc (... );
const
  BufSize = 65536;
var
  FileSrc, FileDst: TFileStream;
  StreamRead: Cardinal;
  InBuf: RawByteString;
begin
  .....
  FileSrc := TFileStream.Create (uFileSrc, fmOpenRead Or fmShareDenyWrite);
  try
    FileDst := TFileStream.Create (uFileTmp, fmCreate);
    try
      SetLength(InBuf, BufSize);
      StreamRead := 0;
      while ((iCounter < iFileSize) or (StreamRead = Cardinal(BufSize))) 
      begin
        StreamRead := FileSrc.Read (InBuf[1], BufSize);
        Inc (iCounter, StreamRead);
      end;
    finally
      FileDst.Free;
    end;
  finally
    FileSrc.Free;
  end;
end;

注意：您先前的代码声明了65536个字节的缓冲区，但是您只使用了65535个字节。 可能不是您的意图。

Answer 2

要将字符串用作缓冲区（我不建议这样做），您必须使用SetLength来分配内部缓冲区，并且必须将InBuf [1]和OutBuf [1]作为数据读取或读取。写。

  var
    InBuf, OutBuf: AnsiString; // or TBytes
  begin
    SetLength(InBuf, BufSize);
    SetLength(OutBuf, BufSize);

    ...

    StreamRead := FileSrc.Read(InBuf[1], BufSize); // if TBytes, use InBuf[0]

    // etc...

您也可以使用TBytes代替AnsiString。 用法保持不变。

但是我实际上看不到在这里动态分配TBytes，AnsiStrings或RawByteStrings的优势 。 我宁愿做您已经做的事情：使用基于堆栈的缓冲区。 我可能会在多线程环境中将其缩小一些。

Answer 3

是的，您可以将字符串保存/从流中加载字符串，请参见以下示例

var Len: Integer;
    buf: string;
    FData: TStream;

// save string to stream
// save the length of the string
Len := Length(buf);
FData.Write(Len, SizeOf(Len));
// save string itself
if(Len > 0)then FData.Write(buf[1], Len * sizeof(buf[1]));

// read string from stream
// read the length of the string
FData.Read(Len, SizeOf(Len));
if(Len > 0)then begin
   // get memory for the string
   SetLength(buf, Len);
   // read string content
   FData.Read(buf[1], Len * sizeof(buf[1]));
end else buf := '';

Answer 4

与此相关的是，要将内容从一个TStream复制到另一个TStream ，可以只使用TStream.CopyFrom()方法：

procedure MyProc (... );
var
  FileSrc, FileDst: TFileStream;
begin
  ...
  FileSrc := TFileStream.Create (uFileSrc, fmOpenRead Or fmShareDenyWrite);
  try
    FileDst := TFileStream.Create (uFileTmp, fmCreate);
    try
      FileDst.CopyFrom(FileSrc, 0); // or FileDst.CopyFrom(FileSrc, iFileSize)
    finally
      FileDst.Free;
    end;
  finally
    FileSrc.Free;
  end;
  ...
end; 

可以通过调用CopyFile（）来简化：

procedure MyProc (... );
begin
  ...
  CopyFile(PChar(uFileSrc), PChar(uFileTmp), False);
  ...
end; 

无论哪种方式，您都不必担心手动读取/写入文件数据！