来自clojure a与非标准迭代java API的互操作

Question

我在clojure中使用java类，它为包含一系列记录的特定于域的二进制文件提供检索API。

java类用文件初始化，然后提供一个.query方法，该方法返回一个只有一个方法.next的内部类的实例，因此不能很好地使用通常的java集合API。 外部类和内部类都不实现任何接口。

.query方法可能返回null而不是内部类。 .next方法返回记录字符串，如果没有找到其他记录则返回null，它可能在第一次调用时立即返回null。

如何在不编写更多java类的情况下使这个java API在clojure中运行良好？

我能想到的最好的是：

(defn get-records
  [file query-params]
  (let [tr (JavaCustomFileReader. file)]
    (if-let [inner-iter (.query tr query-params)] ; .query may return null                                                               
      (loop [it inner-iter
             results []]
       (if-let [record (.next it)]
         (recur it (conj results record))
         results))
      [])))

这给了我一个结果向量来处理clojure seq抽象。 是否有其他方法可以使用lazy-seq或使用协议从Java API中公开seq？

Answer 1

你的代码并不像你使用Iterable那样懒，但你可以用lazy-seq填补空白，如下所示。

(defn query-seq [q]
  (lazy-seq
    (when-let [val (.next q)]
      (cons val (query-seq q)))))

也许你应该包装查询方法以保护自己免受第一个空值的影响。

Answer 2

看起来非常适合lazy-seq ：

(defn query [file query]
  (.query (JavaCustomFileReader. file) query))

(defn record-seq [query]
  (when query
    (when-let [v (.next query)]
      (cons v (lazy-seq (record-seq query))))))

;; usage:
(record-seq (query "filename" "query params"))

Answer 3

没有下降到lazy-seq ：

(defn record-seq
  [q]
  (take-while (complement nil?) (repeatedly #(.next q))))

如果.next没有返回布尔值false你也可以使用identity而不是(complement nil?) 。

(defn record-seq
  [q]
  (take-while identity (repeatedly #(.next q))))

我还会重新调整一下入口点。

(defn query
  [rdr params]
  (when-let [q (.query rdr params)]
    (record-seq q)))

(defn query-file
  [file params]
  (with-open [rdr (JavaCustomFileReader. file)]
    (doall (query rdr params))))