如何使用Perl为字符串生成XOR校验和

Question

I am trying to generate checksum for a NEMA(GPS protocol) word using perl. A sample NEMA word is string of characters as shown below

$GPGLL,5300.97914,N,00259.98174,E,125926,A*28

The checksum is calculated by taking XOR of all the characters between $ and * . In this sentence the checksum is the character representation of the hexadecimal value 28.

I tried the following:

my $NMEA_word = 'GPGLL,5300.97914,N,00259.98174,E,125926,A';
my $uff = unpack( '%8A*', $NMEA_word );
print "Hexadecimal number: ", uc(sprintf("%x\n", $uff)), "\n";

But it doesn't seem to give a correct value. Please suggest what shall be rectified

Answer 1

my $uff;
$uff ^= $_ for unpack  'C*', 'GPGLL,5300.97914,N,00259.98174,E,125926,A';
printf "Hexadecimal number: \U%x\n", $uff;
__END__
Hexadecimal number: 28

Answer 2

More functionally,

use List::Util 'reduce';
sub checksum {
    sprintf '%02X', ord reduce { our $a ^ our $b } split //, shift; 
}
print checksum('GPGLL,5300.97914,N,00259.98174,E,125926,A'), "\n";

Answer 3

The unpack facility to generate a checksum adds the field values together, whereas you want then XORed.

This program will do what you ask.

use strict;
use warnings;

my $NMEA_word = 'GPGLL,5300.97914,N,00259.98174,E,125926,A';  

printf "Hexadecimal number: %s\n", checksum($NMEA_word);

sub checksum {
  my ($string) = @_;
  my $v = 0;
  $v ^= $_ for unpack 'C*', $string;
  sprintf '%02X', $v;
}

output

Hexadecimal number: 28