測試系統插件返回的字符串時出現意外的logiclib行為

Question

我通過使用類似於上一個問題的答案的代碼，通過System插件獲取系統信息。 API函數非常相似，除了它返回（或不返回）寬字符字符串。

在屬於域成員的計算機上使用該腳本時，我無法理解為什么logiclib測試始終通過測試的${else}分支。 以下捕獲顯示$1不為空：

在閱讀更多NetGetDCName參考時，我認為最好檢查函數返回的值而不是寬字符字符串指針。 我有點困惑，為什么我的${If} 0 <> $1總是失敗？ 在這種情況下，我已經檢查了不是$1等於0的域成員的虛擬機。 我想然后${IfThen}測試來釋放內存也是錯誤的。

這是示例代碼：

!include "logiclib.nsh"
outfile "hello2.exe"

!define DEBUG `System::Call kernel32::OutputDebugString(ts)`

section

    Call GetDCName
    pop $0

    Messagebox MB_OK "DCName=$0"

sectionEnd

Function GetDCName
    ;Push the domain controler name to the stack (or an empty string if no dc)
    push $0
    push $1
    push $2
    System::Call "netapi32::NetGetDCName(i0, i0, *w 0 r1) i.r2"
    Dumpstate::debug
    ${If} 0 <> $1
        ${debug} "copy $1"
        StrCpy $0 $1
    ${else}
        ${debug} "copy empty string"
        StrCpy $0 ""
    ${endif}
    ${IfThen} $1 <> 0 ${|} System::Call "netapi32::NetApiBufferFree(ir1)" ${|}
    Pop $2
    Pop $1
    Exch $0
FunctionEnd

編輯：感謝安德斯，這是更正的功能：

Function GetDCName
    ;Push the domain controler name to the stack (or an empty string if no dc)
    push $0
    push $1
    push $2
    System::Call "netapi32::NetGetDCName(i0, i0, *i 0 r1) i.r2" ;do not convert r1 to wchar, keep the pointer to free it
    ${If} $2 = 0
        System::Call "*$1(&w${NSIS_MAX_STRLEN} .r0)"        ;get the wchar from the pointer
        ${IfThen} $1 <> 0 ${|} System::Call "netapi32::NetApiBufferFree(ir1)" ${|}  ;free the pointer
    ${else}
        StrCpy $0 ""
    ${endif}
    Pop $2
    Pop $1
    Exch $0
FunctionEnd

Answer 1

<>運算符用於數字，而不是字符串。 但是，這不是您唯一的問題； * （通常）只能與i一起使用，而不與t / m / w 。 t / m / w類型在C樣式字符串之間來回轉換，但是在這種情況下，您需要實際的內存地址，因為必須將其傳遞給free函數。

您需要將*i0r1傳遞給NetGetDCName，然后，如果$ 2為0，則可以使用結構語法（ *$1(&w${NSIS_MAX_STRLEN}.r5)或*$1(w.r5) ）提取字符串，並最終傳遞未*$1(w.r5) $ 1免費功能...