有什么方法可以使用xpath過濾/處理文字結果元素？

Question

我正在處理一個樣式表，以將類似於IETF（即xhtml）表但面向列的表轉換為xsl-fo。

第一步之一是將<col />標記轉換為<fo：table-column />標記。 不幸的是，由於某些原因，XSL 1.1規范的作者沒有提供將所有屬性自動從<fo：table-column />轉移到相應列中的表格單元以及屬性（寬度除外）的方法。 ），也不會自動應用（我認為這確實是愚蠢的設計決定- 這是天線之家的一位開發商在2001年抱怨同一件事！ ）。 繼承也不適用，因為<fo：table-column />沒有任何子代。

剩下的任務是弄清楚已為每列設置了哪些格式設置屬性，然后手動將其應用於適當的表單元格。 但是，如何最好地做到這一點呢？ 我曾經想到的是將所有<fo：table-column />節點放入一個變量中，但是然后我將如何使用xpath處理這些節點？ 另一個想法是，必須有一種使用臨時結果樹的方法，但是從未使用過這種方法，因此對於是否可行以及如何使用臨時結果樹一無所知。 我張貼這個問題有標簽XSLT 1.0和XSLT 2.0只是為了看看有沒有一個答案，但我真的限制使用XSLT 1.0這個問題。

編輯：有人要求一個具體的例子。 源文檔片段可能看起來像這樣：

<table>
  <col width="33%" font-weight="bold" border="1pt solid black"/>
  <col width="34%" span="2" color="red" background-color="gray"/>
  <col font-style="italic" align="center" background-color="yellow"/>
  <tr><td>A</td><td>B</td><td>C</td><td>D</td></tr>
  <tr><td>dog</td><td>cat</td><td>mouse</td><td>elephant</td></tr>
  ...
</table>

即標准xhtml表，除了一些通常使用style屬性表示的屬性。

那么自然翻譯就是

<table> -->  <fo:table>
<col/>  -->  <fo:table-column/>
<tr>    -->  <fo:table-row>
<td>    -->  <fo:table-cell>

但是，這存在一個問題，即<table-column />中的任何屬性都不會自動應用於對應列中的表單元格，除非您特別要求使用from-table-colum（）函數來調用它們（與寬度的除外，它被自動應用）。 因此，例如，對於表格第三列中的表格單元格，我需要像這樣輸出fo：

<fo:table-cell color="from-table-column()" background-color="from-table-column()>

對於第4列中的表格單元，我需要輸出

<fo:table-cell font-style="from-table-column()" align="from-table-column()" background-color="from-table-column()>

問題是您如何知道要為特定列中的表單元格查找哪些屬性？

Answer 1

在XSLT 1.0中，包含結果節點的變量是結果樹片段，要將其轉換為要應用XPath或進一步處理節點的節點集，您可以使用exsl:node-set或類似示例

<xsl:variable name="v1-rtf">
  <fo:table-column>...</fo:table:column>
</xsl:variable>

<xsl:variable name="v1-ns" xmlns:exsl="http://exslt.org/common" select="exsl:node-set($v1-rtf)"/>

<xsl:apply-templates select="$v1-ns/fo:table-column"/>

XSLT 2.0中的唯一區別是，您不需要exsl:node-set函數及其轉換操作，可以直接將任何變量與臨時樹一起使用，例如

<xsl:variable name="v1">
  <fo:table-column>...</fo:table:column>
</xsl:variable>

<xsl:apply-templates select="$v1/fo:table-column"/>

Answer 2

警告 ：我對XSL-FO一無所知； 這只是您可以使用的起點。

以我理解您的問題的方式，您希望每個表單元格都具有與源文檔中相應col相同的屬性列表。 通過查看當前處理的td的位置並使用該位置在相同的相對位置查找col ，將非常容易實現。 但是，由於某些col元素具有span屬性，因此並非如此簡單。

我建議的解決方案是從“枚舉” col元素開始，以便它們與列一樣多。 有了這個，我們可以按計划進行。

以下樣式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="columns">
    <xsl:for-each select="/table/col">
        <xsl:call-template name="replicate">
            <xsl:with-param name="n">
                <xsl:choose>
                    <xsl:when test="@span">
                        <xsl:value-of select="@span"/>
                    </xsl:when>
                    <xsl:otherwise>1</xsl:otherwise>
                </xsl:choose>
            </xsl:with-param>
        </xsl:call-template>
    </xsl:for-each>
</xsl:variable>

<xsl:template match="/table">
    <fo:table>
        <xsl:apply-templates/>  
    </fo:table>
</xsl:template>

<xsl:template match="tr">
    <fo:table-row>
        <xsl:apply-templates select="td"/>
    </fo:table-row>
</xsl:template>

<xsl:template match="td">
    <xsl:variable name="i" select="position()" />
    <fo:table-cell>
        <xsl:for-each select="exsl:node-set($columns)/col[$i]/@*[not(name()='width' or name()='span')]">
            <xsl:attribute name="{name()}">from-table-column()</xsl:attribute>
        </xsl:for-each>
        <xsl:apply-templates/>  
    </fo:table-cell>
</xsl:template>

<xsl:template name="replicate">
    <xsl:param name="n"/>
    <xsl:if test="$n">
        <xsl:copy-of select="."/>
        <xsl:call-template name="replicate">
            <xsl:with-param name="n" select="$n - 1"/>
        </xsl:call-template>        
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

當應用於您的輸入示例時，將產生以下結果 ：

<?xml version="1.0" encoding="utf-8"?>
<fo:table xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:table-row>
      <fo:table-cell font-weight="from-table-column()" border="from-table-column()">A</fo:table-cell>
      <fo:table-cell color="from-table-column()" background-color="from-table-column()">B</fo:table-cell>
      <fo:table-cell color="from-table-column()" background-color="from-table-column()">C</fo:table-cell>
      <fo:table-cell font-style="from-table-column()" align="from-table-column()" background-color="from-table-column()">D</fo:table-cell>
   </fo:table-row>
   <fo:table-row>
      <fo:table-cell font-weight="from-table-column()" border="from-table-column()">dog</fo:table-cell>
      <fo:table-cell color="from-table-column()" background-color="from-table-column()">cat</fo:table-cell>
      <fo:table-cell color="from-table-column()" background-color="from-table-column()">mouse</fo:table-cell>
      <fo:table-cell font-style="from-table-column()" align="from-table-column()" background-color="from-table-column()">elephant</fo:table-cell>
   </fo:table-row>
</fo:table>

這是假設表單元格本身沒有跨度。 否則這可能變得更加復雜。