如何以适合在文件/文件夹名称中使用的格式在 Windows 命令行上获取当前日期/时间？

Question

更新：现在是 2016 年，我会为此使用 PowerShell ，除非有一个真正令人信服的向后兼容原因，特别是因为使用date的区域设置问题。 请参阅@npocmaka 的https://stackoverflow.com/a/19799236/8479

---

什么是 Windows 命令行语句，我可以使用我可以放入文件名的格式获取当前日期时间？

我想要一个 .bat 文件，它将目录压缩到存档中，并将当前日期和时间作为名称的一部分，例如Code_2008-10-14_2257.zip 。 有没有什么简单的方法可以做到这一点，独立于机器的区域设置？

我真的不介意日期格式，理想情况下它是 yyyy-mm-dd，但任何简单的都可以。

到目前为止，我已经得到了这个，它在我的机器上给了我Tue_10_14_2008_230050_91 ：

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new ZIP file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.zip Code

我可以忍受这个，但它似乎有点笨拙。 理想情况下，它会更简短，并具有前面提到的格式。

我正在使用 Windows Server 2003 和 Windows XP Professional。 我不想安装额外的实用程序来实现这一点（尽管我意识到有些可以很好地格式化日期）。

Answer 1

请参阅Windows 批处理文件 (.bat) 以 MMDDYYYY 格式获取当前日期：

@echo off
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime%

如果您更喜欢 24 小时/军用格式的时间，您可以将第二个 FOR 行替换为：

For /f "tokens=1-2 delims=/:" %%a in ("%TIME%") do (set mytime=%%a%%b)

C:> .\\date.bat
2008-10-14_0642

如果您想要独立于区域日/月顺序的日期，您可以使用“WMIC os GET LocalDateTime”作为源，因为它是按 ISO 顺序排列的：

@echo off
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
set ldt=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2% %ldt:~8,2%:%ldt:~10,2%:%ldt:~12,6%
echo Local date is [%ldt%]

C:>test.cmd
本地日期是 [2012-06-19 10:23:47.048]

Answer 2

区域独立的日期时间解析

%DATE%和dir命令的输出格式是区域相关的，因此既不可靠也不智能。 date.exe （ UnxUtils 的一部分）以任何可想到的格式提供任何日期和时间信息。 您还可以使用date.exe从任何文件中提取日期/时间信息。

示例：（在 cmd 脚本中使用 %% 而不是 %）

date.exe +"%Y-%m-%d"
2009-12-22

date.exe +"%T"
18:55:03

date.exe +"%Y%m%d %H%M%S: Any text"
20091222 185503：任何文字

date.exe +"Text: %y/%m/%d-any text-%H.%M"
文本：09/12/22-任何文本-18.55

