制作批处理文件，创建具有今天日期的文件夹，然后将文件从文件夹移动到新创建的文件夹

Question

我需要制作一个批处理文件，该文件将以月日年格式创建一个包含今天日期的文件夹（例如 080112）。 然后，一旦它被创建，我需要将文件从一个设置的文件夹移动到它刚刚创建的文件夹中。 老实说，我不知道如何制作批处理文件。

Answer 1

这将向您展示如何在变量中设置日期。

其余的只是使用 copy/xcopy 到该文件夹​​:)

告诉我您是否需要详细说明如何操作。

干杯!

[编辑]：这是完整的解决方案：

使用记事本创建文件 -> 另存为“something.bat”或使用 CMD -> 复制 con something.bat（完成后按 Ctrl-Z）并粘贴以下代码：

@echo off
IF "%1"=="" GOTO MissingArgument
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set year=%%c
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set month=%%a
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set day=%%b
set TODAY=%month%%day%%year%
md %TODAY%
MOVE %1\*.* %TODAY%
GOTO end
:MissingArgument
echo Incorrect Syntax: Source Folder Name Required!
:end

希望这可以帮助！

Answer 2

set TODAY=%date:~10,4%%date:~7,2%%date:~4,2%

是将日期部分放入 shell 变量的另一种方法

来自： http ://stevesgeekspeak.com/2010/01/howto-get-variable-substrings-in-batcmd-scripts/

Jony ... FTW，当然，因为有完整的答案。

Answer 3

FOR /f "tokens=2-4 delims=/ " %%i in ('DATE/T') do SET today_fname=%%i%%j%%k
md c:\myfolder\%today_fname%
REM This creates a folder named 05242016 in c:\myfolder

Answer 4

只需按照 Erik 的建议重命名文件夹即可：

move FolderName FolderName_%date:~7,2%%date:~4,2%%date:~10,4%

Answer 5

@echo on

:: Use date /t and time /t from the command line to get the format of your date and
:: time; change the substring below as needed.

:: This will create a timestamp like yyyy-mm-dd-hh-mm-ss.
set TIMESTAMP=%DATE:~10,4%-%DATE:~4,2%-%DATE:~7,2%-%TIME:~0,2%-%TIME:~3,2%-%TIME:~6,2%

@echo TIMESTAMP=%TIMESTAMP%

:: Create a new directory
md e:\example\"%1\%TIMESTAMP%"
xcopy /y c:\windows E:\windows\%TIMESTAMP% /e

@echo on

Answer 6

建议不要使用 Windows 命令处理器cmd.exe的动态变量DATE或其使用选项/T执行的内部命令date来仅输出当前日期，而使用在后台启动的另一个cmd.exe来获取所需的当前日期格式MMddyyyy因为这些解决方案取决于为运行批处理文件时使用的帐户配置的国家/地区。

Wikipedia page date format by country记录了许多不同的日期格式。

使用 ROBOCOPY 获取当前日期并移动文件

使当前日期区域独立的一种解决方案是使用ROBOCOPY ，它从 Windows Vista 和 Windows Server 2003 开始​​在 Windows 的系统目录中可用，但默认情况下在 Windows XP 上不可用。 可以将 Windows Server 2003 的robocopy.exe复制到 Windows XP 的%SystemRoot%\System32以在 Windows XP 上使用此可执行文件，但在 Windows XP 上默认不可用。

使用无效的源目录字符串"C:\|"执行ROBOCOPY 和有效的目标目录字符串. （也可能是其他有效的东西）和参数/NJH来抑制头信息的输出。

robocopy "C:\|" . /NJH

此执行产生错误消息：

2022/07/10 10:34:23 ERROR 123 (0x0000007B) Accessing Source Directory C:\|\
The filename, directory name, or volume label syntax is incorrect.

空行后第二行开头的当前日期/时间格式与区域无关。

此输出可用于获取所需格式的当前日期，以将文件移动到名称为MMddyyyy格式的当前日期的目录中。

