列为序言中的图形

Question

我正在尝试生成从矩阵中的一个元素到另一个元素的所有可能的“路线”，主要条件是说，只有当元素共享至少一个角时，矩阵中的元素才能与其他元素连接，因此在该矩阵中

[[1,2,3]
 [5,4,6]
 [8,9,7]]

1只能与2,4,5连接，而4与所有元素都连接。 是否可以在不使用吸引的情况下将该列表表示为图形？ 也许我可以找到更简单的方法

---

感谢所有答案。 好的，我提出了:-)现在有了谓词，我生成了所有“ edges”，但是我无法在任何地方使用它们，我无法弄清楚如何以这种模式([row:R1,column:C1,value:V1], [row:R2,column:C2,value:V2]) 。

Answer 1

这是一个（很长但很简单）的解决方案。

首先，它有助于使用辅助谓词从矩阵的Row,Col位置检索元素作为列表列表，例如：

get_matrix_entry_nth0(RowInd, ColInd, Matrix, Entry) :-
    nth0(RowInd, Matrix, Row),
    nth0(ColInd, Row, Entry).

其次，它也有助于使用该谓词来定义相对于Row和Col在方向上索引的条目的条目，例如：

up_left_entry(R-C, Matrix, E) :-
    PrevR is R - 1,
    PrevC is C - 1,
    get_matrix_entry_nth0(PrevR, PrevC, Matrix, E).

up_entry(R-C, Matrix, E) :-
    PrevR is R - 1,
    get_matrix_entry_nth0(PrevR, C, Matrix, E).

up_right_entry(R-C, Matrix, E) :-
    PrevR is R - 1,
    NextC is C + 1,
    get_matrix_entry_nth0(PrevR, NextC, Matrix, E).

right_entry(R-C, Matrix, E) :-
    NextC is C + 1,
    get_matrix_entry_nth0(R, NextC, Matrix, E).

down_right_entry(R-C, Matrix, E) :-    
    NextR is R + 1,
    NextC is C + 1,
    get_matrix_entry_nth0(NextR, NextC, Matrix, E).

down_entry(R-C, Matrix, E) :-
    NextR is R + 1,
    get_matrix_entry_nth0(NextR, C, Matrix, E).

down_left_entry(R-C, Matrix, E) :-    
    NextR is R + 1,
    PrevC is C - 1,
    get_matrix_entry_nth0(NextR, PrevC, Matrix, E).

left_entry(R-C, Matrix, E) :-
    PrevC is C - 1,
    get_matrix_entry_nth0(R, PrevC, Matrix, E).

有了这些辅助谓词，解决方案就非常简单了：

matrix_path([R|Rs], P) :-
    % determine rows, cols
    length([R|Rs], Rows),
    length(R, Cols),
    % defer to matrix_path/4 to compute all paths starting with 0,0
    matrix_path(0-0, Rows-Cols, [R|Rs], P).

matrix_path/2是程序的入口点。 该单句谓词可预先确定给定矩阵中的行数和列数，并将处理推迟到matrix_path/4 ，该矩阵从0,0 （左上角）元素开始计算。

matrix_path(R-C, Rows-Cols, Matrix, P) :-
    C >= Cols, !,
    % end of column, proceed to next row
    NextRow is R + 1,
    NextRow < Rows,
    matrix_path(NextRow-0, Rows-Cols, Matrix, P).

matrix_path/4的第一子句检查是否已超过列数； 如果是这样，则使用cut（ ! ）排除以下子句，然后在下一行重新开始计算，并将列索引重置为0。

matrix_path(R-C, _, Matrix, adj(S, T)) :-
    % get this entry
    get_matrix_entry_nth0(R, C, Matrix, S),
    % get each adjacent entry
    (   up_left_entry(R-C, Matrix, T)
    ;   up_entry(R-C, Matrix, T)
    ;   up_right_entry(R-C, Matrix, T)
    ;   right_entry(R-C, Matrix, T)
    ;   down_right_entry(R-C, Matrix, T)
    ;   down_entry(R-C, Matrix, T)
    ;   down_left_entry(R-C, Matrix, T)
    ;   left_entry(R-C, Matrix, T)
    ).

matrix_path/4的第二个子句只是尝试从给定条目中检索所有可能的“路径”。 有些可能会失败（例如在第一行中查找），但是Prolog将回溯以找到所有可行的解决方案。

matrix_path(R-C, Rows-Cols, Matrix, P) :-
    % get the entry for the next column in this row
    NextC is C + 1,
    matrix_path(R-NextC, Rows-Cols, Matrix, P).

matrix_path/4的最后一个子句仅相对于同一行中下一列的项目移动处理。

运行一个简单的示例：

?- matrix_path([[1,2],[3,4]], P).
P = adj(1, 2) ;
P = adj(1, 4) ;
P = adj(1, 3) ;
P = adj(2, 4) ;
P = adj(2, 3) ;
P = adj(2, 1) ;
P = adj(3, 1) ;
P = adj(3, 2) ;
P = adj(3, 4) ;
P = adj(4, 1) ;
P = adj(4, 2) ;
P = adj(4, 3) ;
false.

请注意，如果您希望所有相邻对立即进行而不回溯，则将调用包装在findall/2 ，如下所示：

?- findall(P, matrix_path([[1,2],[3,4]], P), Ps).
Ps = [adj(1, 2), adj(1, 4), adj(1, 3), adj(2, 4), adj(2, 3), adj(2, 1), adj(3, 1), adj(3, 2), adj(..., ...)|...].

Answer 2

使用Prolog回溯可以轻松完成有限集的枚举：

adjacent_pos((R,C), (Ra,Ca)) :-
     (R > 1, Ra is R-1 ; Ra is R ; Ra is R+1),
     (C > 1, Ca is C-1 ; Ca is C ; Ca is C+1),
     once(Ra \= R ; Ca \= C).

使用成对的nth1 / 3，我们可以访问一个单元：

cell(Mat, (R,C), Cell) :-
     nth1(R, Mat, Row),
     nth1(C, Row, Cell).

因此，在不同元素的矩阵NxM中：

adjacent(Mat, Elem, Adj) :-
     cell(Mat, Pe, Elem),
     adjacent_pos(Pe, Pa),
     cell(Mat, Pa, Adj).

简单测试：

test :-
   M = [[1,2,3],
        [5,4,6],
        [8,9,7]],
   findall(A, adjacent(M,1,A), L1), writeln(L1),
   findall(A, adjacent(M,4,A), L4), writeln(L4).

产量：

?- test.
[2,5,4]
[1,2,3,5,6,8,9,7]
true.

请注意，可以避免测试R > 1和C > 1 ，要求在“带外”测试中失败nth1 / 3。 上限也是如此，实际上已被省略，其附加好处是我们不仅限于预定义的矩阵大小。