perl使用数组解析并向哈希键分配多个值

Question

I have files that I'm trying to parse and build a hash and lookup from a third file. File format :

File 1:

ID2
ID4

File 2:

x1 y1 z1 ID1
x2 y2 z2 ID2
x3 y3 z3 ID2
x4 y4 z4 ID4

File 3:

a1 b1
a2 b2
a3 b3

What I'm trying to do :

For all those IDs in File1, look up x and y coordinate using ID field in File2 , and see if 'a' in File3 lies between x and y.

What I have thought so far :

1. Take file 2; parse it into a hash using ID as the key
2. Take file 1; if ID exists in file 2; open file 3 and check coordinates ranges for 'a' and print it

How far have I executed? Not too far. I am trying to read File 2 and parse all element in a hash, but I'm stuck:

while (<FILE>){
    chomp $_;
    my $line = $_;
    my @arr  = split ("\t", $line);
    my $id = $arr[3];

    if (exists ($hash{$id})) {
        my $x = $arr[0];
        my $y  = $arr[1];
        my $z   = $arr[2];
        push @{$hash{$id}{'x'}, $x;
        push @{$hash{$id}{'y'}, $y;
        push @{$hash{$id}{'y'}, $y;
    } else {
        $hash{'id'} = $id;
        $hash{$id}{'x'} = $arr[0];   
        $hash{$id}{'y'} = $arr[1];
        $hash{$id}{'z'} = $arr[2];
    }
}
print Dumper %hash;
close FILE;

But of course, I'm doing something wrong here

Answer 1

This is how to read your file2 into a hash. Note that I think it may be easier to use three-element arrays to hold the x, y and z values rather than a hash.

I would show more but I'm very unclear about how your file3 works, and how it is related to file1 . Do you want to process all values in file1 and find, for each of them, which values in file3 are between the corresponding limits?

use strict;
use warnings;
use autodie;

use Data::Dump;

open my $fh, '<', 'file2.txt';

my %data;

while (<$fh>){
    chomp;
    my @fields = split /\t/;
    my $id = pop @fields;
    for ('x' .. 'z') {
      push @{$data{$id}{$_}}, shift @fields;
    }
}

dd \%data;

output

{
  ID1 => { x => ["x1"], y => ["y1"], z => ["z1"] },
  ID2 => { x => ["x2", "x3"], y => ["y2", "y3"], z => ["z2", "z3"] },
  ID4 => { x => ["x4"], y => ["y4"], z => ["z4"] },
}

---

Update

Although the storage format from the above code is what I think you intended I don't think it's very workable. I think it would be easier for you to code the rest of the program if you use this

while (<$fh>){
    chomp;
    my @fields = split /\t/;
    my $id = pop @fields;
    push @{$data{$id}}, \@fields;
}

resulting in this

{
  ID1 => [["x1", "y1", "z1"]],
  ID2 => [["x2", "y2", "z2"], ["x3", "y3", "z3"]],
  ID4 => [["x4", "y4", "z4"]],
}

or even this

while (<$fh>){
    chomp;
    my @fields = split /\t/;
    my $id = pop @fields;
    my %item;
    @item{qw/ x y z /} = @fields;
    push @{$data{$id}}, \%item;
}

which results in this data

{
  ID1 => [{ x => "x1", y => "y1", z => "z1" }],
  ID2 => [
           { x => "x2", y => "y2", z => "z2" },
           { x => "x3", y => "y3", z => "z3" },
         ],
  ID4 => [{ x => "x4", y => "y4", z => "z4" }],
}

Answer 2

I would approach your task this way:

1. load file 1 into memory and keep it as a filter of IDs

2. tie file 3 or load it into memory and otherwise keep it around to index into

3. process file 2 as a stream of requests.

Thus:

#! /usr/bin/env perl
use common::sense;
use Tie::File;
use autodie;

tie my @table, 'Tie::File', 'f3' or die $!;

my %filter;
open my $f, '<', 'f1';
while (<$f>) {
  chomp;
  $filter{$_}++
}
close $f;

while (<>) {
  next unless /^x(\d+) y(\d+) z\d+ (ID\d+)$/;
  next unless exists $filter{$3};
  say((split ' ', $table[$2])[$1])
}

untie @table;

Usage:

$ ./example
x1 y1 z2 ID2
b2
x0 y0 z5 ID2
a1

$ ./example file2
<three blank lines, because your examples are 1-indexed>