當用戶沒有組時，在 Active Directory 中搜索特定組的成員失敗

Question

以下代碼應該遍歷活動目錄中的所有用戶並找到特定組中的每個人。 一旦獲得用戶，它會將他們添加到數據表中，該數據表將成為 gridview 的來源，最終導出到 Excel。

但是，在運行和單步執行時，我注意到它在某個沒有組的用戶上停止了。 我嘗試添加一個條件語句來跳過該實例，但它不起作用，當它找到沒有組的用戶時，代碼仍然停止運行。

有人可以告訴我我可以做些什么不同的事情嗎？ 警告：這是我繼承的一個遺留站點，對活動目錄知之甚少，並且是一個新手 vb 編碼器。

Dim entry As DirectoryEntry = New DirectoryEntry("LDAP://DOMAIN.EDU", "USERNAME", "PASSWORD", AuthenticationTypes.Secure)
    Dim search As DirectorySearcher = New DirectorySearcher(entry) With {
        .Filter = "(&(objectCategory=User)(objectClass=person))",
        .PageSize = 4000
    }
    search.PropertiesToLoad.Add("userPrincipalName").ToString
    search.PropertiesToLoad.Add("name").ToString
    Dim mySearchResultColl As SearchResultCollection = search.FindAll
    Dim results As DataTable = New DataTable
    results.Columns.Add("User ID")        
    results.Columns.Add("Full Name")
    Dim CurrRow = 0

    For Each sr As SearchResult In mySearchResultColl

        Dim dr As DataRow = results.NewRow
        Dim de As DirectoryEntry = sr.GetDirectoryEntry
        !!!! line below is the problem !!!!
        If de.Properties("memberOf") IsNot Nothing AndAlso de.Properties("memberOf").Value.ToString = "CN=MYGROUP,OU=Security Groups,OU=Students,DC=DOMAIN,DC=edu" Then 
            dr("User ID") = de.Properties("userPrincipalName").Value           
            dr("Full Name") = de.Properties("name").Value
            results.Rows.Add(dr)
            de.Close
        End If
    Next

    gvNot.DataSource = results
    gvNot.DataBind()
    gvNot.Visible = True
    gvAgreed.Visible = False
    ExportToExcel("notagreed", gvNot)

Answer 1

我不確定您所說的“停止”是什么意思，但您可以對其進行更改，使其性能更好並解決您遇到的任何問題。

1. 這個循環將永遠持續下去，因為您必須檢查域中的每個用戶。 如果您只想要特定組中的用戶，那么您可以通過只詢問該組的成員來加快速度。 您可以通過在查詢中為memberOf屬性添加一個條件來做到這一點。 這樣，您只會得到您關心的結果。

（請注意，如果您的森林中有多個域，則使用memberOf查找成員可能無法按您希望的方式工作。我在這里寫過。但如果您只有一個域，那就沒問題了。）

2. 在循環中，不要為每個結果創建一個DirectoryEntry ，因為這將強制它 go 回到 AD 並再次請求 object 的屬性，即使您已經在搜索結果中得到了所需的內容。 因此，請改用SearchResult object 中的值。

3. SearchResultCollection的文檔說：

由於實施限制，SearchResultCollection class 在垃圾回收時無法釋放其所有非托管資源。 為防止 memory 泄漏，您必須在不再需要 SearchResultCollection object 時調用 Dispose 方法。

所以你應該把它放在一個Using子句中。

4. 我也不確定為什么在不使用返回值時在PropertiesToLoad.Add上調用ToString 。 你可以刪除它。

這一切都在一起：

Dim entry As DirectoryEntry = New DirectoryEntry("LDAP://DOMAIN.EDU", "USERNAME", "PASSWORD", AuthenticationTypes.Secure)
Dim search As DirectorySearcher = New DirectorySearcher(entry) With {
    .Filter = "(&(objectCategory=User)(objectClass=person)(memberOf=CN=MYGROUP,OU=Security Groups,OU=Students,DC=DOMAIN,DC=edu))",
    .PageSize = 4000
}
search.PropertiesToLoad.Add("userPrincipalName")
search.PropertiesToLoad.Add("name")

Dim results As DataTable = New DataTable
results.Columns.Add("User ID")        
results.Columns.Add("Full Name")
Dim CurrRow = 0

Using mySearchResultColl As SearchResultCollection = search.FindAll
    For Each sr As SearchResult In mySearchResultColl

        Dim dr As DataRow = results.NewRow
        dr("User ID") = sr.Properties("userPrincipalName")(0)
        dr("Full Name") = sr.Properties("name")(0)
        results.Rows.Add(dr)
    Next
End Using

gvNot.DataSource = results
gvNot.DataBind()
gvNot.Visible = True
gvAgreed.Visible = False
ExportToExcel("notagreed", gvNot)

我沒有看到您在任何地方使用CurrRow ，但我留下了它，以防您在此處未顯示的其他代碼中使用它。

Answer 2

嘗試使用 String.Equals function 和 StringComparer.OrdinalIgnoreCase 參數，而不是使用 equals 運算符。 另外你得到的錯誤是什么？