批处理脚本获取远程文件的上次修改日期

Question

我正在尝试运行一个批处理脚本，该脚本将查找特定文件的最后修改日期。 我正在使用类似于以下脚本的内容：

@echo off

set mainDir=\\subdomain.myintranet.net\c$
set txtFile=%mainDir%\tmp.txt
set txtFile2=%mainDir%\tmp2.txt
set "bodyText=^<p^>Hello,^<br /^>^<br /^>"

if exist %txtFile% (
    for %%X in (%txtFile%) do (set fileDate=%%~tX)
    set "bodyText=%bodyText%tmp.txt file updated as of %fileDate%^<br /^>"
) else (
    set "bodyText=%bodyText%Warning: Issues finding %txtFile%.^<br /^>"
)

if exist %txtFile2% (
    for %%X in (%txtFile2%) do (set fileDate2=%%~tX)
    set "bodyText=%bodyText%tmp2.txt file updated as of %fileDate2%^<br /^>"
) else (
    set "bodyText=%bodyText%Warning: Issues finding %txtFile2%.^<br /^>"
)

set "bodyText=%bodyText%^</p^>"

echo %bodyText% > %mainDir%\mylog.txt

测试该示例代码后，我发现它有时可以工作，有时不能。 发生的情况是找到了文件，但是fileDate变量fileDate变回空白。

我也曾尝试在脚本的开头放置一个空变量fileDate= ，但这没有用。

如果很重要：我已将批处理脚本连接到每天运行的SQL Server 2000作业。 批处理文件和日志文件与数据库位于同一台服务器上，但是批处理脚本完全限定了文件位置，如我在示例中所示（这是因为如果我要从桌面运行批处理文件，它将检查/更新正确的文件）。

预先感谢，约瑟夫

编辑：

输出应如下所示：

Hello,

tmp.txt file updated as of 9/19/2012 2:24 PM 
tmp2.txt file updated as of 9/19/2012 10:02 AM

而我有时会得到的是：

Hello,

tmp.txt file updated as of 
tmp2.txt file updated as of 

其他时候我可能会得到：

Hello,

tmp.txt file updated as of 9/19/2012 2:24 PM 
tmp2.txt file updated as of 

弄清楚出了什么问题是令人困惑的。

Answer 1

呻吟...

这一定是Windows批处理开发中最常见的错误。 您试图扩展在同一代码块中设置的变量。 但是，当解析整个代码块时，变量将被扩展，因此您将获得在执行代码块之前存在的值。 那显然是行不通的。

输入HELP SET或SET /? 从命令提示符处，并阅读“延迟扩展”部分。 这显示了解决问题的一种方法。

但是在您的情况下，您根本不需要该变量，因此您不需要延迟扩展。 追加到bodyText时，只需直接使用FOR变量即可：

@echo off

set mainDir=\\subdomain.myintranet.net\c$
set txtFile=%mainDir%\tmp.txt
set txtFile2=%mainDir%\tmp2.txt
set "bodyText=^<p^>Hello,^<br /^>^<br /^>"

if exist %txtFile% (
    for %%X in (%txtFile%) do set "bodyText=%bodyText%tmp.txt file updated as of %%~tX^<br /^>"
) else (
    set "bodyText=%bodyText%Warning: Issues finding %txtFile%.^<br /^>"
)

if exist %txtFile2% (
    for %%X in (%txtFile2%) do set "bodyText=%bodyText%tmp2.txt file updated as of %%~tX^<br /^>"
) else (
    set "bodyText=%bodyText%Warning: Issues finding %txtFile2%.^<br /^>"
)

set "bodyText=%bodyText%^</p^>"

echo %bodyText% > %mainDir%\mylog.txt

编辑

还有更多的简化空间，应使代码易于维护。 由于您正在准备HTML文件，因此没有理由担心其他换行符，因此您不必将所有文本都放入一个变量中。 您可以使用多个ECHO语句。 我会像下面这样构造您的代码（未经测试，但是概念很合理）：

@echo off
setlocal
set "mainDir=\\subdomain.myintranet.net\c$"
set "br=^<br /^>"
set "p=^<p^>"
set "/p=^</p^>"
>"%mainDir%\mylog.txt" (
  echo %p%Hello,%br%%br%"
  for %%F in (
    "%mainDir%\tmp.txt"
    "%mainDir%\tmp2.txt"
  ) do (
    if exist %%F (
      echo %%~nxF file updated as of %%~tF%br%"
    ) else (
      echo Warning: Issues finding %%~nxF.%br%"
    )
  echo %/p%
)