如何在ASP Classic中的类中初始化数组属性？

Question

How does one initialize an array property in a class? How to initialize array1 below:

class Class1
    private count
    private array1

    private sub class_initialize
        count     = 0
        array1(0) = 0 'initialize first element
    end sub

end class

Results in the error: Microsoft VBScript runtime error '800a000d' Type mismatch: 'array1'

Answer 1

I figured it out:

class Class1
    private count
    private array1

    private sub class_initialize
        count  = 0
        array1 = array() 'initialize array property
    end sub

    'to add a new element to array property
    public sub add(input)
        redim preserve array1(count + 1)
        array1(count) = input
        count = count + 1
    end sub
end class

Answer 2

Because reformed's class does not work correctly and ShadowWizards' comment is dangerous:

Option Explicit

class ArrMemberA
    private count
    private array1

    private sub class_initialize
        count  = 0
        array1 = array() 'initialize array property
    end sub

    'to add a new element to array property
    public sub add(input)
        redim preserve array1(count + 1)
        array1(count) = input
        count = count + 1
    end sub

    Public Function toString()
      toString = "[" & Join(array1, "*") & "]"
    End Function
end class

Class ArrMemberB
  Private m_a
  Private Sub Class_Initialize
    m_a = Array() ' initialize to empty dynamic array
  End Sub
  Public Sub add(input)
    ReDim Preserve m_a(UBound(m_a) + 1)
    m_a(UBound(m_a)) = input
  End Sub
  Public Function toString()
    toString = "[" & Join(m_a, "*") & "]"
  End Function
End Class

Class ArrMemberC
  Private m_a()
  Public Sub add(input)
    ReDim Preserve m_a(UBound(m_a) + 1)
    m_a(UBound(m_a)) = input
  End Sub
  Public Function toString()
    toString = "[" & Join(m_a, "*") & "]"
  End Function
End Class

Class ArrMemberD
  Private m_a()
  Private m_n
  Private Sub Class_Initialize
    m_n = -1 ' initialize to empty ubound
  End Sub
  Public Sub add(input)
    m_n = m_n + 1
    ReDim Preserve m_a(m_n)
    m_a(m_n) = input
  End Sub
  Public Function toString()
    toString = "[" & Join(m_a, "*") & "]"
  End Function
End Class

Dim a : Set a = New ArrMemberA
a.add "zero"
a.add "one"
WScript.Echo "a:", a.toString(), "- spurious empty tail element"

Dim b : Set b = New ArrMemberB
b.add "zero"
b.add "one"
WScript.Echo "b:", b.toString()

Dim c : Set c = New ArrMemberC
On Error Resume Next
 c.add "zero"
 WScript.Echo "c:", Err.Description, "- Ubound() fails for the abomination created by 'Private m_a()'"
On Error GoTo 0

Dim d : Set d = New ArrMemberD
d.add "zero"
d.add "one"
WScript.Echo "d:", d.toString()

output:

cscript demoarray.vbs
a: [zero*one*] - spurious empty tail element
b: [zero*one]
c: Subscript out of range - Ubound() fails for the abomination created by 'Private m_a()'
d: [zero*one]

(a) shows that it is risky to roll your own counter; (b) does it my way; (c) proves that the result of "Dim/Private/Public varname()" can't be UBound(); (d) demonstrates that 'to make it work' you need the Class_Initialize sub you tried to avoid.