Flex和FLash之间的连接

Question

我正在研究一个项目，该项目基于两个主要部分，第一部分由Flex完成，第二部分是Flash专业项目，包含PROJECTNAME.fla和PROJECTNAME.as文件。 我的问题是我们如何从flex part中在.fla项目中设置一些参数（例如，用户名，用户的图像）。 我按照以下说明主要程序；

1. 通过弹性部件连接到服务器并获取用户状态
2. 运行由Flash专业项目创建的.swf，如上所述
3. 在.swf文件中设置一些参数。

我已经在Google上搜索了很多，但没有找到任何解决方案。 （有些解决方案可将符号转换为flex组件，因为它可用于转换单个符号）。 任何想法将不胜感激。

Answer 1

有几种方法可以将参数从一个swf（在您的情况下为flex）传递到另一个运行时加载的fla.swf：

1.传递加载查询参数：

flex.swf中的代码：

    public function astest()
    {
        var loader:Loader = new Loader();
        addChild(loader);
        loader.load( new URLRequest("astest1.swf?param1=value1&param2=value2"));
    }

从fla.swf访问参数：

public function astest1()
{
    if(stage)
        onAdded();
    else
        addEventListener(Event.ADDED_TO_STAGE, onAdded);
}

protected function onAdded(event:Event = null):void
{
    //root.loaderInfo.parameters - params of this swf file
    //stage.loaderInfo.parameters - params of core swf file
    var params:Object = root.loaderInfo.parameters;
    for (var param:String in params)
        trace(param,"=",params[param]);
}

输出：

param2 = value2
param1 = value1

缺乏这种方法：

-一次使用，加载时只能传递一次参数
-第二个swf必须在运行时由url加载，例如，您不能嵌入它（或带有它的类之一）。

2.通过事件进行运行时通信
我建议使用这种方法，它不缺少上一种方法。
使用stage作为全局公共调度程序的示例。

flex.swf：

    public function astest()
    {
        addEventListener("ready", onReady);
        var loader:Loader = new Loader();
        addChild(loader);
        loader.load( new URLRequest("astest1.swf"));
    }

    protected function onReady(event:Event):void
    {
        sendParams("param1=value1&param2=value2");
    }

    protected function sendParams(params:String):void
    {
        stage.dispatchEvent(new DataEvent("params", false, false, params));
    }

fla.swf：

public function astest1()
{
    if(stage)
        onAdded();
    else
        addEventListener(Event.ADDED_TO_STAGE, onAdded);
}

protected function onAdded(event:Event = null):void
{
    stage.addEventListener("params", onParams);
    //fire event with bubbling that anables handling it in the parent swf
    dispatchEvent(new Event("ready", true));
}

protected function onParams(event:DataEvent):void
{
    var data:String = event.data;
    trace(data);
}

输出：

param1=value1&param2=value2

通过这种方法，您可以根据需要发送尽可能多的参数，还可以创建自定义事件以传递对象参数，但是在这种情况下，两个项目都必须在该源路径中具有此cusom事件。