如何解决序言中的密码算术难题

Question

我必须编写一个Prolog程序来解决密码难题。

我需要编写一个函数resolve（[A，M，P，D，Y]），将变量[A，M，P，D，Y]分配给0到9的值，以便满足方程AM + PM = DAY。 每个变量都分配有不同的值，并且A，P和D不能等于0。

我开始编写此函数，但在运行程序时遇到问题。 我将A，P和D的限制设置为不为零。 在研究算法时，我意识到D必须为1，因此我在程序开始时就定义了它。 我为M定义了两个不同的变量（M1和M2），并将它们设置为相等，因为拼图中的不同M应当分配给相同的值。 我为不同的变量分配了位置，并根据难题将它们加起来。 我考虑了随身携带变量携带的任何变量。 我的程序编译了，但是函数没有执行。

solve([A, M1, M2, P, D, Y]):- D is 1,
A/=0,
P/=0,
D/=0,
M1 = M2,
select(M1, [0,2,3,4,5,6,7,8,9], R1),
select(M2, R1, R2),
Y is (M1+M2) mod 10,
C1 is (M1+M2) // 10,
select(Y, R2, R3),
select(A, R3, R4),
select(P, R4, R5),
select(D, R5, R6),
A is (A+P+C1) mod 10,
D is (A+P+C1)// 10.

我究竟做错了什么？ 我的变量定义有问题吗？ 我需要定义两个不同的M变量，还是一个足够？

Answer 1

这是我为您解决难题的方法。 我们仅依靠PROLOG的回溯。 我们首先选择所有变量，然后检查拼图条件。 我认为您不需要定义两个女士。

solve([A,M,P,D,Y]):- 
select(A,[0,1,2,3,4,5,6,7,8,9],WA), % W means Without
not(A=0),
select(M,WA,WMA),
select(P,WMA,WMAP),
not(P=0),
select(D,WMAP,WMAPD),
not(D=0),
select(Y,WMAPD,WMAPDY),
DAY is 100*D+10*A+Y,
AM  is 10*A+M,
PM  is 10*P+M,
DAY is AM+PM.

Answer 2

您写道：“我的程序已编译，但该函数未执行：”

solve([A, M1, M2, P, D, Y]):- D is 1,
    A/=0,

难怪。 首先，Prolog中没有/=运算符。 我假设您的意思是\\= 。 但是A \\= B表示“ A无法与B统一”。 在您的情况下， B为0，但A是尚未设置的逻辑变量。 它可以与任何事物统一。 在实例化了所有涉及的logvar 之后 ，仅应使用\\= 检查不平等！

因此， A \\= 0 失败 。 （另一件事是， M1=M2是多余的，您可以始终使用M ）。

解决此类难题的通用工具是从缩小的领域中进行唯一选择 ：

selectM([A|As],S,Z):- select(A,S,S1),selectM(As,S1,Z).
selectM([],Z,Z).

有了它，您的难题就是

solve([A,M,P,D,Y]):-
  selectM([A,P,D],[1,2,3,4,5,6,7,8,9],R),     % R is the remaining domain
  selectM([M,Y],[0|R],_),                     % don't care what remains
  10*(A+P)+M+M =:= 100*D+10*A+Y.

---

您有一个正确的想法，即在可能的情况下在搜索之前先找出任务。 使用您的方法，可以写成

solve([A,M,P,D,Y]):-    
  selectM([M,A],[0,1,2,3,4,5,6,7,8,9],R),
  A =\= 0,
  Y  is (M+M) mod 10,     % AM+PM=DAY
  C1 is (M+M) // 10,
  A  is (A+P+C1) mod 10,
  D  is (A+P+C1) // 10,
  selectM([P,D,Y],R,_),   % ensure all are different
  p =\= 0, D =\= 0.

同样，我们必须在测试其值之前选择A

Answer 3

除了其他人发表的内容外，我想提出一点不同的看法。

以下解决方案使用GNU Prolog及其CLP（FD）约束。 在所有广泛使用的Prolog系统中都可以使用这种约束。

solution(Vs) :-
        Vs = [A,M,P,D,Y],
        fd_domain(Vs, 0, 9),
                   A*10 + M
                 + P*10 + M
        #= D*100 + A*10 + Y,
        fd_all_different(Vs),
        A #\= 0,
        P #\= 0,
        D #\= 0.

我现在重点介绍在这种情况下使用CLP（FD）约束的一些关键优势 。

首先，很明显，我们可以在这种约束下以极其简单的方式对所有需求建模。 该程序实际上是将您的任务几乎完全转换为内置关系的方法：

• 我需要写一个函数solve（[A，M，P，D，Y]）

  我使用solution/1而不是命令式的solve/1 ，因为该谓词在所有方向上都是有意义的，包括所有变量已绑定到具体整数的特定实例。 在这种情况下，我们可以使用谓词来验证解决方案。 在难题已经完全解决的情况下，将其称为“解决”是没有意义的。 同样，我们可以使用谓词来完成部分实例化的解决方案。 在Prolog中，最好避免使用谓词名称的命令。

• 将变量[A，M，P，D，Y]分配给0到9之间的值

  这通过fd_domain(Vs, 0, 9) 。

• 因此它满足方程AM + PM = DAY。

  因此，等式为A*10 + M + P*10 + M #= D*100 + A*10 + Y 。

• 每个变量分配给不同的值

  这由内置约束fd_all_different/1 。

• 并且A，P和D不能等于0。

  这通过A #\\= 0等表示。

其次，我们可以使用最通用的查询来研究约束传播的影响：

| ?- solution([).

Vs = [_#3(2..8),_#24(5..8),9,1,_#87(0:2..6)]

或者，换句话说：

| ?- solution([A,M,P,D,Y]).

A = _#3(2..8)
D = 1
M = _#24(5..8)
P = 9
Y = _#87(0:2..6)

这证实了您所说的：在这个难题中D 必定为 1。 这还显示了其他一些有趣的事情，这些事情超出了您所发现的范围： P 必须为 9。此外， M边界非常严格，并且A和Y的域也已被大幅修剪。

这表明约束传播已大大减少了搜索空间。

具体解决方案是什么样的？ 这里有一些例子：

| ?- solution(Vs), fd_labeling(Vs).

Vs = [2,5,9,1,0] ? ;

Vs = [2,7,9,1,4] ? ;

Vs = [2,8,9,1,6] ?

yes

第三，您可以运行不同的标签选项来尝试各种搜索策略来探索解决方案空间， 而无需更改或重新编译程序。

最后，大大减少的搜索空间通常会产生更快的程序。 我将其保留为运行一些基准测试的练习，这些基准测试表明在这种情况下基于CLP（FD）的版本要快多少。

有关此重要的声明式范例的更多信息，请参见clpfd 。

Answer 4

我认为您的问题是对D的多个“分配”。首先将D绑定到1，之后不能更改值（Prolog使用统一而不是分配）。 然后两者

...
select(D, R5, R6),
...
D is (A+P+C1)// 10.

D不同于1时将失败