如何使用DOS批处理文件创建要传递给可执行文件的文件列表？

Question

我想获取目录中所有.dll和.exe的（用分号分隔）列表作为变量，以作为参数传递给可执行文件。 我已经尝试了一些方法，但是它从未按预期运行。 我已经找到了一部分-以下内容打印出了我想要的文件列表：

CLS
@ECHO OFF
SET INPUT_FILES=
for /f %%x in ('dir /b E:\Builds\MyProgram\Release\*.exe E:\Builds\MyProgram\Release\*.dll') do ECHO %%x

......但下一步不太正确，我正在努力解决我的错误：

CLS
@ECHO OFF
SET INPUT_FILES=
for /f %%x in ('dir /b E:\Builds\MyProgram\Release\*.exe E:\Builds\MyProgram\Release\*.dll') do IF DEFINED INPUT_FILES SET INPUT_FILES=INPUT_FILES;%%X ELSE SET INPUT_FILES=%%X
ECHO %INPUT_FILES%

如果可以在这里解决问题，我将把%INPUT_FILES%作为输入传递给另一个可执行文件。

编辑

如果执行以下命令，则可以更新INPUT_FILES变量：

IF "%INPUT_FILES%"=="" (SET INPUT_FILES=Test1) ELSE (SET INPUT_FILES=Test1a)
IF "%INPUT_FILES%"=="" (SET INPUT_FILES=Test2) ELSE (SET INPUT_FILES=%INPUT_FILES%;Test2a)
ECHO %INPUT_FILES%

..输出：

Test1;Test2a

..但如果我尝试将其添加到FOR循环中，我什么都得不到：

CLS
REM @ECHO OFF
SET INPUT_FILES=
for /f %%X in ('dir /b E:\Builds\MyProgram\Release\*.exe E:\Builds\MyProgram\Release\*.dll') do (IF "%INPUT_FILES%"=="" (SET INPUT_FILES=%%X) ELSE (SET INPUT_FILES=%INPUT_FILES%;%%X))
ECHO %INPUT_FILES%

Answer 1

问题在于百分比变量的扩展。
这些在解析时也得到了扩展（也适用于块）。

更好地使用延迟扩展，语法几乎相同，但有!variable! 而不是%variable% 。
不同之处在于：扩展发生在执行时而不是解析时。

@ECHO OFF
CLS
setlocal EnableDelayedExpansion
SET "INPUT_FILES="
for /f %%X in ('dir /b E:\Builds\*.exe E:\Builds\*.dll') do (
  IF "!INPUT_FILES!"=="" (
    SET "INPUT_FILES=%%X"
  ) ELSE (
    SET "INPUT_FILES=!INPUT_FILES!;%%X"
  )
)
ECHO !INPUT_FILES!