尝试并无法通过VBA在Excel中的列中循环。 我究竟做错了什么？

Question

I'm trying to loop through the A column in Excel. Check if its got a value, if it has, move to the adjacent cell in the b column and check that value and store it to use for a search.

I can't even get the loop through the A column working yet. I've looked at hundreds of examples and what I have should work.

Can someone please point out what is missing? This is my code:

Sub AdjacentRow()

    Dim xlWrkBk As Excel.Workbook

    Dim xlsht As Excel.Worksheet
    Dim xl As Excel.Application

    Set xl = CreateObject("Excel.Application")
    Set xlWrkBk = GetObject("C:\Users\my_username\Desktop\AgileProjects\ITAG Open Interactions.xlsx")
    Set xlsht = xlWrkBk.Worksheets(1)

    Dim i, j, FirstCell, LastCell As Integer
    Dim strIMresult As String


    Dim Cell, Row, Column As Excel.Range

    'Set Cell = Range("A9").End(xlDown)
    'Set Cell = Range([a1], [a250])

    For Each Row In Range("A9:A250").Rows
        If Not IsEmpty(ActiveCell.Value) Then
            'move to adjacent cell
            ActiveCell.Offset(0, 1).Select
            If Not IsEmpty(ActiveCell.Value) Then
                'copy the value
                strIMresult = ActiveCell.Value
                'ActiveCell.Offset(1, 0).Select
                'ActiveCell = strIMresult
                Debug.Print strIMresult
            Else
                ActiveCell.Offset(0, -1).Select
            End If
        End If
    Next Row

End Sub

Answer 1

Many of your variables are not dimensioned properly which may be contributing to errors (or may in the future contribute errors).

For example, Dim i, j, FirstCell, LastCell As Integer declares i , j , and FirstCell as Variant. Only LastCell as Integer . Same with: Dim Cell, Row, Column As Excel.Range which declares Cell , Row as Variant, with only Column declared as a Range variable.

This should get you started. I cleaned up the declarations, and I have removed the lines that you commented out and made some changes so your Loop should work properly now.

Sub AdjacentRow()

Dim xlWrkBk As Excel.Workbook

Dim xlsht As Excel.Worksheet
Dim xl As Excel.Application

Dim i#, j#, FirstCell#, LastCell#
Dim strIMresult As String
Dim cl As Excel.Range
Dim clNext As Excel.Range


Set xl = CreateObject("Excel.Application")
Set xlWrkBk = GetObject("C:\Users\my_username\Desktop\AgileProjects\ITAG Open Interactions.xlsx")
Set xlsht = xlWrkBk.Worksheets(1)

For Each cl In xlsht.Range("A9:A250")
    Set clNext = cl.Offset(0, 1)
    If Not cl.Value = vbNullString Then
        'check the adjacent cell'
        If Not clNext.Value = vbNullString Then
            'store the value'
            strIMresult = clNext.Value
            Debug.Print strIMresult
        End If
    End If
Next Row

End Sub

Answer 2

GENERAL COMMENT 1

Dimensioning in VBA should be done per variable, only the last one in a row will get the type that you specify. So the following:

Dim Cell, Row, Column As Excel.Range

Should becomes:

Dim Cell As Excel.Range, Row As Excel.Range, Column As Excel.Range

If this script is in Excel VBA you dont even need to use Excel., just dimension it as Range:

Dim aa As Range

GENERAL COMMENT 2

You use Row, Column and Cell as local variables, these are existing Objects in Excel and should not be used as local variable names as well!! Furthermore they are not saying much with names like this. Please changes those variable/object names to something meaningful AND unique!

Now to the problem

You do loop through the Rows, however your script doesnt interact with the Row at all! Your script is interacting with the ActiveCell range instead... So change ActiveCell in your script for a reference to the Row variable (with its new name...):

If Not IsEmpty(Row.Value) Then

And see what happens!

Furthermore I am wondering if Range("A9:A250").Rows actually contains anything as you dont explicitly refer to the Excel worksheet object. You better run this in debug mode to see if your local variables and objects actually refer to what you expect...

Answer 3

I don't get what your code is meant to do, but I think that there are few problems in your code:

1) Avoid using variable name identical to the vba objects names, like "row", "column", "cell". It may cause bugs, so better use same names like "myrow", "row1", "rw" etc.

2) If you want to make a loop on one of the "ITAG Open Interactions.xlsx" sheets, you must refer to it's name and specify the sheet, like "xlWrkBk.Worksheets(1).Range("A9:A250").Rows"

3) Before ActiveCell will refer to the iterated cell, you must activate it, like (row1.Activate). However, I prefer to use select and selection.

4) When you open other excel application and create objects, at the end of the code you should close or release them, like "set xlWrkbk = nothing" or "xl.Application.Quit".

5) When using loop "For Each" you can just check if currently iterated range fulfil your coditions and then do specified actions. You don't have to return to the right column, so you can skip the outer if statement.

I don't exacly know what you want to do with the strIMresult, however whole code should look like that:

Sub AdjacentRow()

Dim xlWrkBk As Excel.Workbook
Dim xl As Excel.Application

Set xl = CreateObject("Excel.Application")
Set xlWrkBk = GetObject("D:\Excel\a.xlsx")

Dim i, j As Integer
Dim strIMresult As String
Dim row1 As Excel.Range

xlWrkBk.Worksheets(1).Activate
For Each row1 In xlWrkBk.Worksheets(1).Range("A9:A250").Rows
    row1.Select
    If Not IsEmpty(Selection) Then
        'move to adjacent cell
        Selection.Offset(0, 1).Select
        strIMresult = Selection
        'I dont understand what the code should do with the value from b column,
        'so you should add here some code.
        'For now I just added code that print string value in the message box
        MsgBox (strIMresult)
    End If
Next

Set xlWrkBk = Nothing
xl.Application.Quit

End sub

Answer 4

This is what worked:

Sub AdjacentRow()

    Dim xlWrkBk As Excel.Workbook

    Dim xlsht As Excel.Worksheet
    Dim xl As Excel.Application

    Set xl = CreateObject("Excel.Application")

    Set xlWrkBk = GetObject("C:\Users\My_Account\Desktop\tst.xlsx")
    Set xlsht = xlWrkBk.Worksheets(1)

    Dim i, j, FirstCell, LastCell As Integer
    Dim strIMresult As String


    Dim Cell, Row, Column As Excel.Range

    For Each Row In xlsht.Range("A9:A250").Rows
        For Each Cell In Row.Cells

            If Len(Cell.Value) > 0 Then
                'move to adjacent cell
                ActiveCell.Offset(0, 1).Select

                If Len(ActiveCell.Value) > 0 Then
                    'copy the value
                    strIMresult = ActiveCell.Value

                    Debug.Print strIMresult
                Else
                    ActiveCell.Offset(0, -1).Select
                End If
            End If
        Next Cell
    Next Row
End Sub

Ultimately the fix was in the following

For Each Row In Range("A9:A250").Rows

changing to

For Each Row In xlsht.Range("A9:A250").Rows

to specify the work sheet that had to be looped through. Then adding,

For Each Cell In Row.Cells