ANTLR语法-解析标签和说明

Question

我正在写一个使用指令列表代码的解释器。 尝试为带有标签的指令编写语法时遇到一些问题。

我想解析此代码块：

LD 4
ST A
LD A
EQ 4
ST _AUX_1
(* IF *)
LDN _AUX_1
JMPC _label_2 
(* THEN *)
LD B
EQ 3
ST _AUX_2
_label_2: (* ELSE *)
_label_1: (* END IF*)
LD TRUE

如您所见，这些标签在一行中没有指令，但是我要解析的语言允许一行中的“标签+指令”。 因此，指令和标签有三种不同的组合：

1. 指令
2. 标签：
3. 标签：说明

我可以解析1和2，但无法解析所有不同的组合。

这是我的ANTLR语法的一部分：

program_il : instruction* ;

instruction 
        : ID':' // label
        | ID_INST operand
        ;

operando
    : ID
    | CTE_INT
    | CTE_BOOL
    ;

我试图将语法更改为：

instruction : (ID':')? instruction? ;

但是我有下一个错误：

As a result, alternative(s) 2 were disabled for that input
[14:43:49] error(201): Analizador.g:131:29: The following alternatives can never be matched: 2

有人可以帮我解决这个问题吗？ 先感谢您。

Answer 1

因为您现在接受Label: Instruction ，所以语法是模棱两可的。 解析器无法区分：

lbl:
LD 4

和

lbl: LD 4

换句话说，您需要让instruction用某种分隔符分开。 如以下演示所示，换行可以解决问题：

grammar T;

program_il
 : NL* instruction (NL+ instruction)* NL* EOF
 ;

instruction 
 : ID ':' (ID_INST operand)?
 | ID_INST operand
 ;

operand
 : ID
 | CTE_INT
 | CTE_BOOL
 ;

CTE_BOOL
 : 'TRUE'
 | 'FALSE'
 ;

ID_INST
 : 'LD'
 | 'ST'
 | 'EQ'
 | 'LDN'
 | 'JMPC'
 ;

ID
 : ('_' | 'a'..'z' | 'A'..'Z') ('_' | 'a'..'z' | 'A'..'Z' | '0'..'9')*
 ;

CTE_INT
 : ('0'..'9')+
 ;

NL
 : '\r'? '\n'
 | '\r'
 ;

COMMENT
 : '(*' .* '*)' {skip();}
 ;

SPACE
 : (' ' | '\t')+ {skip();}
 ;

现在解析输入：

(* IF *)
JMPC _label_2 
(* THEN *)
LD B
ST _AUX_2
_label_2: LDN _AUX_1 (* ELSE *)
_label_1: (* END IF*)
LD TRUE

将产生以下树：