@echo off
setlocal EnableExtensions DisableDelayedExpansion
for /F "tokens=1-3 delims=/ " %%G in ('%SystemRoot%\System32\robocopy.exe "%SystemDrive%\|" . /NJH') do %SystemRoot%\System32\robocopy.exe "C:\Source Directory" "C:\Destination Directory\%%H%%I%%G" /MOV /NDL /NFL /NJH /NJS /R:3 /W:2 & goto FileMovesDone
:FileMovesDone
endlocal

在这种情况下， FOR在后台启动另一个命令进程，其中%ComSpec% /c和两个'之间的命令行作为附加参数附加，这导致 Windows 在执行以下操作时被安装到C:\Windows中：

C:\Windows\System32\cmd.exe /c C:\Windows\System32\robocopy.exe "C:\|" . /NJH

用于处理由FOR捕获的后台命令进程的STDOUT的错误消息输出的第一个非空行的前三个斜杠或空格分隔的字符串分配给：

• G ...年
• H ...月
• I ...天

这三个数据字符串连接到目标目录参数字符串中所需格式的日期字符串，接下来执行的ROBOCOPY命令将指定源目录C:\Source Directory中的所有文件移动到目标目录中。 ROBOCOPY自动将整个目录树创建到目标目录。

但是FOR会为第二个错误消息行再次运行命令SET 。 出于这个原因，无条件运算符&用于独立于通过ROBOCOPY移动文件的成功或失败运行命令GOTO以在标签FileMovesDone下方的行上继续批处理文件，因此在处理第二个非空行之前退出FOR循环ROBOCOPY的错误信息。

最好使用以下代码：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
for /F "tokens=1-3 delims=/ " %%G in ('%SystemRoot%\System32\robocopy.exe "%SystemDrive%\|" . /NJH') do %SystemRoot%\System32\robocopy.exe "C:\Source Directory" "C:\Destination Directory\%%G-%%H-%%I" /MOV /NDL /NFL /NJH /NJS /R:3 /W:2 & goto FileMovesDone
:FileMovesDone
endlocal

不同之处在于使用%%G-%%H-%%I而不是%%H%%I%%G导致创建目标目录，其名称采用国际日期格式yyyy-MM-dd 。 该日期格式更易于阅读，并且还具有按名称排序的目录同时按正确的时间顺序列出的优点。

---

使用 WMIC 获取当前日期区域独立

由于ROBOCOPY在 Windows XP 上默认不可用，因此需要一个不同的解决方案来获得独立于 Windows XP 的当前日期区域。

可以使用Windows Management Instrumentation 命令行工具WMIC获取与区域无关的日期/时间字符串。

命令行

wmic OS GET LocalDateTime /VALUE

输出 UTF-16 Little Endian 编码，例如：

LocalDateTime=20220710105636.581000+120

有两个空行，然后是当前本地日期/时间格式为 yyyyMMddHHmmss.microsecond±UTC 偏移量（以分钟为单位）的行和另外两个空行。

数据可以与这样的批处理代码一起使用：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
for /F "tokens=2 delims==." %%I in ('%SystemRoot%\System32\wbem\wmic.exe OS GET LocalDateTime /VALUE') do set "FolderDate=%%I"
set "DestinationFolder=C:\Destination Directory\%FolderDate:~4,2%%FolderDate:~6,2%%FolderDate:~0,4%"
md "%DestinationFolder%"
if exist "%DestinationFolder%\" move /Y "C:\Source Directory\*" "%DestinationFolder%\"
endlocal

有趣的是这里只有等号和小数点之间的日期/时间字符串，这是使用for /F选项tokens=2 delims==. 仅20220710105636分配给循环变量I ，其中的值分配在环境变量FolderDate 。

环境变量FolderDate使用字符串替换重新格式化，以获取格式MMddyyy的日期字符串，从而导致环境变量DestinationFolder使用C:\Destination Directory\07102020 。

使用WMIC获取本地日期/时间的优点是它独立于 Windows 区域设置，甚至在 Windows XP 上也能正常工作。 缺点是命令执行需要相当长的时间（在 Windows XP 上为 1 到 2 秒，在 Windows Vista 和较新的 Windows 版本上超过 50 毫秒）与使用动态DATE变量（在几微秒内访问）相比.

