处理电子邮件的主题行时类型不匹配（脚本）

Question

我在“邮件到达之前”上运行Lotusscript代理。 我需要它来抓住“＃”符号后面的主题行中的文本。 无论我如何尝试获取Subject字段（Evaluate，getFirstItem，getItemValue等），我总是会遇到一个错误。 通常是类型不匹配或未设置对象变量。

下面的代码是我当前的代码，并在第14行“类型不匹配”返回错误13

Option Public
Option Declare

Sub Initialize
    On Error GoTo ErrorHandler 
    Dim s As New NotesSession
    Dim db As NotesDatabase
    Dim view As NotesDocumentCollection
    Dim doc As NotesDocument
    Dim nextdoc As NotesDocument
    Dim result As String
    Set db = s.CurrentDatabase
    Set view = db.Unprocesseddocuments
    If Not view Is Nothing Then
        Set doc = view.Getfirstdocument()
        While Not doc Is Nothing
            result = Evaluate ("@Right(Subject;""#"")", doc)
            Print result
            Set nextDoc = view.GetNextDocument(doc)
            Call doc.Remove(True)
            Set doc = nextDoc
        Wend
    End If
    Print "End"
Done: 
    Exit Sub
ErrorHandler: 
    Select Case Err 
        Case Else 
            Print "Error " & CStr(Err) & " in agent on line " & CStr(Erl) & ": " & Error 
            Resume Done 
    End Select 
End Sub 

Answer 1

在新邮件到达之前，不返回NotesDocumentCollection。 采用...

Sub Initialize
    Dim Session As New NotesSession
    Dim Doc As NotesDocument
    Dim result As String
    Set Doc = Session.DocumentContext
    Let result = StrRight(Doc.Subject(0), "#")
End Sub

而不是UnprocessedDocuments ...

Answer 2

关于您在使用评估时有关Type Mismatch原始问题，请注意“使用评估语句”下的Designer帮助：

“ returnValue是一个数组，其中元素的类型和数量反映了公式的结果；标量值返回到该数组的元素0。您应该对返回值使用一个变体，因为您可能不知道有多少个元素回来。”

因此，请尝试以下更改：

    ...
    Dim result As Variant
    ...
    result = Evaluate (|@Right(Subject;"#")|, doc)
    ' Treat result as an array
    Print result(0)
    ...