带Dephi的SAPI：异步语音不起作用

Question

以下内容可以完美运行（Delphi 7）：

procedure TMainForm.SayIt(s:string); // s is the string to be spoken
var
voice: OLEVariant;
begin
  memo1.setfocus;
  voice := CreateOLEObject ('SAPI.SpVoice');
  voice.Voice := voice.GetVoices.Item(combobox1.ItemIndex); // current voice selected
  voice.volume := tbVolume.position;
  voice.rate := tbRate.position;
  voice.Speak (s, SVSFDefault);
end;

上面的工作在“同步”模式下（ SVSFDefault标志），但是如果我尝试将标志更改为SVSFlagsAsync以尝试在异步模式下播放声音，则不会产生声音。 没有给出错误消息，但是扬声器上没有任何声音。

可能是什么问题？ 我在Delphi的Imports文件夹中有SpeechLib_TLB单元。

编辑：这是在Windows XP中

谢谢，布鲁诺。

Answer 1

当您使用SVSFlagsAsync标志时，语音流会在内部缓冲区中排队，并等待由语音服务执行。因此，我认为您发出的语音与语音对象的生命周期有关，因为它是局部变量，实例在执行声音之前被销毁。

解决方法是，可以使用WaitUntilDone方法等待声音

  voice.Speak (s, SVSFlagsAsync);
  repeat  Sleep(100); until  voice.WaitUntilDone(10);

或在表单定义中声明voice变量。

  TMainForm = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
   voice: OLEVariant;
   procedure SayIt(const s:string);
  end;

var
  MainForm: TMainForm;

implementation

uses
   ComObj;

{$R *.dfm}
procedure TMainForm.SayIt(const s:string); // s is the string to be spoken
const
  SVSFDefault = 0;
  SVSFlagsAsync = 1;
  SVSFPurgeBeforeSpeak= 2;
begin
  memo1.setfocus;
  voice.Voice := voice.GetVoices.Item(combobox1.ItemIndex); // current voice selected
  voice.volume := tbVolume.position;
  voice.rate := tbRate.position;
  voice.Speak (s, SVSFlagsAsync {or SVSFPurgeBeforeSpeak});
end;


procedure TMainForm.Button1Click(Sender: TObject);
begin
  SayIt('Hello');
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  voice := CreateOLEObject('SAPI.SpVoice');
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  voice  := Unassigned;
end;

end.

另外请注意，由于您使用的是后期绑定，因此不需要SpeechLib_TLB单元。