列中每个单元格的公式中的单元格引用增量

Question

Forgive me for my ignorance but I need help with the following code

Sub D3()
Dim currentRow As String
Dim sTemp As String

sTemp = Range("D3").Formula 'cell in sheet that needs reference to be increased

Do While (IsNumeric(Right(sTemp, 1)))

    currentRow = Right(sTemp, 1) & currentRow
    sTemp = Mid(sTemp, 1, Len(sTemp) - 1)

Loop

currentRow = CLng(currentRow) + 1 'Number to increment cell reference by

Range("D3").Formula = sTemp & currentRow

End Sub

As I've forgotten most of my coding and for what I thought was a simple solution I went to google and got the code above. It works excellently on a single cell but I want to be able to update the formula in a range of cells from D3 to D29 and this is where i've become stuck.

I've tried

sTemp = Range("D3:D29").Formula

with no luck.

The only way I can currently get what I want is to create 120ish Macros and run them within a Master Macro - which I'm sure you'll agree isn't very efficent.

I want to be able to apply the solution easily to other columns within the sheet.

Thanks

Answer 1

Ignoring the reason why you want to do this. I guess what you are missing is you just need to loop your code.

I guess you know the range that is D3:D29. Modifying your code as below

Sub D3()
Dim currentRow As String
Dim sTemp As String
Dim i as Integer


For i = 3 to 29

currentRow = ""

sTemp = Range("D" & i).Formula 'cell in sheet that needs reference to be increased

Do While (IsNumeric(Right(sTemp, 1)))

    currentRow = Right(sTemp, 1) & currentRow
    sTemp = Mid(sTemp, 1, Len(sTemp) - 1)

Loop

currentRow = CLng(currentRow) + 1 'Number to increment cell reference by

Range("D" & i).Formula = sTemp & currentRow

Next i
End Sub

Answer 2

If I have understood your intent correctly, the following code should do the trick. It presumes that the formulas in the target range are single cell references (eg, "=CC95").*

I've eliminated the type conversion errors that prevented the code from compiling. In addition, I've rewritten the somewhat confused code to increment the row numbers.

To run the procedure on other columns, just change the values of the targetColumn, firstTargetRow, and lastTargetRow variables.

Sub IncrementFormulaRows()
   Dim formulaString As String
   Dim targetColumn As String
   Dim firstTargetRow As Long
   Dim lastTargetRow As Long
   Dim i As Long
   Dim j As Long

   targetColumn = "D"
   firstTargetRow = 3
   lastTargetRow = 29

   For i = firstTargetRow To lastTargetRow
      If Range(targetColumn & i).HasFormula Then          '// Skip cell if it does not 
         formulaString = Range(targetColumn & i).Formula  '// contain a formula
         j = Len(formulaString)
         While (j > 0) And IsNumeric(Mid(formulaString, j, 1))  '// Walk formula backwards 
            j = j - 1                                           '// to find last char of  
         Wend                                                   '// column reference
         Range(targetColumn & i).Formula = Left(formulaString, j) _
            & (Val(Mid(formulaString, j + 1, Len(formulaString) - j)) + 1)
      End If
   Next i
End Sub

*The formula will actually run when a more complicated formula is used, as long as it ends in a single cell reference. However, I assume the result would be undesirable.