您應該如何在Typed Racket中的letrec中鍵入相互注釋的遞歸函數？

Question

如果我正確理解，這是注釋Typed Racket中letrec中定義的函數的正確方法：

#lang typed/racket

(letrec ((is-even? (lambda ((n : Nonnegative-Integer))
                     : Boolean
                     (or (zero? n)
                         (is-odd? (sub1 n)))))
         (is-odd? (lambda ((n : Nonnegative-Integer))
                    : Boolean
                    (and (not (zero? n))
                         (is-even? (sub1 n))))))
  (is-odd? 11))

但這給出了錯誤信息：

Type Checker: insufficient type information to typecheck. please add more
              type annotations in: is-odd?

解決方法是這樣的：

(local ((: is-even? : Nonnegative-Integer -> Boolean)
        (define (is-even? n)
          (or (zero? n)
              (is-odd? (sub1 n))))
        (: is-odd? : Nonnegative-Integer -> Boolean)
        (define (is-odd? n)
          (and (not (zero? n))
               (is-even? (sub1 n)))))
  (is-odd? 11))

也可以使用傳統表示法的形式，例如該問題，但我希望也能夠使用當前表示法對letrec進行注釋。

Answer 1

您可以在letrec的函數名稱之后添加類型注釋，如下所示：

(letrec ([f1 : type1 expr1]
         [f2 : type2 expr2])
  body)

以您的示例為例：

(letrec ([is-even? : (-> Nonnegative-Integer Boolean)
                   (lambda (n)
                     (or (zero? n)
                         (is-odd? (sub1 n))))]
         [is-odd? : (-> Nonnegative-Integer Boolean)
                  (lambda (n)
                    (and (not (zero? n))
                         (is-even? (sub1 n))))])
  (is-odd? 11))

為什么這樣做有效，但在lambda內放置類型注釋卻不能呢？

這是因為確保每個lambda類型檢查都依賴於is-odd?類型is-odd? is-even? 分別。 但是，如果您不直接注釋函數名，則只能嘗試通過對lambda進行類型檢查來推斷這些類型。

直接注釋函數名意味着在知道什么類型is-even?之前，它甚至不必查看lambda is-even? is-odd? 一定有。