命令FOR无法正确解析 UTF-16 LE 编码的 Unicode 输出。 它将WMIC输出的字节序列0D 00 0A 00 （回车+换行）错误地解释为0D 0D 0A ，即两个回车和一个换行。 这导致将WMIC输出末尾的最后两个空行解释为两行，并将单个回车符作为字符串。

这通常是一个问题，因为set "EnvironmentVariable=%%I"的结果是%%I扩展为仅回车，删除之前已经定义的具有正确值的环境变量。

有多种解决方案可以解决命令FOR的 Unicode 解析错误。 一旦将值分配给环境变量，可以附加& goto Label以退出循环并跳转到FOR循环下方的:Label以避免遇到此问题。

另一种解决方案是在FOR命令行上方使用if not defined FolderDate set "FolderDate=%%I"和set "FolderDate="以确保命令SET只执行一次。

另一种解决方案是此代码中使用的解决方案。 由于使用了WMIC选项/VALUE ，因此属性的名称及其值在同一行上输出。 只有当由于delims==.使用等号和点作为分隔符，它可以将当前行分成至少两个子字符串（标记）时， FOR命令才运行命令SET ，因为tokens=2 。 . 但是WMIC输出的错误解析空行仅用于FOR仅包含回车的行，因此没有第二个标记。 由于这个原因，错误解析的空行在这里也被FOR命令忽略。

请参阅如何在解析输出时纠正变量覆盖错误行为？ 并且cmd 以某种方式将中文文本作为输出，以获取有关在 UTF-16 Little Endian 编码输出上解析FOR问题的详细信息。

此解决方案采用国际日期格式yyyy-MM-dd ：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
for /F "tokens=2 delims==." %%I in ('%SystemRoot%\System32\wbem\wmic.exe OS GET LocalDateTime /VALUE') do set "FolderDate=%%I"
set "DestinationFolder=C:\Destination Directory\%FolderDate:~0,4%-%FolderDate:~4,2%-%FolderDate:~6,2%"
echo md "%DestinationFolder%"
if exist "%DestinationFolder%\" move /Y "C:\Source Directory\*" "%DestinationFolder%\"
endlocal

第四行不同，使用2022-07-10而不是07102022创建目标文件夹名称。

---

其他解决方案有什么问题？

Erik Eidt写的答案

命令行使用命令行重新格式化动态变量DATE的值：

set TODAY=%date:~10,4%%date:~7,2%%date:~4,2%

环境变量TODAY定义为027.在我的 Windows PC 上，为我的用户帐户配置了德语（奥地利），而不是20220710 （ yyyyMMdd ），因为命令行很可能是为或使用07102022 （ MMddyyyy ）设计的，因为它被要求. 原因是echo %DATE%在我的 PC 上输出日期字符串10.07.2022 （ dd.MM.yyyy ）而不是Sun 10/07/2022 （ ddd dd/MM/yyyy ， ddd代表缩写的工作日），因此命令行中的三个字符串替换不适用于我的 Windows PC 上使用我的用户帐户的日期字符串。

使用动态变量DATE的更好解决方案是：

set "TODAY=%DATE:~-7,2%%DATE:~-10,2%%DATE:~-4%"

此解决方案以MMddyyyy或ddMMyyyy格式获取日期，日期字符串独立于以工作日开头或没有工作日的日期字符串，这也是各个国家/地区之间的差异。 剩下的问题是，地区相关日期可以是第一个月、第二天和第三年，或者在我的情况下是第一天、第二个月和第三年。

所以MM/dd/yyyy （美国日期格式）的命令行必须是：

set "TODAY=%DATE:~-10,2%%DATE:~-7,2%%DATE:~-4%"

这将使用字符串07102022为日期字符串07/10/2022 （无工作日）以及日期字符串Sun 07/10/2022 （有工作日）定义环境变量TODAY 。

有关字符串替换的更多详细信息，请参见：
%date:~-4,4%%date:~-10,2%%date:~-7,2%_%time:~0,2%%time:~3,2% 是什么意思？

Jony Adamit写的答案

这是最糟糕的解决方案，因为使用选项/T执行的cmd.exe的内部命令date始终输出与echo %DATE%相同的日期字符串，即输出字符串与可以直接访问的动态变量DATE的字符串相同如上图所示。

