计数直到填充特定列的最后一行

Question

I have a problem with finishing my macro. It uses the COUNTIF function and checks the whole A column (A:A - no exclusions) against the data from B2. I would like to make the autofill in the C column until the last value in the B column - just like presented on the picture below:

Could anyone help me what should I add to my code to make this autofill possible??

Sub Countif()

Range("C2").Select
ActiveCell.FormulaR1C1 = "=COUNTIF(C[-2],RC[-1])"
Selection.AutoFill Destination:=Range("C2:C10"), Type:=xlFillDefault
Range("C2:C10").Select

End Sub

Answer 1

If you wanna achieve using VBA try below code. Just Run the macro and it wud fill up the column C uptil values in column B.

Sub sample()

Dim LastRowColumnB As Long
LastRowColumnB = Range("B65000").End(xlUp).Row

For i = 2 To LastRowColumnB
    Cells(i, 3) = Application.CountIf(Range("A:A"), Cells(i, 2))
Next
End Sub

Answer 2

You can get the last row of a column like so:

Dim LastRowColumnB as Long
LastRowColumnB = Activesheet.Cells(Activesheet.Rows.Count, "B").End(xlUp).Row

and then modify your autofill to use that value.

Selection.AutoFill Destination:=Range("C2:C" & LastRowColumnB), Type:=xlFillDefault

Answer 3

' COUNTIF(range,criteria)
' {0} will be replaced with range address
' {1} with criteria
Private Const COUNTIF_TEMPLATE As String = "=COUNTIF({0},{1})"
Private Const FIRST_DATA_ROW As Integer = 2
Private Const TARGET_COLUMN As Byte = 3

Public Sub InsertFormulaCountIf()
    ' replace ActiveSheet with your target sheet if necessary
    With ActiveSheet
        Dim lastRowColumnA As Long
        Dim lastRowColumnB As Long

        lastRowColumnA = .Range("A" & .Rows.Count).End(xlUp).Row
        lastRowColumnB = .Range("B" & .Rows.Count).End(xlUp).Row

        Dim formulaText As String
        Dim targetRangeAddress As String
        targetRangeAddress = "A" & FIRST_DATA_ROW & ":A" & lastRowColumnA ' e.g. A2:A500
        formulaText = Replace(COUNTIF_TEMPLATE, "{0}", targetRangeAddress)

        Dim rowIndex As Long
        For rowIndex = FIRST_DATA_ROW To lastRowColumnB
            .Cells(rowIndex, TARGET_COLUMN).Formula = Replace(formulaText, "{1}", "B" & rowIndex)
        Next rowIndex
    End With

End Sub