Perl-将split（）的输出分配给哈希片-检测长度不匹配

Question

I am converting a record of tab-separated values into a hash, as follows:

my @field_names = qw(foo bar xyzzy);
my $record = "33\t45\t78\n";
my %feqv_hash;
@feqv_hash{@field_names} = split /\t/, $record;

which creates %feqv_hash :

{ foo => 33, bar => 45, xyzzy => 78 }

I'd like to be able to ensure, as quickly as possible, that $record has the same number of values as @field_names .

This is the best I can come up with:

my @field_names = qw(foo bar xyzzy);
my $record = "33\t45\t78\n";
my @field_values = split /\t/, $record;
croak if @field_names != @field_values;
my %feqv_hash;
@feqv_hash{@field_names} = @field_values;

Is there a way that might execute any faster? (eg not require the temp array @field_values )

Answer 1

First of all, you want to use -1 instead of 0 for split 's third arg so you don't remove any fields that are present but empty.

my @field_names = qw(foo bar xyzzy);
my $record = "33\t45\t78\n";
my %feqv_hash;
@feqv_hash{@field_names} = split /\t/, $record, -1;

---

Let's see how slow the check is.

use strict;
use warnings;
use Benchmark qw( timethese );
use Carp      qw( croak );

my %tests = (
   without => <<'__EOI__',
      my %feqv_hash;
      @feqv_hash{@field_names} = split /\t/, $record, -1;
__EOI__
   with => <<'__EOI__',
      my @field_values = split /\t/, $record, -1;
      croak if @field_names != @field_values;
      my %feqv_hash;
      @feqv_hash{@field_names} = @field_values;
__EOI__
);    

$_ = 'use strict; use warnings; our @field_names; our $record; '.$_
   for values %tests;

{
   local our @field_names = qw(foo bar xyzzy);
   local our $record = "33\t45\t78\n";
   timethese(-3, \%tests);
}

Results:

without check: 2.7 microseconds
with check:    4.1 microseconds
               ----------------
check:         1.4 microseconds

The check takes 1.4 microseconds. I'm not sure why you think there's a problem.

---

But it is possible to cut that time almost in half by scanning the string with tr/\\t// . : Or by using list assignment in scalar context

use strict;
use warnings;
use Benchmark qw( cmpthese );
use Carp      qw( croak );

my %tests = (
   temp_array => <<'__EOI__',
      my @field_values = split /\t/, $record, -1;
      croak if @field_names != @field_values;
      my %feqv_hash;
      @feqv_hash{@field_names} = @field_values;
__EOI__
   tr => <<'__EOI__',
      croak if @field_names != 1 + $record =~ tr/\t//;
      my %feqv_hash;
      @feqv_hash{@field_names} = split /\t/, $record, -1;
__EOI__
   aassign => <<'__EOI__',
      my %feqv_hash;
      ( @feqv_hash{@field_names} = split /\t/, $record, -1 ) == @field_names
         or croak;
__EOI__
);    

$_ = 'use strict; use warnings; our @field_names; our $record; '.$_
   for values %tests;

{
   local our @field_names = qw(foo bar xyzzy);
   local our $record = "33\t45\t78\n";
   cmpthese(-3, \%tests);
}

Results:

               Rate temp_array         tr    aassign
temp_array 233472/s         --       -30%       -36%
tr         334671/s        43%         --        -8%
aassign    362326/s        55%         8%         --

Answer 2

This is certainly premature optimization; write the code how it is most readable to the likely audience, not for some practically unmeasurable performance boost.

That said, in scalar context, the slice assignment itself (like all list assignments) will return the count of elements on the right, so all you need do is:

( @feqv_hash{@field_names} = split /\t/, $record, -1 ) == @field_names
    or croak;