Command: date.exe +"%m-%d """%H %M %S """"
07-22 "18:55:03"`

参考文件中的日期/时间信息：
date.exe -rc:\\file.txt +"The timestamp of file.txt is: %Y-%m-%d %H:%M:%S"

在 CMD 脚本中使用它来获取年、月、日、时间信息：

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

在 CMD 脚本中使用它以获取任何所需格式的时间戳：

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe +"%%y-%%m-%%d %%H:%%M:%%S"') do set timestamp=%%i

从任何参考文件中提取日期/时间信息。

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

将其日期/时间信息添加到文件中：

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y-%%m-%%d.%%H%%M%%S"') do ren file.txt file.%%i.txt

date.exe 是不需要安装的免费 G​​NU 工具的一部分。

注意：将date.exe复制到搜索路径中的任何目录可能会导致其他使用 Windows 内置date命令的脚本失败。

Answer 3

另外两种不依赖于时间设置的方法（均取自：How get data/time Independent from localization: ）。 并且两者都可以获得星期几，并且都不需要管理员权限！：

1. MAKECAB - 将适用于每个 Windows 系统（速度快，但会创建一个小的临时文件）（foxidrive 脚本）：

    @echo off pushd "%temp%" makecab /D RptFileName=~.rpt /D InfFileName=~.inf /f nul >nul for /f "tokens=3-7" %%a in ('find /i "makecab"^<~.rpt') do ( set "current-date=%%e-%%b-%%c" set "current-time=%%d" set "weekday=%%a" ) del ~.* popd echo %weekday% %current-date% %current-time% pause

   有关 get-date 函数的更多信息。

2. ROBOCOPY - 它不是 Windows XP 和 Windows Server 2003 的本机命令，但可以 从 microsoft 站点下载。 但是内置于 Windows Vista 及更高版本的所有内容中：

    @echo off setlocal for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \\ \\ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do ( set "dow=%%D" set "month=%%E" set "day=%%F" set "HH=%%G" set "MM=%%H" set "SS=%%I" set "year=%%J" ) echo Day of the week: %dow% echo Day of the month : %day% echo Month : %month% echo hour : %HH% echo minutes : %MM% echo seconds : %SS% echo year : %year% endlocal

   以及另外三种使用其他 Windows 脚本语言的方式。 它们将为您提供更大的灵活性，例如您可以获得一年中的一周、以毫秒为单位的时间等等。

3. JScript/批处理混合（需要另存为.bat ）。 JScript 可用于 NT 及更高版本的每个系统，作为Windows Script Host的一部分（虽然可以通过注册表禁用，但这种情况很少见）：

    @if (@X)==(@Y) @end /* ---Harmless hybrid line that begins a JScript comment @echo off cscript //E:JScript //nologo "%~f0" exit /b 0 *------------------------------------------------------------------------------*/ function GetCurrentDate() { // Today date time which will used to set as default date. var todayDate = new Date(); todayDate = todayDate.getFullYear() + "-" + ("0" + (todayDate.getMonth() + 1)).slice(-2) + "-" + ("0" + todayDate.getDate()).slice(-2) + " " + ("0" + todayDate.getHours()).slice(-2) + ":" + ("0" + todayDate.getMinutes()).slice(-2); return todayDate; } WScript.Echo(GetCurrentDate());

4. VSCRIPT/BATCH混合（ 是否可以在不使用临时文件的情况下在批处理文件中嵌入和执行 VBScript？ ）与 JScript 相同的情况，但混合不是那么完美：

    :sub echo(str) :end sub echo off '>nul 2>&1|| copy /Y %windir%\\System32\\doskey.exe %windir%\\System32\\'.exe >nul '& echo current date: '& cscript /nologo /E:vbscript "%~f0" '& exit /b '0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM. '1 = vbLongDate - Returns date: weekday, monthname, year '2 = vbShortDate - Returns date: mm/dd/yy '3 = vbLongTime - Returns time: hh:mm:ss PM/AM '4 = vbShortTime - Return time: hh:mm WScript.echo Replace(FormatDateTime(Date,1),", ","-")

5. PowerShell - 可以安装在每台具有 .NET 的机器上 - 从 Microsoft 下载（ v1 、 v2 、 v3 （仅适用于 Windows 7 及更高版本））。 它默认安装在 Windows 7/Windows Server 2008 及更高版本上：

    C:\\> powershell get-date -format "{dd-MMM-yyyy HH:mm}"

   要从批处理文件中使用它：

    for /f "delims=" %%# in ('powershell get-date -format "{dd-MMM-yyyy HH:mm}"') do @set _date=%%#

6. 自编译jscript.net/batch （从来没有见过没有.NET的Windows机器，所以我认为这是一个非常便携的）：

    @if (@X)==(@Y) @end /****** silent line that start JScript comment ****** @echo off :::::::::::::::::::::::::::::::::::: ::: Compile the script :::: :::::::::::::::::::::::::::::::::::: setlocal if exist "%~n0.exe" goto :skip_compilation set "frm=%SystemRoot%\\Microsoft.NET\\Framework\\" :: Searching the latest installed .NET framework for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\\Microsoft.NET\\Framework\\v*"') do ( if exist "%%v\\jsc.exe" ( rem :: the javascript.net compiler set "jsc=%%~dpsnfxv\\jsc.exe" goto :break_loop ) ) echo jsc.exe not found && exit /b 0 :break_loop call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0" :::::::::::::::::::::::::::::::::::: ::: End of compilation :::: :::::::::::::::::::::::::::::::::::: :skip_compilation "%~n0.exe" exit /b 0 ****** End of JScript comment ******/ import System; import System.IO; var dt=DateTime.Now; Console.WriteLine(dt.ToString("yyyy-MM-dd hh:mm:ss"));

7. Logman这无法获得一周中的年份和日期。 它相对较慢，还会创建一个临时文件，并且基于 logman 放在其日志文件上的时间戳。 它将适用于 Windows XP 及更高版本的所有内容。 它可能永远不会被任何人使用 - 包括我 - 但它是另一种方式......

    @echo off setlocal del /q /f %temp%\\timestampfile_* Logman.exe stop ts-CPU 1>nul 2>&1 Logman.exe delete ts-CPU 1>nul 2>&1 Logman.exe create counter ts-CPU -sc 2 -v mmddhhmm -max 250 -c "\\Processor(_Total)\\%% Processor Time" -o %temp%\\timestampfile_ >nul Logman.exe start ts-CPU 1>nul 2>&1 Logman.exe stop ts-CPU >nul 2>&1 Logman.exe delete ts-CPU >nul 2>&1 for /f "tokens=2 delims=_." %%t in ('dir /b %temp%\\timestampfile_*^&del /q/f %temp%\\timestampfile_*') do set timestamp=%%t echo %timestamp% echo MM: %timestamp:~0,2% echo dd: %timestamp:~2,2% echo hh: %timestamp:~4,2% echo mm: %timestamp:~6,2% endlocal exit /b 0

8. 使用WMIC 的另一种方法，它也给出了一年中的一周和一周中的哪一天，但不是毫秒（毫秒，请查看 foxidrive 的答案）：

    for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@ echo %day% echo %DayOfWeek% echo %hour% echo %minute% echo %month% echo %quarter% echo %second% echo %weekinmonth% echo %year%

9. 努力使用TYPEPERF以尽可能快地与不同的语言设置兼容：

    @echo off setlocal :: Check if Windows is Windows XP and use Windows XP valid counter for UDP performance ::if defined USERDOMAIN_roamingprofile (set "v=v4") else (set "v=") for /f "tokens=4 delims=. " %%# in ('ver') do if %%# GTR 5 (set "v=v4") else ("v=") set "mon=" for /f "skip=2 delims=," %%# in ('typeperf "\\UDP%v%\\*" -si 0 -sc 1') do ( if not defined mon ( for /f "tokens=1-7 delims=.:/ " %%a in (%%#) do ( set mon=%%a set date=%%b set year=%%c set hour=%%d set minute=%%e set sec=%%f set ms=%%g ) ) ) echo %year%.%mon%.%date% echo %hour%:%minute%:%sec%.%ms% endlocal

10. MSHTA允许调用类似于上面 #3 中演示的 JScript 方法的 JavaScript 方法。 请记住，JavaScript 的 Date 对象属性涉及月份值的编号是从 0 到 11，而不是 1 到 12。所以值 9 表示十月。

     <!-- : Batch portion @echo off setlocal for /f "delims=" %%I in ('mshta "%~f0"') do set "now.%%~I" rem Display all variables beginning with "now." set now. goto :EOF end batch / begin HTA --> <script> resizeTo(0,0) var fso = new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1), now = new Date(), props=['getDate','getDay','getFullYear','getHours','getMilliseconds','getMinutes', 'getMonth','getSeconds','getTime','getTimezoneOffset','getUTCDate','getUTCDay', 'getUTCFullYear','getUTCHours','getUTCMilliseconds','getUTCMinutes','getUTCMonth', 'getUTCSeconds','getYear','toDateString','toGMTString','toLocaleDateString', 'toLocaleTimeString','toString','toTimeString','toUTCString','valueOf'], output = []; for (var i in props) {output.push(props[i] + '()=' + now[props[i]]())} close(fso.Write(output.join('\\n'))); </script>

Answer 4

这是 alt.msdos.batch.nt 的一个变体，它在本地独立工作。

把它放在一个文本文件中，例如 getDate.cmd

-----------8<------8<------------ snip -- snip ----------8<-------------
    :: Works on any NT/2k machine independent of regional date settings
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
    for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
      for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
        set '%%a'=%%i
        set '%%b'=%%j
        set '%%c'=%%k))
    if %'yy'% LSS 100 set 'yy'=20%'yy'%
    set Today=%'yy'%-%'mm'%-%'dd'% 
    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]

    :EOF
-----------8<------8<------------ snip -- snip ----------8<-------------

为了让代码在没有错误 msg 到 stderr 的情况下工作，我必须在 %%a、%%b 和 %%c 的变量赋值周围添加单引号。 我的语言环境 (PT) 在循环/解析的某个阶段导致错误，其中正在执行诸如“set = 20”之类的内容。 引号为赋值语句的左侧生成一个标记（尽管是空的）。

缺点是语言环境变量名称凌乱：“yy”、“mm”和“dd”。 但是，嘿，谁在乎！

Answer 5

我使用这个（同样不是地区独立的（英国））

set bklog=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%%time:~3,2%

Answer 6

此代码的前四行将在 Windows XP Professional 及更高版本中为您提供可靠的 YY DD MM YYYY HH Min Sec 变量。

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

Answer 7

不幸的是，这并不能不受区域设置的影响，但它可以满足您的需求。

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

您可以在Wikipedia 上找到令人惊奇的东西。

Answer 8

请使用以下脚本在命令行中获取当前日期：

echo %Date:~0,3%day

Answer 9

另一种方式（ 信用）：

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

请注意，我在这里的两个答案仍然依赖于由区域设置确定的日期和月份的顺序 - 不知道如何解决这个问题。

Answer 10

"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

Answer 11

这并不是更简洁，但可能是一种更灵活的方式（ 信用）：

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%

Answer 12

这是一种在一行中获取日期时间的方法：

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %a in ('%date% %time%') do echo %c-%a-%b %d%e

在美国，这将输出“yyyy-mm-dd hhmm”。 不同的区域设置会导致不同的 %date% 输出，但您可以修改令牌顺序。

如果您想要不同的格式，请通过重新排列标记或使用不同（或不使用）分隔符来修改 echo 语句。

Answer 13

Matthew Johnson获得单行日期和时间的单行解决方案是雄辩且有用的。

然而，它确实需要一个简单的修改才能在批处理文件中工作：

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %%a in ('%date% %time%') do echo %%c-%%a-%%b %%d%%e

Answer 14

只需使用这一行：

PowerShell -Command "get-date"

Answer 15

简短的回答：

 :: Start - Run , type:
 cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"

 :: click into target media, Ctrl + V to paste the result 

长答案

    @echo off
    :: START USAGE  ==================================================================
    ::SET THE NICETIME 
    :: SET NICETIME=BOO
    :: CALL GetNiceTime.cmd 

    :: ECHO NICETIME IS %NICETIME%

    :: echo nice time is %NICETIME%
    :: END USAGE  ==================================================================

    echo set hhmmsss
    :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c 
    ::DEBUG ECHO hhmmsss IS %hhmmsss%
    ::DEBUG PAUSE
    echo %yyyymmdd%
        :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
    ::DEBUG ECHO yyyymmdd IS %yyyymmdd%
    ::DEBUG PAUSE


    set NICETIME=%yyyymmdd%_%hhmmsss%
    ::DEBUG echo THE NICETIME IS %NICETIME%

    ::DEBUG PAUSE

Answer 16

我使用vMax的批处理文件更改了答案，因此它也适用于荷兰语。
荷兰语 - 像我们一样持久 - 在%date% 、 date/t和date中有一些更改，这些更改破坏了原始批处理文件。

如果有些人也可以针对其他 Windows 语言环境进行检查，并报告结果，那就太好了。
如果批处理文件在您的位置失败，请在命令提示符中包含这两个语句的输出：
echo:^|date
date/t

这是您应该从批处理文件中获得的输出示例：

C:\temp>set-date-cmd.bat
Today is Year: [2011] Month: [01] Day: [03]
20110103

这是修订后的代码，其中包含对原因的评论：

:: https://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional date settings
::
:: 20110103 - adapted by jeroen@pluimers.com for Dutch locale
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy'
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date
::            set '%%c'=%%k
::            set 'yy'=%%k
::
:: In addition, date will display the current date before the input prompt using dashes
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch
:: and one occurence in English.
:: This skips the first iteration:
::        if "%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
    set v_day=
    set v_month=
    set v_year=

    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::DEBUG echo toks=%toks%
      for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
        if "%%a" GEQ "A" (
          for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
            set '%%a'=%%i
            set '%%b'=%%j
            set 'yy'=%%k
          )
        )
      )
      if %'yy'% LSS 100 set 'yy'=20%'yy'%
      set Today=%'yy'%-%'mm'%-%'dd'%

    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
    set datestring=%V_Year%%V_Month%%V_Day%
    echo %datestring%

    :EOF

--杰罗恩

Answer 17

这是时间部分的类似批处理文件。

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional time settings
::
:: Gets the time in ISO 8601 24-hour format
::
:: Note that %time% gets you fractions of seconds, and time /t doesn't, but gets you AM/PM if your locale supports that.
:: Since ISO 8601 does not care about AM/PM, we use %time%
::
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    for /f "tokens=1-4 delims=:,.-/ " %%i in ('echo %time%') do (
      set 'hh'=%%i
      set 'mm'=%%j
      set 'ss'=%%k
      set 'ff'=%%l)
    ENDLOCAL & SET v_Hour=%'hh'%& SET v_Minute=%'mm'%& SET v_Second=%'ss'%& SET v_Fraction=%'ff'%

    ECHO Now is Hour: [%V_Hour%] Minute: [%V_Minute%] Second: [%v_Second%] Fraction: [%v_Fraction%]
    set timestring=%V_Hour%%V_Minute%%v_Second%.%v_Fraction%
    echo %timestring%

    :EOF

--杰罗恩

Answer 18

这是我用过的：

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

---

如果您想要更多关于自动备份到 7-Zip 档案的想法，我有一个免费/开放的项目，您可以使用或查看想法： http : //wittman.org/ziparcy/

Answer 19

基于wmic函数：

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
  setlocal
  for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
  endlocal & (
    if "%~1" neq "" set %~1=%T:~0,4%
    if "%~2" neq "" set %~2=%T:~4,2%
    if "%~3" neq "" set %~3=%T:~6,2%
    if "%~4" neq "" set %~4=%T:~8,2%
    if "%~5" neq "" set %~5=%T:~10,2%
    if "%~6" neq "" set %~6=%T:~12,2%
  )
goto:eof

好处：区域独立。 缺点：只有系统管理员才能运行 wmic.exe。

用法：

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

这会回显这样的字符串：

2014-01-22 12:51:53

请注意，函数参数是 out-Parameters - 也就是说，您必须提供变量名称而不是值。

所有参数都是可选的，所以如果你只想得到年和月，那么call:Now YM是一个有效的调用。

Answer 20

我有一个类似的问题。 我每天从 FTP 服务器自动下载加密文件。 我想使用 gpg 解密文件，将文件重命名为当前日期（YYYYMMDD 格式），并将解密后的文件放入正确部门的文件夹中。

我经历了一些根据日期重命名文件的建议，但在我偶然发现这个简单的解决方案之前一直没有运气。

for /f "tokens=1-5 delims=/ " %%d in ("%date%") do rename "decrypted.txt" %%g-%%e-%%f.txt

它工作得很好（即文件名显示为“2011-06-14.txt”）。

（来源）

Answer 21

http://sourceforge.net/projects/unxutils/files/

在 ZIP 文件中查找名为“Date.exe”的内容并将其重命名为“DateFormat.exe”（以避免冲突）。

把它放在你的 Windows system32 文件夹中。

它有很多“日期输出”选项。

如需帮助，请使用DateFormat.exe --h

我不确定您将如何将其输出放入环境变量中……使用 SET。

Answer 22

生成 ISO 日期格式的区域独立解决方案：

rem save the existing format definition
for /f "skip=2 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate') do set FORMAT=%%a
rem set ISO specific format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d yyyy-MM-dd 1>nul:
rem query the date in the ISO specific format 
set ISODATE=%DATE%
rem restore previous format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d %FORMAT% 1>nul:

仍然可以优化的内容：如果在修改的短时间内使用日期格式，其他进程可能会感到困惑。 因此，根据现有格式字符串解析输出可能更“安全” - 但会更复杂

Answer 23

:: GetDate.cmd -> Uses WMIC.exe to get current date and time in ISO 8601 format
:: - Sets environment variables %_isotime% and %_now% to current time
:: - On failure, clears these environment variables
:: Inspired on -> https://ss64.com/nt/syntax-getdate.html
:: - (cX) 2017 adolfo.dimare@gmail.com
:: - http://stackoverflow.com/questions/203090
@echo off

set _isotime=
set _now=

:: Check that WMIC.exe is available
WMIC.exe Alias /? >NUL 2>&1 || goto _WMIC_MISSING_

if not (%1)==() goto _help
SetLocal EnableDelayedExpansion

:: Use WMIC.exe to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC.exe Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
    IF "%%~L"=="" goto  _WMIC_done_
        set _yyyy=%%L
        set _mm=00%%J
        set _dd=00%%G
        set _hour=00%%H
        set _minute=00%%I
        set _second=00%%K
)
:_WMIC_done_

::   1    2     3       4      5      6
:: %%G  %%H    %%I     %%J    %%K    %%L
:: Day  Hour  Minute  Month  Second  Year
:: 27   9     35      4      38      2017

:: Remove excess leading zeroes
        set _mm=%_mm:~-2%
        set _dd=%_dd:~-2%
        set _hour=%_hour:~-2%
        set _minute=%_minute:~-2%
        set _second=%_second:~-2%
:: Syntax -> %variable:~num_chars_to_skip,num_chars_to_keep%

:: Set date/time in ISO 8601 format:
        Set _isotime=%_yyyy%-%_mm%-%_dd%T%_hour%:%_minute%:%_second%
:: -> http://google.com/search?num=100&q=ISO+8601+format

if 1%_hour% LSS 112 set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%am
if 1%_hour% LSS 112 goto _skip_12_
    set /a _hour=1%_hour%-12
    set _hour=%_hour:~-2%
    set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%pm
    :: -> https://ss64.com/nt/if.html
    :: -> http://google.com/search?num=100&q=SetLocal+EndLocal+Windows
    :: 'if () else ()' will NOT set %_now% correctly !?
:_skip_12_

EndLocal & set _isotime=%_isotime% & set _now=%_now%
goto _out

:_WMIC_MISSING_
echo.
echo WMIC.exe command not available
echo - WMIC.exe needs Administrator privileges to run in Windows
echo - Usually the path to WMIC.exe is "%windir%\System32\wbem\WMIC.exe"

:_help
echo.
echo GetDate.cmd: Uses WMIC.exe to get current date and time in ISO 8601 format
echo.
echo    %%_now%%     environment variable set to current date and time
echo    %%_isotime%% environment variable to current time in ISO format
echo    set _today=%%_isotime:~0,10%%
echo.

:_out
:: EOF: GetDate.cmd

Answer 24

将Powershell合并到一个批处理文件中，并使用元变量来分配每个：

@echo off
for /f "tokens=1-6 delims=-" %%a in ('PowerShell -Command "& {Get-Date -format "yyyy-MM-dd-HH-mm-ss"}"') do (
    echo year: %%a
    echo month: %%b
    echo day: %%c
    echo hour: %%d
    echo minute: %%e
    echo second: %%f
)

如果您更喜欢月份名称MMM或MMMM以及 12 小时到 24 小时格式hh或HH您也可以更改格式

Answer 25

• 我使用了date.exe ，并将其重命名为date_unxutils.exe以避免冲突。

• 将它放在批处理脚本旁边的bin文件夹中。

代码

:: Add binaries to temp path
IF EXIST bin SET PATH=%PATH%;bin

:: Create UTC Timestamp string in a custom format
:: Example: 20210128172058
set timestamp_command='date_unxutils.exe -u +"%%Y%%m%%d%%H%%M%%S"'
FOR /F %%i IN (%timestamp_command%) DO set timestamp=%%i
echo %timestamp%

下载 UnxUtils

• 链接。

参考

• 我建立在这个很棒的答案上。

Answer 26

PowerShell 试试下面的代码。 它将在 24 小时内创建日期为 ddmmyyhhmm 的文件或文件夹变量

[int] $day = Get-Date -UFormat %d
[int] $month = Get-Date -UFormat %m
[int] $year = Get-Date -UFormat %y
[String] $date = "$($day)$($month)$($year)"
$time = Get-Date -UFormat %R
$time -replace ‘[:]’,”"
$fileFolderName = $date + time

Answer 27

给定一个已知位置，以函数形式参考。 ECHOTIMESTAMP调用显示了如何将时间戳放入变量（本例中为DTS ）。

@ECHO off

CALL :ECHOTIMESTAMP
GOTO END

:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
    SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
    SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
    SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF

:ECHOTIMESTAMP
SETLOCAL
    CALL :TIMESTAMP DTS
    ECHO %DTS%
ENDLOCAL
GOTO :EOF

:END

EXIT /b 0

并保存到文件，timestamp.bat，输出如下：

Answer 28

对于 Windows 7，此代码适用于我：

SET DATE=%date%
SET YEAR=%DATE:~0,4%
SET MONTH=%DATE:~5,2%
SET DAY=%DATE:~8,2%
ECHO %YEAR%
ECHO %MONTH%
ECHO %DAY%

SET DATE_FRM=%YEAR%-%MONTH%-%DAY% 
ECHO %DATE_FRM%

Answer 29

我知道已经提到了很多方法。 但这是我分解它以了解它是如何完成的方法。 希望对喜欢循序渐进方法的人有所帮助。

:: Check your local date format
echo %date%

    :: Output is Mon 08/15/2016

:: get day (start index, number of characters)
::         (index starts with zero)
set myday=%DATE:~0,4%
echo %myday%
    :: output is Mon 

:: get month
set mymonth=%DATE:~4,2%
echo %mymonth%
    :: output is 08

:: get date 
set mydate=%DATE:~7,2% 
echo %mydate%
    :: output is 15

:: get year
set myyear=%DATE:~10,4%
echo %myyear%
    :: output is 2016

Answer 30

我注意到，O / P没有要求的区域，独立的解决方案。 不过，我的解决方案是针对英国的。

这是在批处理文件中使用的最简单的可能解决方案，即 1 行解决方案：

FOR /F "tokens=1-3 delims=/" %%A IN ("%date%") DO (SET today=%%C-%%B-%%A)
echo %today%