如何使用cmake（和visual studio）为qt设计器创建自定义（小部件）插件

Question

The amount of tutorials, how to create a qt designer plugin is very thin..and the ones i found always use qt creator ( like this one : http://qt-project.org/doc/qt-4.8/designer-customwidgetplugin.html ). Where i have to add some qt definitions in the .pro file

 CONFIG      += designer plugin

I use CMake and Visual Studio for coding, so it would be really awesome if someone could tell me how i successfully create a .dll that i can put in the plugins/designer folder to have the custom widget show up in Qt Designer

Answer 1

Disclaimer: I know this is an old question but Even now I didn't find complete resources on how to do it.

I can't answer you for the Visual Studio part since I build on the (windows) command line, but here is my cmake.

I assume you have already created the following files related to the plugin, ie:

• widget.h
• widget.cpp
• widget.ui
• widgetPlugin.h -> QDesignerCustomWidgetInterface class
• widgetPlugin.cpp

And that you want to create a library with multiple plugins, ie created the related files:

• plugins.h -> QDesignerCustomWidgetCollectionInterface class
• plugins.cpp

The content of the files simply follow what's in the tutorials.

The CMakeLists.txt is:

cmake_minimum_required(VERSION 2.8)

set(PROJECT Plugins)
project(${PROJECT})

# Needed to compile against ui and moc generated files
include_directories(${CMAKE_CURRENT_BINARY_DIR})

set(SOURCES
    plugins.cpp
    widgetPlugin.cpp
    widget.cpp
)

set(HEADERS
    plugins.h
    widgetPlugin.h
    widget.h
)

set(FORMS
    widget.ui
)

# This is experimental, it works but it may be not optimal, don't hesitate to change this
find_package(Qt4 REQUIRED QtCore QtGui QtDesigner)
if (QT4_FOUND AND QT_QTCORE_FOUND AND QT_QTGUI_FOUND AND QT_QTDESIGNER_FOUND)
    set(QT_USE_QTDESIGNER TRUE)
    include(${QT_USE_FILE})
else()
    message(FATAL_ERROR "no qt...")
endif()

qt4_wrap_cpp(HEADERS_MOC ${HEADERS})
qt4_wrap_ui(FORMS_HEADERS ${FORMS})
qt4_add_resources(RESOURCES_RCC ${RESOURCES})

# Here too, I'm not sure every define is necessary
include_directories(${CMAKE_CURRENT_BINARY_DIR})
add_definitions(-DQT_PLUGIN)
add_definitions(-DQT_NO_DEBUG)
add_definitions(-DQT_SHARED)
add_definitions(-DQDESIGNER_EXPORT_WIDGETS)

add_library(${PROJECT} SHARED
    ${SOURCES}
    ${HEADERS_MOC}
    ${FORMS_HEADERS}
    ${RESOURCES_RCC}
)
target_link_libraries(${PROJECT} ${QT_LIBRARIES})

# Install the library in QtDesigner plugin directory
install(TARGETS ${PROJECT}
    DESTINATION ${QT_PLUGINS_DIR}/designer
)

To reload the plugins in QtDesigner, go to Help > About Plugins > Reload.

Then in the other CMakeLists.txt, I didn't want to include the library since there are also useless *Plugin files. So I included again the files I wanted :

cmake_minimum_required(VERSION 2.8)

set(PROJECT GPAUSX)
project(${PROJECT})

# Include the other CMakeLists.txt
subdirs(Plugins)
find_package(Qt4 REQUIRED)

# Files to insert
set(SOURCES
    main.cpp
    MainWindow.cpp
    ${Plugins_SOURCE_DIR}/widget.cpp

)
set(HEADERS
    MainWindow.h
    ${Plugins_SOURCE_DIR}/widget.h

)
set(FORMS
    MainWindow.ui
    ${Plugins_SOURCE_DIR}/widget.ui
)

qt4_wrap_cpp(HEADERS_MOC ${HEADERS})
qt4_wrap_ui(FORMS_HEADERS ${FORMS})
qt4_add_resources(RESOURCES_RCC ${RESOURCES})

include(${QT_USE_FILE})
include_directories(${CMAKE_CURRENT_BINARY_DIR})
add_definitions(${QT_DEFINITIONS})
# I'm no expert in libraries so, intuitively I'd say this is useless but it won't compile if I don't define it.
# This clearly needs to get fixed.
add_definitions(-DQDESIGNER_EXPORT_WIDGETS)

# Possible variants making it compile :
# 1/ either include Plugins_BINARY_DIR or include .uis
#   including the binary dir makes use of the already generated .uis
# 2/ either target Plugins or add Plugins .uis, .hs and .cpps with -DQDESIGNER_EXPORT_WIDGETS
#   if you target plugins, make sure you compile with the same flags

add_executable(${PROJECT}
    ${SOURCES}
    ${HEADERS_MOC}
    ${FORMS_HEADERS}
    ${RESOURCES_RCC}
)
target_link_libraries(${PROJECT}
    # Uncomment the following if you want to target Plugins
    #Plugins
    ${QT_LIBRARIES}
)

Hope you'll find it useful !

Answer 2

Just use the cmake's qt auto tools and add all sources(.cpp .ui .qrc etc) to the target as follow:

set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTORCC ON)
set(CMAKE_INCLUDE_CURRENT_DIR ON)

find_package(Qt4 REQUIRED QtCore QtGui QtDesigner #...
)
include(${QT_USE_FILE})
add_definitions(${QT_DEFINITIONS})

add_library(someplugin SHARED
    path/to/plugin/someplugin.cpp
    path/to/plugin/someplugin.qrc
    path/to/plugin/someplugin.ui
    path/to/plugin/s/other/src.cpp
    #...
)

target_link_libraries(someplugin ${QT_LIBRARIES})

install(TARGETS someplugin
    DESTINATION ${QT_PLUGINS_DIR}/designer
)