调用Ajax.BeginForm和Html.BeginForm后，编辑器模板不起作用

Question

我为枚举创建了一个可以正常工作的编辑器模板，直到我决定使用Ajax.BeginForm。 属性status具有以下定义：

<DisplayName("Status")>
<UIHint("enum")>
Public Property status As String

我已经尝试了以下方法：

@Using Ajax.BeginForm("New", "Os", Nothing)
    @Html.EditorFor(Function(m) m.status, "Enum", New With { .enumType = GetType(OsStatus)})
End Using

@Ajax.BeginForm("New", "Os", Nothing)

@Html.EditorFor(Function(m) m.status, "Enum", New With { .enumType = GetType(OsStatus)})

@Using Html.BeginForm()
    @Html.EditorFor(Function(m) m.status, "Enum", New With { .enumType = GetType(OsStatus)})
End Using

@Html.BeginForm()
@Html.EditorFor(Function(m) m.status, "Enum", New With { .enumType = GetType(OsStatus)})

以上都不起作用。

我的模板的代码如下

@ModelType String

@code

    Dim options As IEnumerable(Of OsStatus)
    options = [Enum].GetValues(ViewData("enumType")).Cast(Of OsStatus)()


    Dim list As List(Of SelectListItem) = 
            (from value in options 
            select new SelectListItem With { _
                .Text = value.ToString(), _
                .Value = value.ToString(), _
                .Selected = value.Equals(Model) _
            }).ToList()
    End If
End Code

@Html.DropDownList(Model, list)

调用.BeginForm方法后，仍会调用我的模板，但是模板内的Model属性为null 。

有任何想法吗？

Answer 1

您的编辑器模板至少可以看到4个问题：

• 您有一个“ End If没有开头， If ，则您的编辑器模板可能会引发异常
• 为了确定选定的值，您正在将枚举值与字符串： value.ToString().Equals(Model) value.Equals(Model)进行比较，而应该将字符串与字符串： value.ToString().Equals(Model)进行比较value.ToString().Equals(Model)
• 呈现下拉列表时，您将使用Model值作为名称，而应该使用空字符串，以便从父属性中获得此下拉列表的正确名称。
• 您的编辑器模板现在在将其OsStatus到OsStatus枚举时已绑定到它。 最好使此编辑器模板更具通用性和可重用性。

这是正确的方法：

@ModelType String

@code
    Dim options = [Enum].GetValues(ViewData("enumType")).Cast(Of Object)()

    Dim list As List(Of SelectListItem) =
            (From value In options
            Select New SelectListItem With { _
                .Text = value.ToString(), _
                .Value = value.ToString(), _
                .Selected = value.ToString().Equals(Model) _
            }).ToList()
End Code

@Html.DropDownList("", list)

正确的调用方式是：

@Using Ajax.BeginForm("New", "Os", Nothing)
    @Html.EditorFor(Function(m) m.status, "Enum", New With { .enumType = GetType(OsStatus)})
End Using

要么：

@Using Html.BeginForm("New", "Os", Nothing)
    @Html.EditorFor(Function(m) m.status, "Enum", New With { .enumType = GetType(OsStatus)})
End Using

现在，在渲染此视图时，请确保控制器操作实际上已通过模型，并且将status字符串属性设置为枚举中包含的某个字符串值，以便可以在下拉列表中自动预先选择正确的选项。