如何使用 Windows 命令提示符删除空文件夹？

Question

我需要使用 Windows 命令提示符从我的应用程序文件夹中删除所有空文件夹？

我怎样才能创建一个这样的bat文件？

请帮我。

Answer 1

您可以使用ROBOCOPY命令。 它非常简单，也可用于删除大型层次结构中的空文件夹。

ROBOCOPY folder1 folder1 /S /MOVE

这里源和目标都是folder1 ，因为您只需要删除空文件夹，而不是将其他（必需）文件移动到不同的文件夹。 /S选项是跳过复制（在上述情况下移动）空文件夹。 由于文件在同一个驱动器内移动，它也更快。

Answer 2

更简单的方法是执行 xcopy 以使用 /s 开关制作整个目录结构的副本。 /s 的帮助说复制目录和子目录，除了空目录。

xcopy dirA dirB /S

其中 dirA 是带有空文件夹的源。 DirB 将是没有空文件夹的副本

Answer 3

for /f "usebackq" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"

来自：http: //blogs.msdn.com/b/oldnewthing/archive/2008/04/17/8399914.aspx

当然，在执行该命令之前，我会先对其进行测试而不删除。 此外，这是来自评论的修改版本，其中包括带空格的文件夹：

 for /f "usebackq delims=" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"

PS 博客文章中有更多评论可能会对您有所帮助，因此请务必在尝试之前阅读这些评论

Answer 4

你不需要 usebackq：

FOR /F delims^= %%A IN ('DIR/AD/B/S^|SORT/R') DO RD "%%A"

Answer 5

从同一引用页面添加到腐蚀的答案是 PowerShell 版本http://blogs.msdn.com/b/oldnewthing/archive/2008/04/17/8399914.aspx#8408736

Get-ChildItem -Recurse . | where { $_.PSISContainer -and @( $_ | Get-ChildItem ).Count -eq 0 } | Remove-Item

或者，更简洁地说，

gci -R . | where { $_.PSISContainer -and @( $_ | gci ).Count -eq 0 } | ri

归功于发帖作者

Answer 6

从命令行： for /R /D %1 in (*) do rd "%1"

在 /R /D %%1 的批处理文件中 (*) do rd "%%1"

我不知道它是否被记录在案，但它适用于 W2K、XP 和 Win 7。而且我不知道它是否总是有效，但它不会意外删除文件。

Answer 7

这是上述的杂种。 它会删除所有早于 X 天的文件，并删除给定路径的所有空文件夹。 要使用只需设置天数、文件夹路径和驱动器

@echo off
SETLOCAL
set days=30
set folderpath=E:\TEST\
set drive=E:

::Delete files
forfiles -p %folderpath% -s -d -%days% -c "cmd /c del /q @path "

::Delete folders
cd %folderpath%
%drive%
for /f "usebackq delims=" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"`

Answer 8

它会工作得很好。 这是删除旧文件和递归删除空目录的最佳方法。 以下 .bat 文件是，

forfiles /p [PATH] /s /m [FILE-PATTERN] /d -[DAYS] /c "cmd /c del @path"
for /f "delims=" %%d in ('dir [PATH] /s /b /ad ^| sort /r') do rd "%%d"

占位符需要替换如下（不带引号）：

[DAYS] = Max. age of the files in days, e.g. “10”
[PATH] = Path to search for old files and empty folders, e.g. “C:\Backup\”
[FILE-PATTERN] = Pattern that matches files to delete, e.g. “*.bkp”

该脚本已在 Windows 7 和 Windows Server 2003 下成功测试。

Answer 9

安装任何适用于 Windows 的 UNIX 解释器（Cygwin 或 Git Bash）并运行 cmd：

查找 /path/to/directory -empty -type d

To find them

查找 /path/to/directory -empty -type d -delete

To delete them

（不是真正使用 windows cmd 提示符，但它很容易运行，需要几秒钟的时间）

Answer 10