使用三个for /F在后台启动三个cmd.exe与选项/c和命令行date /T让后台命令进程将当前日期输出到其句柄STDOUT是没有意义的，捕获使用cmd.exe处理批处理文件的输出，将日期字符串拆分为三个子字符串（令牌）并始终只使用三个子字符串之一。 这确实是对 CPU 功率和 CPU 时间的浪费，并且还会导致不必要的文件系统访问。

该非常低效的解决方案仅适用于格式为ddd MM/dd/yyyy的日期字符串，该日期字符串以工作日开头，例如美国日期格式。 它不适用于没有工作日或使用与/ like 不同的分隔符的日期. 并且日期字符串中的日期和月份的顺序可能会有所不同，具体取决于为使用的帐户配置的国家/地区。

mangyan写的答案

该解决方案还使用低效的方法在后台再启动一个cmd.exe来处理日期字符串，这也可以通过使用以下命令行来完成，而无需再使用一个cmd.exe ：

FOR /f "tokens=2-4 delims=/ " %%i in ("%DATE%") do SET today_fname=%%i%%j%%k

但是，此解决方案也仅适用于格式为ddd MM/dd/yyyy且以工作日开头的日期字符串。 所以它也不是很好，也不是很有效。

Anna Malai写的答案

注释中写到命令date /t和time /t用于获取当前日期和时间，尽管实际上代码使用动态变量DATE和TIME 。

环境变量TIMESTAMP不仅定义为格式为MMddyyyy的日期，而且还定义了时间，看起来想要的格式是yyyy-MM-dd-HH-mm-ss ，这当然只适用于日期和时间格式为ddd MM/dd/yyyy HH:mm:ss

用于创建目录的命令行md e:\example\"%1\%TIMESTAMP%"语法不正确，因为"在目录路径内而不是包围整个目录路径。错误的语法由cmd.exe因为"是文件/文件夹名称中的无效字符。 因此cmd.exe在将目录字符串传递给 Windows 文件 I/O 函数之前将其从目录字符串中删除"目前还不清楚为什么%1在引用批处理文件的第一个参数的路径内。

jardane要求以MMddyyyy格式创建具有当前日期的文件夹，以将文件移动到其中。 因此，为什么在复制而不是移动文件的答案中使用命令XCOPY尚不清楚。 目标路径与之前使用命令MD创建的目录不同。 XCOPY的选项/e用于复制整个 Windows 目录以及所有子目录中的几乎所有文件（隐藏和系统文件被忽略），同时将空子目录复制到指定的目标目录。 XCOPY命令还会在复制多个文件时自动创建目标文件夹，如果E:\windows\%TIMESTAMP%指定文件名或目录并按下目录键，则用户会回答提示。 （可以通过以反斜杠结束目标文件夹路径来避免提示。）

最后一个带有@echo on的命令行在第一行已经明确启用命令回显模式没有意义。

霍格写的答案

该答案表明，应用于动态变量DATE的值的三个字符串替换也可以直接在命令行上使用。 命令SET并不是真正需要的。 但是代码根本不会创建目录，因为MOVE不会像ROBOCOPY那样自动创建目标目录。 动态变量DATE的日期字符串值必须采用ddd dd/MM/yyyy格式，才能真正获得日期格式MMddyyyy的文件夹名称。

---

附加信息

要了解使用的命令及其工作原理，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• md /?
• move /?
• robocopy /?
• set /?
• setlocal /?
• wmic /?
• wmic os /?
• wmic os get /?
• wmic os get localdatetime /?

PS：还有许多其他解决方案可以以特定格式获取当前日期/时间，独立于为所用帐户配置的国家/地区。 所有这些替代解决方案都可以在以下答案中找到：

如何以适合文件/文件夹名称的格式在 Windows 命令行上获取当前日期/时间？

Answer 7

我自己在这个问题上遇到了麻烦，但不用多说，将您的源文件夹放在.bat文件之后：

yourscript.bat c:\users\myname\Desktop\sourcefolder

希望对其他人有所帮助，花了我几秒钟的时间：D