Apex更新触发器 - 更新查找字段

Question

I'm trying to write my first Apex update trigger and struggling slightly as I'm trying to set the value of a custom lookup field.

I have an object called Deployment__c which is the master in a master-detail relationship with an object called Service__c (names simplified!)

The Service__c field has no Owner in Salesforce as it is the child/detail in a master-detail relationship. Therefore we have created a pseudo-owner field called Owner__c on this object, which is a lookup field looking up the User object in Salesforce.

The aim of the trigger is to set the value of Service__c.Owner__c to that of the user who is the owner of Deployment__c , if there is no Owner__c already set on Service__c .

The code I have is as follows:

trigger AfterServiceUpdate on Service__c (before update) {
    for (Service__c oldService : Trigger.new) {
        if (oldService.Owner__c == null) {
            User defaultUser = [Select Id FROM User WHERE User.Id = :oldService.Deployment__r.OwnerId];
            oldService.Owner__c = defaultUser.Id;
        }
    }
}

However, I get an error when I try to save this trigger:

Error: Compile Error: Invalid field Owner__c for SObject ASE_Deployment__c at line 5 column 13

I've verified that I have the field name correct, but can't get this to work. Any pointers welcome!

Answer 1

I just recreated that object structure you described in a test org and was unable to reproduce the error you got. On another note I was able to get the trigger you described to work with the following code which has been bulkified for you:

trigger AfterServiceUpdate on Service__c (before update) 
{
    //instantiate set to hold unique deployment record ids
    Set<Id> deplomentIds = new Set<Id>();
    for(Service__c s : Trigger.new)
    {
        deplomentIds.add(s.Deployment__c);
    }

    //instantiate map to hold deployment record ids to their corresponding ownerids
    Map<Id, Deployment__c> deploymentOwnerMap = new Map<Id, Deployment__c>([SELECT Id, OwnerId FROM Deployment__c WHERE Id IN: deplomentIds]);

    for (Service__c s : Trigger.new) 
    {
        if (s.Owner__c == null && deploymentOwnerMap.containsKey(s.Deployment__c)) 
        {
            s.Owner__c = deploymentOwnerMap.get(s.Deployment__c).OwnerId;
        }
    }
}

I also created a test class for you to test the result:

@isTest
private class AfterServiceUpdateTest {

    @isTest static void test_method_one() {
        Deployment__c d = new Deployment__c();
        insert d;

        Service__c s = new Service__c();
        s.Deployment__c = d.Id;
        insert s;

        Id deploymentOwnerId = [SELECT Id, OwnerId FROM Deployment__c WHERE Id=:d.Id].OwnerId;

        test.startTest();

        update s;

        Service__c updatedService = [SELECT Id, Owner__c FROM Service__c WHERE Id=:s.Id];

        system.assertEquals(deploymentOwnerId, updatedService.Owner__c);

        test.stopTest();
    }

}

Hope this helps!

Answer 2

尝试将owner__c更改为Ownerld