@echo off
set /p "ipa= ENTER FOLDER NAME TO DELETE> "
set ipad="%ipa%"
IF not EXIST %ipad% GOTO notfound
IF EXIST %ipad% GOTO found
:found
echo DONOT CLOSE THIS WINDOW
md ccooppyy
xcopy %ipad%\*.* ccooppyy /s > NUL
rd %ipad% /s /q
ren ccooppyy %ipad%
cls
echo SUCCESS, PRESS ANY KEY TO EXIT
pause > NUL
exit 
:notfound
echo I COULDN'T FIND THE FOLDER %ipad%
pause
exit

Answer 11

如果您想在资源管理器上下文菜单（即右键单击）中使用 Varun 的 ROBOCOPY 命令行，这里是 Windows 注册表导入。 我尝试将此作为评论添加到他的答案中，但内联标记不可行。

我已经在自己的 Windows 10 PC 上对此进行了测试，但使用风险自负。 它将打开一个新的命令提示符，运行命令，然后暂停，以便您可以看到输出。

1. 复制到一个新的文本文件中：

   Windows 注册表编辑器版本 5.00

   [HKEY_CURRENT_USER\Software\Classes\directory\Background\shell\Delete Empty Folders\command] @="C:\Windows\System32\Cmd.exe /C \"C:\Windows\System32\Robocopy.exe \"%V \" \"%V\" /s /move\" && PAUSE"

   [HKEY_CURRENT_USER\Software\Classes\directory\shell\Delete Empty Folders\command] @="C:\Windows\System32\Cmd.exe /C \"C:\Windows\System32\Robocopy.exe \"%V\" \"%V\" /s /move\" && PAUSE"

2. 将 .txt 扩展名重命名为 .reg

3. 双击导入。

Answer 12

for /r "D:\Music" /d %F in (.) do @dir /b "%F" | findstr "^" >nul || rmdir %~fF

D:\Fun 是包含空文件夹的文件夹，在文件夹名称中有空格的情况下双引号（本例中不需要）

Answer 13

一个更现代、更简单的解决方案是：

forfiles /p C:\Path\To\Folder /c "cmd /c if @isdir==TRUE rd @file"

这将尝试在C:\Path\To\Folder中的所有目录上执行rd 。 包含内容的目录不会被删除。

如果您排除/p C:\Path\To\Folder那么它将在当前目录中运行。

如果您添加/s （在/c之前），那么它也会在子目录中查找。

Answer 14

以下 .cmd 是一个实验（有效）：

• 删除空目录并在 %temp% 和 C:\Windows\Temp 文件夹下包含“旧”(-1days)文件，
• 将 cmd 输出日志写入 .txt 文件，关于 fouded & deleted 文件夹/文件。

%temp% = C:\Users(user)\AppData\Local\Temp | %userprofile%\AppData\Local\Temp

代码：

::  This is a .cmd file
::    Use to:
::        Writes a Log about Temporary files & folders.
::        Cleans 'Windows Temp' folders/files.    (%userprofile%\AppData\Local\Temp  -&-  %windir%\Temp)
::        - a 'Cleaning_LOGs.txt'  will be created or updated in  Documents Library.    (%userprofile%\Documents\Cleaning_LOGs.txt)
::        
@echo off
title Log&CleanTemp

: Set the Path of 'Log file'  (%LogPath% variable)
set "LogPath=%userprofile%\Documents\Cleaning_LOGs.txt"
::  Note: ">> path\file.txt 2>&1" redirects cmd output to <path\to>\<log_file.txt>,    (will be created if does not exist)
::        (if exist, adds the new log at the end of the file, without deleting previous logs)

: Set  'C:\Windows\Temp'  (%WinTemp% var.)
set "WinTemp=%windir%\Temp"

: Seperator [Header] with Date-Time between (any) previous Logs in <log_file.txt>
echo: >> %LogPath% 2>&1
echo ======================================== >> %LogPath% 2>&1
echo %date% - %time% >> %LogPath% 2>&1
echo: >> %LogPath% 2>&1
echo Log Path: %LogPath%  (this text file) >> %LogPath% 2>&1
echo: >> %LogPath% 2>&1

