如何自动关闭模式窗体

Question

I have a VB6 project and I implement a session timer with an automatic logout.

My problem is if a modal form is opened, this form is not in Forms Collection so I can't know if this form is opened in order to unload it. With non modal forms, no problems.

If anyone have an idea ? Is it possible to show all opened forms (non modal AND modal) ?

Thanks for your responses

Edit : code snippet :

form creation :

Dim FormLoc As New F_Options
FormLoc.Show vbModal

form destruction :

For Each mFrm In Forms
    unload mFrm
next    

For Each mFrm In F_MDIParent.MDIActiveX1.Forms
    unload mFrm
next 

Main form is a MDI Form. Other forms can be open and dock in MDI Mainform but some forms are "normal".

Edit :

I made some tests and Forms collection depend on a project, I thought that this collection was global for the application but apparently not.

I want to close all forms from main project. I can have a modal form opened by another project (90 projects for all the application)

Answer 1

you can also use Windows API functions if you just want to make sure it is closed:

Private Declare Function CloseWindow Lib "user32" Alias "CloseWindow" (ByVal hwnd As Long) As Long Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Dim wid as long wid=FindWindow(vbnullstring,"") if wid <> 0 then CloseWindow wid

Answer 2

One alternative that may work;

do until Screen.ActiveForm is Nothing
    unload Screen.ActiveForm
loop

Answer 3

modal, modeless, and default forms do show up in the forms collection

run the following test project to see it happening :

'project with 2 forms
'  form1 with :
'    1 label: name=Label1
'    1 timer: name=Timer1
'    4 command buttons: names are Command1, Command2, Command3, Command4
'  form2 with nothing on it
Option Explicit

Private Sub Command1_Click()
  Dim frm As New Form2
  frm.BackColor = vbRed
  frm.Show vbModal
End Sub

Private Sub Command2_Click()
  Dim frm As New Form2
  frm.BackColor = vbGreen
  frm.Show vbModeless, Me
End Sub

Private Sub Command3_Click()
  Dim frm As New Form2
  frm.Show
End Sub

Private Sub Form_Load()
  With Screen
    Move .Width / 2, 0, .Width / 2, .Height / 2
  End With 'Screen
  Command1.Caption = "modal"
  Command2.Caption = "modeless"
  Command3.Caption = "default"
  Command4.Caption = "unload"
  With Timer1
    .Interval = 1000
    .Enabled = True
  End With 'Timer1
End Sub

Private Sub Form_Resize()
  Dim sngLblWidth As Single, sngLblHeight As Single
  Dim sngCmdWidth As Single, sngCmdHeight As Single
  sngCmdHeight = 495
  sngLblHeight = ScaleHeight - sngCmdHeight
  sngLblWidth = ScaleWidth
  sngCmdWidth = sngLblWidth / 4
  Label1.Move 0, 0, sngLblWidth, sngLblHeight
  Command1.Move 0, sngLblHeight, sngCmdWidth, sngCmdHeight
  Command2.Move sngCmdWidth, sngLblHeight, sngCmdWidth, sngCmdHeight
  Command3.Move 2 * sngCmdWidth, sngLblHeight, sngCmdWidth, sngCmdHeight
  Command4.Move 3 * sngCmdWidth, sngLblHeight, sngCmdWidth, sngCmdHeight
End Sub

Private Sub Timer1_Timer()
  Dim frm As Form
  Dim strShow As String
  strShow = CStr(Now)
  For Each frm In Forms
    strShow = strShow & vbCrLf & frm.Name
  Next frm
  Label1.Caption = strShow
End Sub

[EDIT]

add 3 command buttons to form2 and click them to test what happens upon unloading

test it while running from the ide and notice the difference when a modal form is shown, when the modeless form is shown (with owner), and when a default form is shown (without owner) .. pay attention to the 'run' button i the ide .. when unloading form1 with a model form shown, the application remains running

here is the code for Form2

Option Explicit

Private Sub Command1_Click()
  UnloadForms "Form1"
End Sub

Private Sub Command2_Click()
  UnloadForms "Form2"
End Sub

Private Sub Command3_Click()
  UnloadForms ""
End Sub

Private Sub Form_Load()
  Command1.Caption = "Unload Form1"
  Command2.Caption = "Unload Form2"
  Command3.Caption = "Unload All"
End Sub

Private Sub UnloadForms(strName As String)
  Dim frm As Form
  For Each frm In Forms
    If InStr(frm.Name, strName) > 0 Then
      Unload frm
    End If
  Next frm
End Sub

[EDIT 2]

below is the sub which i use to unload all my forms, this sub is in a module so i can call it everywhere

Public Sub UnloadAll(strExcept As String, blnKeepMDI As Boolean)
  Dim frm As Form
  'unload all other forms
  For Each frm In Forms
    Select Case frm.Name
      Case "mdiPaneel"   'unload mdi as last
      Case "frmMsg"      'dont unload msg unless specified
      Case strExcept     'dont unload this if mdi stays
        If blnKeepMDI = False Then
          Unload frm
        End If
      Case Else
        Unload frm
    End Select
  Next frm
  If blnKeepMDI = False Then
    'unload mdi and finish program
    Unload mdiPaneel
  End If
End Sub