获取列表的最小值

Question

我试图找到列表的最小值（作为一种学习经验，所以没有min ）。

我的方法如下：

minimo([X], X).
minimo([X,Y|Tail], N):-
    (X > Y, minimo([Y,Tail], Y));
    (X <= Y, minimo([X,Tail], X)).

这给了我以下错误：

语法错误：应为运算符

所以我的问题是：

• 是什么导致语法错误？
• 如果它确实可以返回正确的值，那么一旦修复后，我将自己尝试一下，但这实际上是正确的方法吗？

提前致谢。

Answer 1

您的程序中存在几个错误：

1. 正如Joe Lehmann指出的那样，没有'<='/2 。 它必须是'=<'/2 。

2. 当您递归调用minimo/2 ，会错误地构造列表。 代替[Y,Tail]使用[Y|Tail] 。 否则，您将获得一个列表，其中列表是第二个元素。

3. 您将minimo/2的递归调用的第二个参数绑定到Y或X 相反，它必须绑定到N 否则，您的N将永远不会被实例化。

您可以通过添加剪切或使用if-then-else（ '->' + ; ）来进一步改善程序：

minimo([X], X) :- !.
minimo([X,Y|Tail], N):-
    ( X > Y ->
        minimo([Y|Tail], N)
    ;
        minimo([X|Tail], N)
    ).

Answer 2

除了已经发布的其他版本之外，还考虑不带if-then-else的版本，并为该关系使用更具描述性的名称（它将列表与其最小值相关联）：

list_min([L|Ls], Min) :- list_min(Ls, L, Min).

list_min([], Min, Min).
list_min([L|Ls], Min0, Min) :-
    Min1 is min(L, Min0),
    list_min(Ls, Min1, Min).

这种模式称为折叠 （从左开始），我们可以等效地使用`foldl / 4编写它：

list_min([L|Ls], Min) :- foldl(min_, Ls, L, Min).

min_(A, B, Min) :- Min is min(A, B).

查询示例：

?- list_min([1,0,2], Min).
Min = 0.

---

请注意，尽管这不是真正的关系，并且由于使用了低级算术，所以不能在所有方向上使用。 例如，如果尝试在另一个方向上使用它，则会得到：

?- list_min([X,Y], 3).
ERROR: is/2: Arguments are not sufficiently instantiated

为了使其成为一个真正的解决方案，请使用诸如clpfd和clpq之类的约束 。 例如，对于整数的解决方案：

:- use_module(library(clpfd)).

list_min([L|Ls], Min) :- foldl(min_, Ls, L, Min).

min_(A, B, Min) :- Min #= min(A, B).

这适用于所有方向：

?- list_min([X,Y], 3).
X in 3..sup,
3#=min(Y, X),
Y in 3..sup.

Answer 3

语法错误是因为Prolog中的小于或等于= <，而不是<=。

我认为这种方法会行得通，但您确实应该避免； 在条款中。 只需将其分为两个子句。

我也认为您想在递归中执行[X | Tail]之类的操作，而不是[X，Tail]

Answer 4

min([H|T], Min) :- min(T, H, Min).

min([], Min, Min).
min([H|T], Min, Min1) :-
  (   H < Min
  ->  min(T, H, Min1)
  ;   min(T, Min, Min1) ).