: Report Output & Log
::  Writes a log about temporary files & folders. 
::  Note: ( %temp% = C:\Users\<user>\AppData\Local\Temp = %userprofile%\AppData\Local\Temp )
::         ( 'WinTemp' = C:\Windows\Temp = %windir%\Temp )
echo: >> %LogPath% 2>&1
echo __________ Empty (0 size) , Old (-1days)  files: >> %LogPath% 2>&1
ForFiles /p "%temp%" /s /d -1 /c "cmd /c if @fsize==0 ECHO @path " >> "%LogPath%" 2>&1
ForFiles /p "%WinTemp%" /s /d -1 /c "cmd /c if @fsize==0 ECHO @path " >> "%LogPath%" 2>&1
echo: >> %LogPath% 2>&1
echo __________ All Old (-1days) files: >> %LogPath% 2>&1
ForFiles /p "%temp%" /s /d -1 /c "cmd /c ECHO @path " >> "%LogPath%" 2>&1
ForFiles /p "%WinTemp%" /s /d -1 /c "cmd /c ECHO @path " >> "%LogPath%" 2>&1
::  Note: "ForFiles"  /p=Path  /s=SubDir  /d=Days(dd)  /c=cmd    "forfiles /?"  for info about command's Variables (@path, @file, etc.)

: Get permissions (unlock files/folders) (OPTIONAL)
::  Uncomment to make it work, IF needed.
::echo: >> %LogPath% 2>&1
::ForFiles /p "%temp%" /s /d -1 /c "cmd /c TAKEOWN /f * /r /d y && ICACLS @file /grant *S-1-3-4:F /t /c /l /q"

: Clean proper files  & Log it
::   Test: ForFiles /p "%temp%\" /s /d -1 /c "cmd /c if @fsize==0 DEL /f /s /q @file" >> "%LogPath%" 2>&1
::        ERROR: Invalid argument/option - '@fsize==0'
echo: >> %LogPath% 2>&1
echo __________ Deleted files: >> %LogPath% 2>&1
forfiles /p %temp%\ /s /d -1 /c "cmd /c DEL /f /s /q @path" >> "%LogPath%" 2>&1
forfiles /p %WinTemp%\ /s /d -1 /c "cmd /c DEL /f /s /q @path" >> "%LogPath%" 2>&1
echo: >> %LogPath% 2>&1
echo __________ Deleted empty directories: >> %LogPath% 2>&1
for /f "delims=" %%d in ('dir %temp%\ /s /b /ad ^| sort /r') do RD "%%d" >> "%LogPath%" 2>&1
for /f "delims=" %%d in ('dir %WinTemp%\ /s /b /ad ^| sort /r') do RD "%%d" >> "%LogPath%" 2>&1
::  Note:  'RD' = Remove-Directory (delete)

: Open Log file
:: this opens the log file    [(my) Documents\Cleaning_LOGs.txt]
explorer.exe %LogPath%

:: https://stackoverflow.com/questions/7831286/how-to-delete-empty-folders-using-windows-command-prompt/46617314#46617314

请注意：作为“预处理”的一部分，对此进行试验的触发器是为了防止在每次启动时自动重新安装（也是过时的）声卡的特定（过时的）驱动程序。 并清理（幻影）隐藏的设备等等。 （...）（这个笔记只是为了得到一个使用的想法）

所以，简而言之：这是清理留下的“临时”垃圾并给出报告的部分。

Answer 15

好吧，对于没有空格的简单 1 级目录结构，[编辑] 以及仅包含一种我认为有用的文件类型的目录（有时来自http://www.pcreview.co.uk /forums/can-check-if-folder-empty-bat-file-t1468868.html ）：

for /f %a in ('dir /ad/b') do if not exist %a\*.xml echo %a Empty

/ad ：仅显示目录条目
/b ：使用裸格式（只是名称）

[编辑] 使用普通星号检查任何文件（上面的 %a\*）都不起作用，感谢更正

因此，删除将是：

for /f %a in ('dir /ad/b') do if not exist %a\*.xml rmdir %a

Answer 16

这可以通过使用带有两个参数的rd命令轻松完成：

rd <folder> /Q /S

• /Q - 安静模式，不询问是否可以使用 /S 删除目录树

• /S - 除目录本身外，删除指定目录中的所有目录和文件。 用于删除目录树。