Excel VBA - 下標超出范圍錯誤（運行時：錯誤 9）

Question

嘗試使用 Cells.Find Function 時出現運行時錯誤 (9) 下標超出范圍。

根據官方文檔，只有幾種可能的原因：

• 引用了一個不存在的數組元素
• 聲明了一個數組但沒有指定元素的數量
• 引用了一個不存在的集合成員
• 將 , 運算符與集合一起使用， ! 隱式指定一個鍵

這是一些與我相關的代碼，也許有人有想法：

Dim Partner As Worksheet
Dim rangePartner As Range
Set Partner = Worksheets("Partner")
Set rangePartner = Range(Partner.Cells(2, 2), Partner.Cells(2, 2).End(xlDown))
    
Dim partnerid As String  
Dim segment As String
    
With rangePartner
    segment = Cells.Find(partnerid, LookIn:=Values, SearchOrder:=xlByRows).Offset(0, 3)
End With

另外，如果可以給我提示如何結合查找function避免偏移方法，請隨時拍攝。 :)

正在瀏覽論壇和官方文檔以排除原因。 檢查作業和拼寫 1000 次，但無法解決問題所在......

此外，我排除了 Offset 方法，以查看這是否會導致不同的錯誤。

Answer 1

Set rangePartner = Range(Partner.Cells(2, 2), Partner.Cells(2, 2).End(xlDown)) Range需要明確的父級 object 否則它會使用活動工作表，如果該工作表是不是Partner ，因為cells使用Partner 。

您的With當前什么都不做，您需要一個. cells的前面。

LookIn:=Values應該是xlvalues

不要在與Find相同的行中使用Range方法或屬性，如果Find失敗，程序將出錯，因為它返回一個沒有屬性或方法的空 object。

我沒有看到partnerid的值。

總的來說是這樣的：

Dim Partner As Worksheet
Dim rangePartner As Range
Set Partner = Worksheets("Partner")

With Partner
    Set rangePartner = .Range(.Cells(2, 2), .Cells(2, 2).End(xlDown))
End With
Dim partnerid As String 'This still needs a value assigned
Dim segment As Range
    
With rangePartner
    Set segment = .Cells.Find(partnerid, LookIn:=xlValues, SearchOrder:=xlByRows)
    If Not segment Is Nothing Then
        Set segment = segment.Offset(0, 3)
    End If
End With