将小的正则表达式转换为DCG

Question

我知道Prolog程序员通常使用DCG而不是正则表达式来匹配字符串中的模式。 在Perl中，可能会写

if ( '... accd' =~ /a+b*c{2,4}d$/ ) {
    say "matched";
}

如何在Prolog中匹配相同的模式？

Answer 1

我已经扩展了这个答案

:- op(100, xf, *).
:- op(100, xf, +).

rexp(C) --> [C].

rexp([T|Ts])   --> rexp(T), rexp(Ts).
rexp([])       --> [].

rexp(eps)      --> [].

rexp(_*)       --> [].
rexp(R*)       --> rexp(R), rexp(R*).

rexp(R+)       --> rexp(R), rexp(R*).

rexp((R1|R2))  --> ( rexp(R1) ; rexp(R2) ).

rexp(range(R,N,M)) -->
    {between(N,M,L),
     length(D,L),
     maplist(copy_term(R),D)
    }, rexp(D).

那么您的正则表达式匹配可能是

?-  phrase(rexp([a+, b*, range(c,2,4), d]), [a,c,c,d]),
    writeln(matched).

请注意，通过这种方式，我们匹配原子而不是单个字符。

在假评论后编辑 ，我认为第一个子句应阅读

rexp(C) --> {atomic(C)}, [C].

避免例如

?- phrase(rexp([a+]), [a+]).
true ;

确实，校正之后，我们可以得到预期的结果：

?- phrase(rexp([a+]), [a+]).
false.

完成编辑

除了解释正则表达式外，还可以对模式进行“硬编码”（容易得多）

% I prefer the equivalent clause below
% p1 --> "a", p1 ; "a", p2.
p1 --> "a", (p1 ; p2).
p2 --> "b", p2 ; p3.
p3 --> ("cc" ; "ccc" ; "cccc"), "d".

然后

?- phrase(p1, "accd").
true

在这里，我们匹配单个字符（Prolog中的字符串是字符代码列表）