For / f中的delims选项可以是字符串吗？

Question

My code is as follows:

for /F "tokens=1,2 delims=%0.3%" %%i in ("double a = 0.3;") do (

set a=%%i

set b=%%j

)

I want a = "double a = " and b =";" but this code can not help.

Does anyone know how to solve this problem?

Answer 1

Your code as posted simply will not work at all.

for /F "tokens=1,2 delims=%0.3%" %%i in ("double a = 0.3;") do (

The %0 will be replaced by yourbatchfilename and since %" % has no value set in the environment, it will be replaced by [nothing] yielding

for /F "tokens=1,2 delims=yourbatchfilename.3i in ("double a = 0.3;") do (

which, unsurprisingly, is a syntax error.

@ECHO OFF
SETLOCAL
for /F "tokens=1,2 delims=3.0" %%i in ("double a = 0.3;") do (
set a=%%i
set b=%%j
)
ECHO first way  :a=%a%+ b=%b%+

ENDLOCAL
SETLOCAL
SET "astring=double a = 0.3;"
SET "aseparator=0.3"
SET "arotorapes=3.0"
for /F "tokens=1,2 delims=%arotorapes%" %%i in ("double a = 0.3;") do (
SET a=%%i
)
CALL SET b=%%astring:*%aseparator%=%%

ECHO second way :a=%a%+ b=%b%+

ENDLOCAL
SETLOCAL
SET "astring=double a = 0.3;"
SET "aseparator=0.3"
CALL SET b=%%astring:*%aseparator%=%%
SET "c=%b%%aseparator%"
SET "a=%astring%"
:loop
IF DEFINED c SET c=%c:~0,-1%&SET a=%a:~0,-1%&GOTO loop

ECHO third way  :a=%a%+ b=%b%+

In the first method, I've changed the sequence of the characters to deomstrate that any sequence of any of the characters between the = and " of a delims clause acts as a SINGLE delimiter. The code "works" by failing to fail.

In the second method, the setting of a works in the same way. Without further information, it's really not possible to tell whether this is adequate. b is set by specifically replacing all characters in the source string up to and including the separator with [nothing]

In the third method, the same operation establishes b , and then b and the separator are concatenated. Systematically lop off the characters at the end of a copy of the original original string and the concatenated string. When the concatenated version becomes empty, you've deleted the separator and the appendix from the original, leaving the portion of the original string up to the separator.