如何使用applescript計算卷大小列表？

Question

我需要弄清楚很多硬盤驅動器上的容量—超過150個USB和雷電驅動器。 我以為我可以構建AppleScript或自動操作來獲得卷的總大小，然后減去“可用”。 理想情況下，我可以啟動腳本，它將監視要裝入的卷，進行此數學運算並將其添加到正在運行的總計中。

我們正在購買一台新服務器，我們很想知道我們需要投入多大的驅動器才能保持所有這些資產的生命。

我在Apple腳本方面還很陌生，但我正在嘗試。 我什至找不到要查找已裝入磁盤的AS詞典項目，更不用說添加數學了（即使它只是輸出要拉入制表符分隔文件的信息，也可以在Excel中計算）

實際上，也許這是理想的版本。 它看到驅動器安裝，獲得名稱，獲得總容量，獲得可用空間...完美的世界？ 創建日期。 然后將其添加到文本文件。

代碼，指向哪里可以學習的指針，不勝感激。

Answer 1

這是一個AppleScript解決方案，它將返回顯示的名稱以及每個已安裝卷上的可用空間量。

set allMountedVolumesInfo to {}

tell application "System Events"
    set everyDisk to every disk
    repeat with i from 1 to count of everyDisk
        set thisDisk to displayed name of item i of everyDisk
        tell its disk thisDisk
            try
                set diskFreeSpace to (characters 1 thru 7 of ((free space / 1.0E+9) as string))
                set totalCapacity to (characters 1 thru 7 of ((capacity / 1.0E+9) as string))
                set creationDate to creation date
            on error errMsg number errNum
                set diskFreeSpace to (free space / 1.0E+9)
                set totalCapacity to (capacity / 1.0E+9)
                set creationDate to creation date
            end try
            set theRecord to {volume:thisDisk, free space:((diskFreeSpace & " Gigabytes") as string), creation date:creationDate, capacity:((totalCapacity & " Gigabytes") as string)}
        end tell
        set end of allMountedVolumesInfo to theRecord
    end repeat
end tell

Answer 2

下面的腳本旨在作為文件夾操作運行。 如果您不熟悉這些內容，它們將允許您監視指定文件夾中其內容的任何更改，然后可以觸發AppleScript來對從監視的文件夾中添加（或刪除）的項目執行某些操作。

每當安裝磁盤時，安裝點都會作為磁盤項添加到/Volumes文件夾中。 因此，您可以設置一個文件夾操作來監視/Volumes文件夾的內容，並在裝入新卷時讓它觸發AppleScript。

這是旨在觸發的腳本：

use sys : application "System Events"
use scripting additions

property text item delimiters : tab
property fp : "~/Desktop/diskinfo.csv"

on adding folder items to Volumes after receiving D
    set D to a reference to the sys's disk named (item 1 of D)

    set f to a reference to sys's file fp
    if not (f exists) then initCSVFile(fp)

    set isod to the (current date) as «class isot» as string

    get the contents of {isod's text 1 thru 10, ¬
        isod's text 12 thru -1, ¬
        D's name, ¬
        gigabytes(D's capacity), ¬
        gigabytes(D's free space)} as text

    write the result & linefeed ¬
        to (f as alias) ¬
        starting at eof ¬
        as «class utf8»
end adding folder items to

to gigabytes(bytes)
    round bytes / (10 ^ 7)
    result / 100
end gigabytes

to initCSVFile(fp)
    local fp

    set f to make of sys new file with properties {name:fp}

    {"Date", "Time", "Volume Name", "Capacity (GB)", "Free Space (GB)"}
    write (result as text) & linefeed to (f as alias) as «class utf8»
end initCSVFile

復制並粘貼到腳本編輯器中 ，並將其另存為~/Library/Scripts/Folder Action Scripts文件夾中的"New Volume Mounted.scpt" ，其中~是您的主目錄，例如/Users/Alex 。 如果"Folder Action Scripts"文件夾不存在，請創建它。

如果您樂意從此處創建文件夾操作，請執行此操作，然后安裝新卷。 當上面的腳本被觸發時，它會將安裝卷的當前日期和時間及其名稱，容量和可用空間量添加到桌面上文件diskinfo.csv的末尾（如果該文件不存在） ，腳本將創建它）。 這是一個CSV（逗號分隔值）文件，使用制表符作為分隔符（因此，它實際上是TSV）。 QuickLook通常可以很好地顯示這些文件的內容：

---

文件夾操作設置

如果您不熟悉設置文件夾操作，請閱讀《 Mac Automation Scripting Guide - Watching Folders Attaching a Folder Action Script to a Folder名為“ Attaching a Folder Action Script to a Folder的部分。

但是，為了節省一些時間，我還創建了一個腳本，該腳本將為您創建文件夾操作：

use sys : application "System Events"

property name : "Volumes"
property path : "/Volumes"
property folder action : a reference to folder action named (my name)
property script : "New Volume Mounted.scpt"
property folder : a reference to Folder Action scripts folder
property file : a reference to the file named (my script) in my folder

set folder actions enabled to true

if not (my file exists) then return open my folder
if my folder action exists then return my folder action's scripts

make new folder action with properties {name:my name, path:my path}
tell my folder action to make new script with properties ¬
    {name:my file's name, POSIX path:my file's POSIX path}

set my folder action's enabled to true
set my folder action's scripts's enabled to true

同樣，將其復制-n-粘貼到腳本編輯器中的新文檔中，然后運行它。 僅在將第一個腳本保存到我指定的位置后，然后"New Volume Mounted.scpt"檢查文件名是"New Volume Mounted.scpt" （您可以選擇所需的任何文件名，但需要在其中進行適當的更改），創建文件夾操作的腳本）。

您可能需要授予必要的可訪問性特權才能運行此腳本。

如果您遇到任何問題，請告訴我。