`UnitRange` 和 `Array` 有什么區別？

Question

我有兩個版本的代碼似乎做同樣的事情：

sum = 0
for x in 1:100
    sum += x
end

sum = 0
for x in collect(1:100)
    sum += x
end

兩種方法之間有實際區別嗎？

Answer 1

UnitRange將使用常量空間，而Array將與您正在迭代的元素數量成比例地增長。

您可以使用BenchmarkTools package 查看差異。

julia> @btime sum(1:1000000)
  0.044 ns (0 allocations: 0 bytes)
500000500000

julia> @btime sum(collect(1:1000000))
  1.123 ms (2 allocations: 7.63 MiB)
500000500000

兩種方法在空間和時間性能上都存在顯着差異。 UnitRange避免了在您一次不需要時分配一大塊 memory 的工作。 如果可能，更喜歡使用UnitRange而不是Array 。

Answer 2

在 Julia 中， 1:100返回一個名為UnitRange的特定結構，如下所示：

julia> dump(1:100)
UnitRange{Int64}
  start: Int64 1
  stop: Int64 100

這是一個非常緊湊的結構，用於表示具有步驟 1 和任意（有限）大小的范圍。 UnitRange是AbstractRange的子類型，是表示具有任意步長的范圍的類型，是AbstractVector的子類型。

每當您使用getindex （或語法糖vector[index] ）時， UnitRange的實例都會動態計算它們的元素。 例如，使用@less (1:100)[3]你可以看到這個方法：

function getindex(v::UnitRange{T}, i::Integer) where {T<:OverflowSafe}
    @_inline_meta
    val = v.start + (i - 1)
    @boundscheck _in_unit_range(v, val, i) || throw_boundserror(v, i)
    val % T
end

這是通過將i - 1添加到范圍的第一個元素（ start ）來返回向量的第i個元素。 一些函數使用UnitRange優化了方法，或者更普遍地使用AbstractRange 。 例如，使用@less sum(1:100)您可以看到以下內容

function sum(r::AbstractRange{<:Real})
    l = length(r)
    # note that a little care is required to avoid overflow in l*(l-1)/2
    return l * first(r) + (iseven(l) ? (step(r) * (l-1)) * (l>>1)
                                     : (step(r) * l) * ((l-1)>>1))
end

此方法使用算術級數之和的公式，該公式非常有效，因為它是在與向量大小無關的時間內進行評估的。

另一方面， collect(1:100)返回一個包含一百個元素 1、2、3、...、100 的普通Vector 。與UnitRange （或其他類型的AbstractRange ）的主要區別在於getindex(vector::Vector, i) （或vector[i] ，帶有vector::Vector ）不進行任何計算，而只是訪問向量的第i個元素。 Vector優於UnitRange的缺點是，一般來說，在使用它們時沒有有效的方法，因為這個容器的元素是完全任意的，而UnitRange表示一組具有特殊屬性（排序、恆定步長等）的數字。 ..)。

如果您比較UnitRange具有超高效實現的方法的性能，這種類型將勝出（注意使用BenchmarkTools中的宏時使用$(...)對變量進行插值）：

julia> using BenchmarkTools

julia> @btime sum($(1:1000_000))
  0.012 ns (0 allocations: 0 bytes)
500000500000

julia> @btime sum($(collect(1:1000_000)))
  229.979 μs (0 allocations: 0 bytes)
500000500000

請記住，每次使用getindex訪問元素時， UnitRange都會帶來動態計算元素的成本。 例如考慮這個 function：

function test(vec)
    sum = zero(eltype(vec))
    for idx in eachindex(vec)
        sum += vec[idx]
    end
    return sum
end

讓我們用一個UnitRange和一個普通的Vector對其進行基准測試：

julia> @btime test($(1:1000_000))
  812.673 μs (0 allocations: 0 bytes)
500000500000

julia> @btime test($(collect(1:1000_000)))
  522.828 μs (0 allocations: 0 bytes)
500000500000

在這種情況下，調用普通數組的 function 比使用UnitRange的更快，因為它不必動態計算 100 萬個元素。

當然，在這些玩具示例中，迭代vec的所有元素而不是它的索引會更明智，但在現實世界的情況下，這樣的情況可能更明智。 然而，最后一個示例表明UnitRange不一定比普通數組更有效，尤其是當您需要動態計算其所有元素時。 當您可以利用可以在恆定時間內執行操作的專用方法（如sum ）時， UnitRange會更有效。

作為文件備注，請注意，如果您最初有UnitRange ，將其轉換為普通Vector以獲得良好性能不一定是一個好主意，特別是如果您只使用一次或很少使用它，因為轉換到Vector涉及范圍內所有元素的動態計算和必要 memory 的分配：

julia> @btime collect($(1:1000_000));
  422.435 μs (2 allocations: 7.63 MiB)

julia> @btime test(collect($(1:1000_000)))
  882.866 μs (2 allocations: 7.63 MiB)
500000500000