检测VB6中是否附加调试器

Question

我正在对我们用 Visual Basic 6 编写的一个旧应用程序进行一些维护工作，由于各种原因，我们有一部分代码只有在我们通过 VB6 IDE 运行程序时才需要运行（即，调试器已附加）。

在 VB.NET 中，您可以使用System.Diagnostics.Debugger.IsAttached()属性来执行此操作，但我在 Google 上的 VB6 中找不到任何类似的内容。

是否有一些简单的方法可以找出这些信息？

Answer 1

这是我们正在使用的没有任何副作用的

Public Property Get InIde() As Boolean
    Debug.Assert pvSetTrue(InIde)
End Property

Private Function pvSetTrue(bValue As Boolean) As Boolean
    bValue = True
    pvSetTrue = True
End Function

Answer 2

这是我一直在使用的一个函数：

Private Function RunningInIde() As Boolean
    On Error GoTo ErrHandler
    Debug.Print 1 / 0
ErrHandler:
    RunningInIde = (Err.Number <> 0)
End Function            ' RunningInIde

Answer 3

不久前我写了这样的东西，找不到它，又需要它。 所以我又写了一遍，我想我是对的：

Public Function IsRunningInIde() As Boolean
    Static bFlag As Boolean
    bFlag = Not bFlag
    If bFlag Then Debug.Assert IsRunningInIde()
    IsRunningInIde = Not bFlag
    bFlag = False
End Function

没有错误被提出。

没有复位 Err。

只有一个功能。

第 1 行：“bFlag”的“静态”声明导致 bFlag 的值在对“IsRunningInIde”的多次调用中保持不变。 我们想要这个是因为我在其内部调用了这个函数，我不想用用户不需要的输入参数来乱扔函数。

第 3 行：不在 IDE 中运行时不会调用“Debug.Assert”。 因此，只有在 IDE 中才会递归调用“IsrunningInIde”。

第 2 行：如果不在递归调用中，bFlag 开始为 false，并设置为 true。 如果在递归调用中（仅在 IDE 中运行时发生），它开始为真，然后设置回假。

第 3 行：仅通过检查 bFlag 是否为真，递归调用“IsRunningInIde”（如果它不在此函数中）。

第 4 行：如果在递归调用中，总是返回 True，这并不重要，但不会导致 Assert 失败。 如果不在递归调用中，则返回“Not bFlag”，如果以递归方式调用 IsRunningInIde，则 bFlag 现在为“False”，如果不以递归方式调用，则 bFlag 为“True”。 所以基本上，如果 Not bFlag 在 IDE 中运行，它会返回“True”。

第 5 行：清除 bFlag，使其在下次调用此函数时始终为“False”。

这很难解释，在这两种情况下，最好在你的脑海中逐步完成。

如果您想要更简单易懂的代码，请不要使用它。

如果此代码有问题，我深表歉意并告诉我，以便我可以修复它。

Answer 4

这是我的功能，类似于 Josh 的功能，但更易于阅读（请参阅里面的评论）。

用了很久都忘记从哪里借的了……

Public Function InDesign() As Boolean
' Returns TRUE if in VB6 IDE
Static CallCount    As Integer
Static Res          As Boolean

    CallCount = CallCount + 1
    Select Case CallCount
    Case 1  ' Called for the 1st time
        Debug.Assert InDesign()
    Case 2  ' Called for the 2nd time: that means Debug.Assert 
            ' has been executed, so we're in the IDE
        Res = True
    End Select
    ' When Debug.Assert has been called, the function returns True
    ' in order to prevent the code execution from breaking
    InDesign = Res

    ' Reset for further calls
    CallCount = 0

End Function

Answer 5

Public Function InIDE() As Boolean
On Error GoTo ErrHandler

    Debug.Print 1 \ 0 'If compiled, this line will not be present, so we immediately get into the next line without any speed loss

    InIDE = False

Exit Function
ErrHandler:
InIDE = True 'We'll get here if we're in the IDE because the IDE will try to output "Debug.Print 1 \ 0" (which of course raises an error).
End Function

Answer 6

Public Function InIDE(Optional ByRef bool As Boolean = True) As Boolean
    If bool Then Debug.Assert Not InIDE(InIDE) Else bool = True
End Function

用法：

If InIDE() Then
    '- Yes
End If