Perl：清除嵌套散列中的值

Question

If I have a hash reference defined as:

my %hash1=(
    "a" => 1,
    "b" => 2,
    "c" => {
               "d" => 4,
               "e" => 5
           }
    );

my $r_hash1 = \%hash1;

Would using:

$r_hash1->{c}=();

To clear the keys in %hash1{c} for reuse be clean?

If so, I was also wondering if I had:

my %hash1=(
    "a" => 1,
    "b" => 2
);

my %hash2=(
    "d" => 4,
    "e" => 5
);

my $r_hash1 = \%hash1;
my $r_hash2 = \%hash2;

$r_hash1->{"c"} = $r_hash2;

Whether using:

$r_hash1->{c}=();

Would free the memory used by %hash2 for reuse as surely it would have to be used in hash context:

%$r_hash1->{c}

But this would look at $r_hash1 in hash context, rather than the contents of $r_hash1->{c}.

Thanks.

Answer 1

If you want to empty out a nested hash (but still have the hash exist) then you need to dereference it first:

%{ $r_hash1->{c} } = ( );

Alternatively, you could just assign an empty hashref in its place:

$r_hash1->{c} = { };

In your second example, if you set $r_hash1->{c} = $r_hash2 , and then clear it with %{ $r_hash1->{c} } = ( ) , the stuff in %hash2 will be cleared. This is because you are dereferencing $r_hash1->{c} , which is a copy of $r_hash2 , which is a reference to %hash2 .

Here's a simple program which demonstrates the outcome:

perl -MData::Dumper -E '%h1 = ( a => 1, b => 2 ); %h2 = ( d => 4, e => 5 ); $h1{c} = \%h2; say Dumper \%h1; %{ $h1{c} } = ( ); say Dumper \%h1; say Dumper \%h2'
$VAR1 = {
          'c' => {
                   'e' => 5,
                   'd' => 4
                 },
          'a' => 1,
          'b' => 2
        };

$VAR1 = {
          'c' => {},
          'a' => 1,
          'b' => 2
        };

$VAR1 = {};

This is slightly abbreviated (I didn't bother with the intermediate named references.) The first dump shows %h1 with its reference to %h2 . The second dump shows %h1 after dereferencing the reference and clearing it out. The third dump shows the original %h2 after it has been cleared.

On the other hand, if you use $h1{c} = { } , the original %h2 will be unaffected, because you are simply replacing the value of $h1{c} . It was originally a reference to %h2 ; now it's a reference to a new anonymous hash.