使用数组引用存储数据

Question

I have a file looks like this

ConfigFile

run Test3
run Test1

TestDir File

{

home/usera/aa/TestFile1
home/usera/aa/TestFile2

}

TestFile1

Test 1
{
  Command1 Value
  Command2 Value
}

Test2
{
  Command4 Value
  Command1 Value
  Sleep    4
  Command5 Value
}

TestFile2

Test 3
{
  Command3 Value
  Sleep    4
}

Test8
{
 Command9  Value
  Command10 Value
  Sleep     2 
}

what I want to do is open each TestFile and read it and just store the data within the {..} in a Test hash having key as Testname(ie.Test1,Test3) and value for the key would be the command value pair withing the test

Can anyone help me out.Thanks

Answer 1

I wonder if your data file format has been decided arbitrarily? It is a dreadful design, and you should stick with it only if you are constrained to using it, say by a third party. If you have a choice then there are many established data file formats and you should simply adopt one of those. JSON is deservedly popular at the moment and there are excellent Perl modules to handle it available from CPAN.

If you decide to stick with your original design then this program will do what you ask.

use strict;
use warnings;
use autodie;

my (%tests, $commands, $test);

for my $file (qw/ testfile1.txt testfile2.txt /) {
  open my $fh, '<', $file;
  while (<$fh>) {
    s/\s+\z//;
    if (/\{/) {
      $commands = [];
    }
    elsif (/\}/) {
      $tests{$test} = $commands if $test and @$commands;
      $commands = undef;
    }
    elsif ($commands) {
      push @$commands, [ split ' ', $_, 2 ] if /\S/;
    }
    else {
      $test = $1 if /(\S(?:.*\S)?)/;
    }
  }
}

use Data::Dump;
dd \%tests;

output

{
  "Test 1" => [["Command1", "Value"], ["Command2", "Value"]],
  "Test 3" => [["Command3", "Value"], ["Sleep", 4]],
  "Test2"  => [
                ["Command4", "Value"],
                ["Command1", "Value"],
                ["Sleep", 4],
                ["Command5", "Value"],
              ],
  "Test8"  => [["Command9", "Value"], ["Command10", "Value"], ["Sleep", 2]],
}

Answer 2

You could write your own parser, but you're not likely to have a good time. If you convert your data files to JSON or YAML , then you'll be able to read your files into memory without much hassle.