寻求目标，在Mathematica中

Question

为了进行实验，我们在Matlab中生成了由8个磁盘组成的一些映像。 我们限制了磁盘之间以及磁盘与框架之间的最小距离，以及磁盘重心（COG）的位置。 下面是举升机“第三”上的COG组成示例

FraXYs = {{4.32, 3.23}, {35.68, 26.75}}

stiDisks = {{{8, 11}, 1}, {{10, 17}, 1}, {{16, 24}, 1}, {{25, 22},1}, 
           {{31, 22}, 1}, {{7, 21}, 2}, {{16, 12}, 2}, {{19, 22}, 2}}

Graphics[{White, EdgeForm[Thick],
  Rectangle @@ FraXYs,
  Red, Disk[{14.77, 18.91}, 1],
  Blue, Opacity[.6], EdgeForm[Black],
  Blue, Thickness[0.003],
  Opacity[1],
  Black,
  Disk[#[[1]], #[[2]]] & /@ stiDisks}, ImageSize -> {400, 300}]

我想在Mathematica中产生这些刺激。 以下是我要处理的元素（功能和约束）。 度量单位为厘米。 形状的重心（COG）定义为圆盘的有效位置。

特点 ：

刺激框架： {{xMin，xMin}，{xMax，yMax}}

FraXYs = {{4.32, 3.23}, {35.68, 26.75}}

5小盘：带半径

rSmall=1

3个大磁盘：带半径

rLarge=2

约束：

形状边缘之间的最小距离：

minDistSha=1

形状边缘和框架边框之间的最小距离：

minDistFra=1

形状COG到中心的距离：

minDistCogCenter=2

潜在地，我将需要将磁盘的COG约束为与中心成一定角度（极坐标系中的θ坐标？）。 所以我可以选择将磁盘的COG约束在极坐标中每22.5度定位的磁盘坐标

angleBin=22.5

除了Selct之外，Mathematica中是否有有用的功能来实现选择。

我很想知道是否有可能使用闭合公式生成具有特定COG位置的1个成分。

指示性地，我将需要获得1000个作品的集合。 使用36度的“θ约束”，我应该提取10 * 100的成分，并将其COG定位在距中心最小或固定距离的10个不同的θ棒上。

请告诉我是否需要澄清。 感谢您的关注。

Answer 1

这可能会让您入门。 这是一种简单的拒绝方法，可以随机生成圆，丢弃不符合要求的合奏。

参数是盒子的大小，小圆和大圆的数量和半径以及最小间距。 最后一个用于边界的距离和圆之间的距离。 我将它的重心加倍到框架约束的中心。 显然，可以通过添加更多参数来推广这种用法。

为了评估找到可行合奏的可能性，我打印了循环中的次数。 另外，我使用了真正不需要的捕获/抛出机制（某些实验的伪像，我没有去掉它）。

-编辑-

下面的代码与我最初发布的内容相比有少许变化。 它将重心圆分隔为红色的圆。

要处理它处于某个特定角度的约束，可能会如下生成，旋转以放置到正确的角度位置，然后重新检查从圆到框边界的距离。 可能有一些更聪明的东西，即使保持一致性，也不太可能拒绝。 实际上，我完全不确定我编写的代码是否可以在允许配置的空间内进行均匀分配。 如果确实如此，旋转的影响很可能会破坏该属性。

---结束编辑---

randomConfiguration[{xlo_, ylo_}, {xhi_, yhi_}, nsmall_, nlarge_, 
  rsmall_, rlarge_, minsep_] := Catch[Module[
   {found = False, xsmall, ysmall, xlarge, ylarge, smallsep, largesep,
     smallcircs, largecircs, cog, cen, indx = 0},
   smallsep = {rsmall + minsep, -rsmall - minsep};
   largesep = {rlarge + minsep, -rlarge - minsep};
   cen = {xhi - xlo, yhi - ylo};
   While[! found,
    found = True;
    indx++;
    xsmall = RandomReal[{xlo, xhi} + smallsep, nsmall];
    ysmall = RandomReal[{ylo, yhi} + smallsep, nsmall];
    xlarge = RandomReal[{xlo, xhi} + largesep, nlarge];
    ylarge = RandomReal[{ylo, yhi} + largesep, nlarge];
    smallcircs = Transpose[{xsmall, ysmall}];
    Do[If[
      Norm[smallcircs[[i]] - smallcircs[[j]]] <= 2*rsmall + minsep, 
      found = False; Break[]], {i, nsmall - 1}, {j, i + 1, nsmall}];
    largecircs = Transpose[{xlarge, ylarge}];
    Do[If[
      Norm[largecircs[[i]] - largecircs[[j]]] <= 2*rlarge + minsep, 
      found = False; Break[]], {i, nlarge - 1}, {j, i + 1, nlarge}];
    Do[If[
      Norm[smallcircs[[i]] - largecircs[[j]]] <= 
       rsmall + rlarge + minsep, found = False; Break[]], {i, 
      nsmall}, {j, nlarge}];
    cog = (rsmall^2*Total[smallcircs] + 
        rlarge^2*Total[largecircs])/(nsmall*rsmall^2 + 
        nlarge*rlarge^2);
    If[Norm[cog - cen] <= 2*minsep, found = False;];
    ];
   Print[indx];
   Throw[{{cog, rsmall},Map[{#, rsmall} &, smallcircs], 
     Map[{#, rlarge} &, largecircs]}]
   ]]

例：

{smallc, largec} = 
  randomConfiguration[{4.32, 3.23}, {35.68, 26.75}, 5, 3, 1, 2, 1];

13

FraXYs = {{4.32, 3.23}, {35.68, 26.75}};

{cog, smallc, largec} = 
  randomConfiguration[{4.32, 3.23}, {35.68, 26.75}, 5, 3, 1, 2, 1];

Graphics[{White, EdgeForm[Thick], Rectangle @@ FraXYs, Red, 
  Apply[Disk, cog], Blue, Opacity[.6], EdgeForm[Black], Blue, 
  Thickness[0.003], Opacity[1], Black, 
  Disk[#[[1]], #[[2]]] & /@ Join[smallc, largec]}, 
 ImageSize -> {400, 300}]