SQL Server触发器的游标不起作用

Question

I created a cursor inside a trigger and it is not working properly. Please help me fix it

Create trigger Posts_Raw_To_Queue_Trigger  ON SendNotificationPostsRaw FOR INSERT
AS
BEGIN

DECLARE @PostID uniqueidentifier  
DECLARE @UserID uniqueidentifier
DECLARE @ProfID int
DECLARE @Email nvarchar(100)
DECLARE @CreationTime  datetime
DECLARE @SpecialityID int

SELECT @ProfID= ProfessionalID,@Email= Email from Professionals where UserID=@UserID
SELECT @PostID = I.PostID,@UserID = I.UserID ,@CreationTime =I.CreationTime  FROM INSERTED I

DECLARE post_relation_cursor CURSOR FOR select CategoryId  from PostCategoryRelations  where PostId=@PostID;

OPEN post_relation_cursor;
FETCH NEXT FROM post_relation_cursor INTO @SpecialityID 
WHILE @@FETCH_STATUS = 0  
BEGIN  
       INSERT INTO SendNotificationPostsQueue (UserID,PostID,SpecialityID,TemplateID,CreationTime,SendTime,JSONParameters) Values(@UserID,@PostID,1,1,'04/11/2013','04/11/2013','')

       FETCH NEXT FROM post_relation_cursor INTO @SpecialityID;
END;
CLOSE post_relation_cursor;
DEALLOCATE post_relation_cursor;

END

If I remove cursor and insert dummy values into SendNotificationPostsQueue , it works. So there is problem with my cursor... Please tell me why cursor is not working?

Answer 1

It doesn't appear that you need to use a cursor at all and would be better off not using one in almost all cases. Simply replace the body of your trigger (the part between begin and end) with a standard insert:

INSERT INTO SendNotificationPostsQueue (UserID,PostID,SpecialityID,TemplateID,CreationTime,SendTime,JSONParameters)
SELECT
    i.UserID,
    i.PostID,
    1,
    1,
    '04/11/2013', -- Might want i.CreationTime or current_timestamp
    '04/11/2013',
    ''
FROM INSERTED i
    -- possibly want "LEFT JOIN Professionals p on i.UserID = p.UserID" here to grab other info

Note how I am not using the values clause of an insert which can only insert one row. I'm putting a select statement as part of the insert, thus inserting as many rows as the select returns. This means that we don't need to use a cursor, and don't need a bunch of variables to power the cursor.

One issue with your current code, as @automatic has mentioned, is that you're assuming INSERTED only holds one row. If it has more than one, then you'll throw an error when you try to assign a column to a variable.

For reasons of elegance, maintainability, and performance, I strongly urge you to abandon this cursor and run a simple insert (since that's all that your cursor is doing anyway).

Answer 2

Possible problem is here -

CREATE TRIGGER dbo.Posts_Raw_To_Queue_Trigger 

    ON SendNotificationPostsRaw
    -- for view
    INSTEAD OF INSERT
    -- OR
    -- for table
    AFTER INSERT

AS BEGIN

    DECLARE 
          @PostID UNIQUEIDENTIFIER
        , @UserID UNIQUEIDENTIFIER
        , @ProfID INT
        , @Email NVARCHAR(100)
        , @CreationTime DATETIME
        , @SpecialityID INT

    SELECT  @ProfID = ProfessionalID
        ,   @Email = Email
    FROM Professionals
    WHERE UserID = @UserID

    -- this posible return invalid result (random record from inserted sequence)
    SELECT  @PostID = I.PostID
        ,   @UserID = I.UserID
        ,   @CreationTime = I.CreationTime
    FROM INSERTED I

    DECLARE post_relation_cursor CURSOR LOCAL READ_ONLY FAST_FORWARD FOR
        SELECT CategoryID
        FROM dbo.PostCategoryRelations
        WHERE PostId = @PostID;

    OPEN post_relation_cursor;

    FETCH NEXT FROM post_relation_cursor INTO @SpecialityID

    WHILE @@FETCH_STATUS=0 BEGIN

        INSERT INTO SendNotificationPostsQueue (
                UserID
            ,   PostID
            ,   SpecialityID
            ,   TemplateID
            ,   CreationTime
            ,   SendTime
            ,   JSONParameters
        )
        SELECT
                 @UserID
             ,   @PostID
             ,   @SpecialityID --- !!!
             ,   1
             ,   '04/11/2013'
             ,   '04/11/2013'
             ,   ''


        FETCH NEXT FROM post_relation_cursor INTO @SpecialityID;

    END;

    CLOSE post_relation_cursor;
    DEALLOCATE post_relation_cursor;

END

---

Update

If I understand you correctly, the business logic must be like this:

CREATE TRIGGER dbo.Posts_Raw_To_Queue_Trigger 

    ON dbo.SendNotificationPostsRaw
    [INSTEAD OF]/[AFTER] INSERT

AS BEGIN

    SET NOCOUNT ON;

    DECLARE 
          @PostID UNIQUEIDENTIFIER
        , @UserID UNIQUEIDENTIFIER
        , @ProfID INT
        , @Email NVARCHAR(100)
        , @CreationTime DATETIME
        , @SpecialityID INT

    DECLARE cur CURSOR LOCAL READ_ONLY FAST_FORWARD FOR
        SELECT
              i.PostID
            , i.UserID
            , ProfID = p.ProfessionalID
            , p.Email
            , i.CreationTime
            , pcr.CategoryID
        FROM INSERTED i
        JOIN dbo.Professionals p ON i.UserID = p.UserID
        JOIN dbo.PostCategoryRelations pcr ON i.PostID = pcr.PostID

    OPEN cur

    FETCH NEXT FROM cur INTO 
          @PostID 
        , @UserID 
        , @ProfID 
        , @Email
        , @CreationTime 
        , @SpecialityID 

    WHILE @@FETCH_STATUS = 0 BEGIN

        INSERT INTO dbo.SendNotificationPostsQueue 
        (
              UserID
            , PostID
            , SpecialityID
            , TemplateID
            , CreationTime
            , SendTime
            , JSONParameters
        )
        SELECT
              @UserID
            , @PostID
            , @SpecialityID
            , 1
            , @CreationTime
            , @CreationTime
            , ''

        FETCH NEXT FROM cur INTO 
              @PostID 
            , @UserID 
            , @ProfID 
            , @Email
            , @CreationTime 
            , @SpecialityID 

    END

    CLOSE cur
    DEALLOCATE cur

END