使用coldfusion 8将图像添加到Excel文档中的行

Question

使用Coldfusion 8有没有人能够将图像嵌入excel电子表格（xlsx）或通过img src链接它们？

一些背景信息：cf服务器将拾取带有产品行的Excel文档。 根据产品ID和样式等，我可以找到或创建一个图像，将其作为第一列添加到现有的Excel文档中。

我知道coldfusion 9有一个名为SpreadsheetAddImage的函数，不幸的是我在cf 8上没有机会升级。

Answer 1

我不确定您目前使用什么操作xlsx文件。 但是，CF9中的电子表格功能使用POI ，显然也可以在CF8中使用。 它只需要更低级别的代码。

先决条件：

虽然POI与CF8捆绑在一起，但它是旧版本。 您需要更新的版本来操作.xlsx文件。 您可以使用javaLoader -OR-替换{cf_root}\\lib文件夹中的现有jar。 注意，我不知道更换罐子是否有任何负面影响。

添加图片：

Excel并不真正支持<img>标签，只支持超链接。 但是，您可以像SpreadsheetAddImage一样在工作簿中嵌入图像。 如POI的繁忙开发者指南中所述，基本过程是：

1. 使用WorkBookFactory加载xlsx文件
2. 获取每个图像的二进制文件并将其添加到工作簿中
3. 将每个图像锚定到所需的单元格
4. 将修改后的工作簿保存回磁盘

例：

---

<cfscript>
    // .. 

    // load the xlsx file with the javaLoader
    factory = loader.create("org.apache.poi.ss.usermodel.WorkbookFactory");
    input = loader.create("java.io.FileInputStream").init( "c:/path/to/someFile.xlsx" );
    workbook = factory.create( input );
    input.close();

    // get the desired sheet and load helper objects (once)
    sheet     = workbook.getSheet("Your Sheet Name");
    patriarch = sheet.createDrawingPatriarch();
    helper    = workbook.getCreationHelper();

    // add the image to the workbook
    imageBytes  = fileReadBinary( "c:/path/to/someImage.jpg" );
    imageIndex  = workbook.addPicture( imageBytes, workbook.PICTURE_TYPE_JPEG );

    // anchor the picture to the first cell ie A1
    anchor     = helper.createClientAnchor();
    anchor.setRow1( javacast("int", 0) ); // row of first cell (zero based)
    anchor.setCol1( javacast("int", 0) ); // column of first cell (zero based)
    picture = patriarch.createPicture( anchor, imageIndex );
    picture.resize(); // only supported for jpg and png

    // save it back to disk
    outstream = loader.create("java.io.FileOutputStream").init( "c:/path/to/outFile.xlsx"" );
    workbook.write( outstream );
    outstream.flush();
    outstream.close(); 
</cfscript>

---

新列具有讽刺意味的是，插入新列比添加图像更棘手。 最后我检查过，POI仍缺少插入新列的内置函数。 因此，在将图像插入第一列之前，您需要将所有现有单元格向右移动。 棘手的部分是维护单元格格式，合并单元格等。