如何在VBA表单上显示Excel的一部分

Question

我有一个.csv格式的文件，并且来自AS列，它有一些记录，例如表格。 我完整的程序将插入/删除/删除/添加一些行，列和编辑单元格值等。我设法编写了我需要的所有操作，现在我正尝试将其与gui集成。

我想要的是显示从Ax1到VBA用户窗体上已记录的最后一列的单元格。 我怎样才能做到这一点？

* ps：同样，我的文件格式为.csv，我正在使用Excel 2007

Answer 1

您可以使用多列列表框显示数据。

逻辑

1. 在临时表中导入文本（Csv）文件
2. 在多列列表框中显示该数据
3. 删除用户表单卸载事件中的临时表

在临时表中导入文本（Csv）文件

Private Sub CommandButton1_Click()
    Dim wb As Workbook, wbTemp As Workbook
    Dim wsTemp As Worksheet

    Set wb = ThisWorkbook
    Set wbTemp = Workbooks.Open("C:\MyCsv.Csv")

    wbTemp.Sheets(1).Copy After:=wb.Sheets(wb.Sheets.Count)

    Set wsTemp = ActiveSheet

    wbTemp.Close SaveChanges:=False
End Sub

现在，您可以在多列列表框中显示该数据。

在多列列表框中显示该数据

我以3列为例，直到拖曳20个。

Private Sub CommandButton1_Click()
    Dim wb As Workbook, wbTemp As Workbook
    Dim wsTemp As Worksheet

    Set wb = ThisWorkbook
    Set wbTemp = Workbooks.Open("C:\MyCsv.Csv")

    wbTemp.Sheets(1).Copy After:=wb.Sheets(wb.Sheets.Count)


    Set wsTemp = ActiveSheet

    wbTemp.Close SaveChanges:=False

    With ListBox1
        .ColumnCount = 3
        .ColumnWidths = "50;50;50"
        .RowSource = wsTemp.Range("A1:C20").Address
    End With
End Sub

屏幕截图

删除用户表单卸载事件中的临时表

要删除临时表，请在代码顶部声明wsTemp ，以便您可以在UserForm_QueryClose事件中访问它。 看到这个完整的例子

Option Explicit

Dim wsTemp As Worksheet

Private Sub CommandButton1_Click()
    Dim wb As Workbook, wbTemp As Workbook


    Set wb = ThisWorkbook
    Set wbTemp = Workbooks.Open("C:\MyCsv.Csv")

    wbTemp.Sheets(1).Copy After:=wb.Sheets(wb.Sheets.Count)


    Set wsTemp = ActiveSheet

    wbTemp.Close SaveChanges:=False

    With ListBox1
        .ColumnCount = 3
        .ColumnWidths = "50;50;50"
        .RowSource = wsTemp.Range("A1:C20").Address
    End With
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    Application.DisplayAlerts = False
    wsTemp.Delete
    Application.DisplayAlerts = True
End Sub

高温超导