VBA运行时错误1004 Object_Global的范围失败

Question

I am unsure what is wrong with my code. I thought that I set the range correctly but maybe not. I did try to set multiple ranges. The error is on the last main row of code "Range("CL_Paid").Paste"

 Sub test()

 Dim HR_Paid, HR_Unpaid, E_Paid, E_Unpaid, SE_Paid, SE_Unpaid, CL_Paid, CL_Unpaid As Range
 Set HR_Paid = Sheets("Data").Range("A1:L49")
 Set HR_Unpaid = Sheets("Data").Range("A50:L99")
 Set E_Paid = Sheets("Data").Range("A100:L149")
 Set E_Unpaid = Sheets("Data").Range("A150:L199")
 Set SE_Paid = Sheets("Data").Range("A200:L249")
 Set SE_Unpaid = Sheets("Data").Range("A250:L299")
 Set CL_Paid = Sheets("Data").Range("A300:L349")
 Set CL_Unpaid = Sheets("Data").Range("A350:L399")




   With Sheets("Data")
      .Select
     ViewMode = ActiveWindow.View
     ActiveWindow.View = xlNormalView
     .DisplayPageBreaks = False
     Firstrow = .UsedRange.Cells(1).Row
     Lastrow = .UsedRange.Rows(.UsedRange.Rows.Count).Row
     For Lrow = Lastrow To Firstrow Step -1
          With .Cells(Lrow, "D")

              If Not IsError(.Value) Then

                  If .Value = ("CL") Then .EntireRow.Cut
                      Range("CL_Paid").Paste


             End If

        End With

    Next Lrow
  End With


 End Sub

Answer 1

Did you intentionally use the one-line version of the If...Then statement?

The indentation of the line below the If looks as though you think it relates to the If in some way. You have this:

If .Value = ("CL") Then .EntireRow.Cut
    Range("CL_Paid").Paste

which has the same effect as this:

If .Value = ("CL") Then
    .EntireRow.Cut
End If

Range("CL_Paid").Paste

when I suspect that you really want this:

If .Value = ("CL") Then
    .EntireRow.Cut
    CL_Paid.Paste
End If

You are therefore trying to Paste regardless of whether or not the Cut ever happened.

Details on the different versions of the If...Then statement are here

Answer 2

CLPaid is already a Range so use Cl_Paid.Paste . However, Paste applies to a Worksheet , not a Range , so you might consider PasteSpecial . Alternatively,

.EntireRow.Cut CL_Paid

will Cut and Paste (to a Destination) in one step, without using the clipboard.

Note also that

Dim HR_Paid, HR_Unpaid, E_Paid, etc As Range

does not (in VBA) define all these are Range references. They are all Variant 's except for the last one. You would have to use:

Dim HR_Paid As Range, HR_Unpaid As Range, E_Paid As Range, etc