乘以值的總和

Question

我有一個相當復雜的XML文件，我需要使用XSL對其中的一些值進行加權平均。 我能夠完成值的權重OR的總和，但我無法使乘法工作。 我收到一個錯誤：

XPTY0004：不允許包含多個項目的序列作為'*'的第一個操作數

我無法共享XML，但我已將XML簡化為以下示例（假設有大量的foos）：

<group>
<fooList>
    <foo>
        <attributeList>
            <Attribute ID="1" Weight="0.5">
                <otherParams />
            </Attribute>
        </attributeList>
        <Properties>
            <PhysicalProperties>
                <Volume Average="125" Unknown="50" />
            </PhysicalProperties>
        </Properties>
     </foo>
</fooList>
</group>

我目前獲得加權平均值的嘗試如下：

<xsl:variable name="WeightedVolume" select="sum(/group/fooList/foo[attributeList/Attribute/[@ID=$test_id]]/attributeList/Attribute/@Weight * /group/fooList/foo[attributeList/Attribute/[@ID=$test_id]]/Properties/PhysicalProperties/Volume/@Average)"/>

我知道有類似的問題可用 - 但大多數問題涉及總結和倍增foo

<foo>
    <Weight>0.5</Weight>
    <VolumeAverage>125</VolumeAverage>
</foo>

這個StackOverflow問題的答案對我很有吸引力 ，但我似乎無法使它工作。

我正在使用Saxonica的Saxon-HE 9.5.1.1N，使用Visual Studio 2013。

編輯我能夠得到一些適用於XSL 2的東西，但需要為XSL1做一個后備。

<xsl:variable name="WeightedVolume" select="sum(for $i in /group/FooList/foo[attributeList/Attribute[@ID=$test_id] return $i/AttributeList/Attribute/@Weight * $i/Properties/PhysicalProperties/Volume/@Average)"/>

Answer 1

要按照您鏈接到的問題中的示例，您將在XSLT 2.0 / XPath 2.0中使用它：

<xsl:variable name="FoosToCalculate"
              select="/group/fooList/foo[attributeList/Attribute/@ID = $test_id]" />
<xsl:variable name="WeightedVolume" 
              select="sum($FoosToCalculate/(attributeList/Attribute/@Weight * 
                                 Properties/PhysicalProperties/Volume/@Average)
                          )"/>

在XSLT 1.0中進行此求和涉及更多，並且通常涉及使用遞歸模板或node-set()函數的某些表現形式。 以下是后者的一個例子：

<xsl:stylesheet version="1.0"
                xmlns:ex="http://exslt.org/common"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>

  <xsl:template match="/">
    <!-- determine $test_id however you need to -->
    <xsl:variable name="products">
      <xsl:for-each 
           select="/group/fooList/foo[attributeList/Attribute/@ID = $test_id]">
        <product>
          <xsl:value-of select="attributeList/Attribute/@Weight * 
                                Properties/PhysicalProperties/Volume/@Average" />
        </product>
      </xsl:for-each>
    </xsl:variable>

    <xsl:value-of select="sum(ex:node-set($products)/product)"/>
  </xsl:template>

</xsl:stylesheet>

Answer 2

為了完整性，如果要在XSLT 1.0中總結計算數量，有三種方法：

（a）遞歸：編寫一個遞歸模板，逐個處理序列中的項目，計算總數。

（b）創建一個XML樹，其中計算的數量是節點值，然后使用sum（）函數處理該樹。 要在單個樣式表中執行此操作，您將需要exslt：node-set（）擴展函數。

（c）使用XSLT供應商提供的擴展功能，或者使用供應商提供的設施進行用戶編寫以調用外部功能。

在XSLT 2.0中，始終可以使用構造完成

sum(for $x in node-set return f($x))

其中f是計算數量的函數。