如何在 Google 表格上按組分隔人員

Question

我希望你做得很好。 我希望有人可以幫助解決這個問題。

我有兩組人“A”和“B”

兩個小組從事相同的任務

但我想在另一張紙上加上“@”； 分成兩組（A組和B組），兩組混合（一般）

有誰知道我怎樣才能自動將它們分成 A 組和 B 組？ 我想知道是否可以使用匹配公式和 if 公式，我嘗試這樣做但沒有成功。 任務可能會有所不同，但不會因組而異，因此最好的辦法是獲取公式或任何自動添加每個組的人的方法。

作為附加信息，我使用此公式來獲得一般結果： =IFNA(JOIN(", ";QUERY('Sheet 1':A3;E12;"select A where B = TRUE";0));"")

這是我一直用來嘗試執行此操作的 Google 表格：

https://docs.google.com/spreadsheets/d/14fdQJcIuqFTfo8upNOtALk0vhQYjSM0d8nYRML4amuM/edit?usp=sharing

任何幫助都非常感謝。 謝謝！

Answer 1

B10：

=ARRAYFORMULA(TRIM(FLATTEN(QUERY(TRANSPOSE(XLOOKUP(SPLIT(B3:B6; "@ "); 
 IF('Sheet 3'!B3:B12; 'Sheet 3'!A3:A12; ); "@"&'Sheet 3'!A3:A12;;; 1));;9^9))))

B17：

=ARRAYFORMULA(TRIM(FLATTEN(QUERY(TRANSPOSE(XLOOKUP(SPLIT(B3:B6; "@ "); 
 IF('Sheet 3'!C3:C12; 'Sheet 3'!A3:A12; ); "@"&'Sheet 3'!A3:A12;;; 1));;9^9))))

Answer 2

粘貼此公式
在Sheet2單元格A2 ， A9 ， A16

=ArrayFormula(IF(SUMPRODUCT('Sheet 1'!B3:E)=0;;IFERROR({ "General"\ " "; 
                 TRANSPOSE({ 'Sheet 1'!B2:E2;BYCOL(
                                   IF('Sheet 1'!B3:E12<>TRUE;;"@"&'Sheet 1'!A3:A12); 
                                   LAMBDA(v; TEXTJOIN(" "; 1;v)))})};"")))

=ArrayFormula(IFERROR({ SPLIT('Sheet 3'!B1&" "&'Sheet 3'!B2&", " ; ",");
                TRANSPOSE({  'Sheet 1'!B2:E2;
                             BYCOL(IF(FILTER('Sheet 1'!B3:E; 'Sheet 3'!B3:B=TRUE)<>TRUE;;"@"&'Sheet 1'!A3:A); 
                             LAMBDA(v; TEXTJOIN(" "; 1;v)))}) };""))

=ArrayFormula(IFERROR({ SPLIT('Sheet 3'!B1&" "&'Sheet 3'!C2&", " ; ",");
                TRANSPOSE({  'Sheet 1'!B2:E2;
                             BYCOL(IF(FILTER('Sheet 1'!B3:E; 'Sheet 3'!C3:C=TRUE)<>TRUE;;"@"&'Sheet 1'!A3:A); 
                             LAMBDA(v; TEXTJOIN(" "; 1;v)))}) };""))

使用的功能
ARRAYFORMULA - BYCOL TRANSPOSE IF - LAMBDA - TEXTJOIN

Answer 3

只需使用regex替換一般類別中的對立組：

對於 A 組，替換 B：

=ARRAYFORMULA(REGEXREPLACE(B3:B6,"@"&JOIN("( |$)|@",FILTER(Sheet3!A3:A12,Sheet3!C3:C12)),))

其中B3:B6是 General 類別的值列， Sheet3包含 Groups。

這會創建一個正則表達式

@P1( |$)|@P2( |$)|@P5( |$)|@P6( |$)|@P8( |$)|@P10

這是@后跟任何組P1並后跟空格或字符串結尾( |$) 。 要使其正常工作，請避免在人員名稱中使用正則表達式元字符。