如何在Perl中引用哈希？

Question

If i have something like this:

%hash = {foo => 'bar', foo1=>'bar1',};

or

%hash = (foo => 'bar', foo1=>'bar1',);

or

$hash = {foo => 'bar', foo1=>'bar1',};

or

$hash = (foo => 'bar', foo1=>'bar1',);

How do the above codes differ? and how do i access their components?

Answer 1

The (...) sorts out precedence, while {...} creates an hash reference .

%hash = {foo => 'bar', foo1=>'bar1',};

Assigns the %hash a single value. However, hashes are assigned an even-sized list of key-value-pairs. Your code will use the stringification of the hashref as a key ( HASH(0x123ABC) ), and undef as value. Please use warnings to tell you when you are assigning a non-even-sized list to a hash variable.

%hash = (foo => 'bar', foo1=>'bar1',);

is correct. The RHS list is evaluated in list context, and is assigned to the hash variable. You can access entries like $hash{foo} .

$hash = {foo => 'bar', foo1=>'bar1',};

is correct. A hash reference is assigned to a scalar variable. You can access elements like $hash->{foo} . Note the dereferencing arrow which is neccessary to disambiguate hashref access from hash access (you can have variables named both %hash and $hash in the same scope).

$hash = (foo => 'bar', foo1=>'bar1',);

evaluates the list on the RHS in scalar context, and will assign the last value. So $hash = "bar1" is the same thing.

Answer 2

1. Assigns a hash reference to a hash. This doesn't make sense.
2. Assigns a list to a hash. This is how you normally handle hashes.
3. Assigns a hash reference to a scalar. This is how you normally handle hash references.
4. Assigns a list to a scalar. You'll end up with the last value being stored.

To assess a scalar value in a hash (2):

$hash{'foo'}

To access a scalar value in a hashref (3):

$hash->{'foo'}

See perldoc perlref for more about references

Answer 3

You want

my %hash = ( key1 => 'value1', key2 => 'value2' );  # Hash

or

my $hash = { key1 => 'value1', key2 => 'value2' };  # Reference to hash

---

When one assigns a list to a hash, it is treated as a list of key-value pairs,so the proper way to initialize a hash is

my %hash = ( key1 => 'value1', key2 => 'value2' );

---

{ ... }

is similar to

do { my %anon = ( ... ); \%anon }

It creates an anonymous hash and returns a reference to it. A single reference is not a list of key-value pairs, so the following makes no sense:

my %hash = { ... };   # XXX

If you did want to store a reference to a hash, you'd store it in a scalar.

my $hash = { ... };   # ok

---

So what does the following do, then?

my $hash = ( a => 'b', c => 'd' );

Well,

a => 'b', c => 'd'

is just a fancy way of writing

'a', 'b', 'c', 'd'

And since we're assigning to a scalar, the right-hand side of the assignment operator is evaluated in scalar context. A list literal (eg 'a', 'b', 'c', 'd' ) in scalar context evaluates in its last item, so

my $hash = ( a => 'b', c => 'd' );

means

my $hash = 'd';