如何实现多个列表框（TCL）的tk滚动条？

Question

我尝试了各种选项，但没有成功实现两个或多个列表框的简单滚动条。 以下是我的代码在滚动时给出错误。 我希望你们能帮助我...

scrollbar .scroll -orient v
pack .scroll -side left -fill y
listbox .lis1
pack .lis1 -side left 
listbox .lis2
pack .lis2 -side left 

for {set x 0} {$x < 100} {incr x} {
 .lis1 insert end $x
 .lis2 insert end $x
}
.lis1 configure -yscrollcommand [list .scroll set]
.lis2 configure -yscrollcommand [list .scroll set]
.scroll configure -command ".lis1 yview .lis2 yview ";

感谢您。

Answer 1

如果您打算在callback命令中做很多工作，请执行一个过程来完成该过程，因为这样做既更快（该过程得到字节编译），又不太可能引入tcl语法问题。 在这种情况下，您尝试在滚动条功能中执行两个tcl命令，因此您需要使用换行符或分号来分隔语句。

从两个列表框中调用滚动条设置功能将使第二个覆盖第一个。 您或者需要一个函数来合并这两个列表，或者如果列表具有相同的长度，只需从其中一个列表中调用它来设置滚动条的大小和位置，然后使用滚动条回调来更新所有列表框。

某个地方有一个multilistbox软件包-尝试Tcl Wiki来找到示例。

Answer 2

Tcler的Wiki上有很多示例，但是核心原则是使用一种过程来确保滚动协议在小部件之间同步。 这是基于该Wiki页面的示例：

# Some data to scroll through
set ::items [lrepeat 10 {*}"The quick brown fox jumps over the lazy dog."]

# Some widgets that will scroll together
listbox .list1 -listvar ::items -yscrollcommand {setScroll .scroll}
listbox .list2 -listvar ::items -yscrollcommand {setScroll .scroll}
scrollbar .scroll -orient vertical -command {synchScroll {.list1 .list2} yview}

# The connectors
proc setScroll {s args} {
    $s set {*}$args
    {*}[$s cget -command] moveto [lindex [$s get] 0]
}
proc synchScroll {widgets args} {
    foreach w $widgets {$w {*}$args}
}

# Put the GUI together
pack .list1 .scroll .list2 -side left -fill y 

值得注意的是，您还可以将任何其他可滚动的小部件插入此方案中。 Tk中的所有内容都以相同的方式滚动（除了-xscrollcommand和xview用于水平滚动，以及滚动条方向的更改）。 此外， 这里的连接器与Wiki页面上的连接器不同，可以一次与多组滚动的小部件一起使用。 一起滚动的内容存储在滚动条的-command选项中（ synchScroll回调的第一个参数）。

---

[编辑]：对于8.4及更低版本，您需要稍微不同的连接器过程：

# The connectors
proc setScroll {s args} {
    eval [list $s set] $args
    eval [$s cget -command] [list moveto [lindex [$s get] 0]]
}
proc synchScroll {widgets args} {
    foreach w $widgets {eval [list $w] $args}
}

其他一切都一样。

Answer 3

我知道这篇文章确实很老，但是最近我发现我认为这是一个非常简单的解决方案。 我发现可以使用滑块控件而不是使用垂直滚动条。 使用滑块，您可以获取滑块的位置，并使用它来设置列表框的yview。 多个列表框可以同时滚动。 我使用vtcl来构建GUI，因此对于使用tk wm comand的人来说，我可以提供的代码可能不是立即显而易见的。 但是这是我使用的代码。 它绑定到滑块运动。

set listIndex [$widget(Scale1) get]
$widget(Listbox1) yview $listIndex
$widget(Listbox2) yview $listIndex

希望对别人有帮助。