將大量選定的數據從一個工作簿移動到另一個工作簿

Question

我正在嘗試編寫一些代碼，以將大量用戶選擇的數據從一個打開的工作簿傳輸到另一個。 行/列的數量有所不同，目標工作簿中的起點也有所不同。 我收到調試運行時錯誤'13'：在代碼的最后一行鍵入不匹配 。 可能有一種更優雅的方法來進行某些操作，例如調整目標范圍的大小，但其他所有操作似乎都按預期工作。

Public SourceWorkbook As Workbook
Public SourceWorksheet As Worksheet
Public DestWorkbook As Workbook
Public DestWorksheet As Worksheet
Public selectedRange As Range
Public selectedRows As Long
Public selectedColumns As Long
Sub SelectRange()
    Set SourceWorkbook = ActiveWorkbook
    Set SourceWorksheet = ActiveSheet
    'Display the Input Box to make selection
    On Error Resume Next
    Set selectedRange = Application.InputBox( _
        Prompt:="Select the range of cells you want to copy.", _
        title:="Select Range", _
        Default:=ActiveCell.Address, _
        Type:=8)
'   Was the Input Box canceled?
    If selectedRange Is Nothing Then
        MsgBox "Cancelled"
        Exit Sub
    End If
    selectedRange.Select
    'Set row and column number variables
    selectedRows = Selection.Rows.Count
    selectedColumns = Selection.Columns.Count
    'vbModeless Form that allows user to select another open workbook and start cell. The OK button simply calls the MoveData sub. 
    SwitchWorkbooksForm.Show vbModeless
End Sub

Sub MoveData()
    Dim DestRange As Range
    Set DestWorkbook = ActiveWorkbook
    Set DestWorksheet = ActiveSheet
'Start the desination range at the user select cell and Set it to the same size as the originally selected range
    StartRow = ActiveCell.Row
    finalRow = StartRow + selectedRows - 1
    StartColumn = ActiveCell.Column
    finalColumn = StartColumn + selectedColumns - 1
    Range(Cells(StartRow, StartColumn), Cells(finalRow, finalColumn)).Select
    Set DestRange = Selection

    'Debug error on the next line
    Workbooks(DestWorkbook).Worksheets(DestWorksheet).Range(DestRange).Value = _
    Workbooks(SourceWorkbook).Worksheets(SourceWorksheet).Range(selectedRange).Value
End Sub

Answer 1

您正在通過傳入工作簿和工作表對象來使用Workbooks(...)和Worksheets(...)集合。 您應該傳遞名稱或使用直接分配的工作簿和工作表引用。

Workbooks(DestWorkbook.name).Worksheets(DestWorksheet.name).Range(DestRange.address).Value = _
   Workbooks(SourceWorkbook.name).Worksheets(SourceWorksheet.name).Range(selectedRange.address).Value

... 要么，

DestRange = selectedRange.Value

您不必繼續重新定義已Set的范圍對象的父級。