在Haskell中创建字符串列表

Question

I am making the pilgrimage from Java to Haskell. Broadly speaking, I get the main concepts behind Haskell. Reading all the tutorials and books 'makes sense' but I am getting stuck writing my own code from scratch.

I want to create 1000 files on the file system with names

"myfile_1.txt" ... "myfile_1000.txt"

and each containing some dummy text.

so far I have worked out the whole IO thing, and realise I need to build a list of Strings 1000 elements long. So I have:

buildNamesList :: [] -> []
buildNamesList ???

Once I have the List I can call the writefile method on each element. What I can't figure out is how to add a number to the end of a String to get each fileName because I can't have an int i = 0, i ++ construct in Haskell.

I am a bit out of my depth here, would appreciate some guidance, thanks

Answer 1

One possible solution:

buildNamesList = map buildName [1..1000]
  where buildName n = "myfile_" ++ show n ++ ".txt"

Answer 2

import Control.Applicative

fileNames = ("myFile_"++) <$> (++".txt")  <$> show <$> [1..1000]

Answer 3

how do I then traverse over it, pluck out the String at element n and then pass it into another function?

No! "Plucking out" something from a list in inefficient. You don't want to worry about how to get to each element, then do something with it. That's necessary in imperative languages because they don't have a proper abstraction over what "sequencing actions" means – it's just something magical built into the language. Haskell has much more well-specified, mathematically sound and type-safe magic for that ; as a result you don't need loops and suchlike.

You know what to do with each element ( String -> IO () ), and you know where the data comes from ( [String] ). You also know what should eventually happen ( IO () ). So the combinator you're looking for has type ( String -> IO() ) -> [String] -> IO () , though obviously it doesn't really depend on the data being Strings, so let's simplify that to (a -> IO()) -> [a] -> IO() . You can look that up on Hoogle , which offers amongst sume rubbish mapM_ and forM_ , both of which do what you want:

mapM_ (\filename -> writeFile filename "bla") filenamesList

or

forM_ filenamesList $ \filename ->
   writeFile filename "bla"

Answer 4

Sometimes I think of foldr as bearing some resemblance to a for loop. Here's something kind of like the i++ construct, applying i inside a loop:

foldr (\i accum -> ("myfile_" ++ show i ++ ".txt") : accum) [] [1..1000]

Another way could be zipWith , which applies a function to combine two lists:

zipWith (\a b -> a ++ show b ++ ".txt") (repeat "myfile_") [1..1000] 

or

zipWith ($) (repeat (("myfile_" ++) . (++ ".txt") . show)) [1..1000]

And here's a recursive example, too, applied as fileList "myfile_" ".txt" [1..1000] :

fileList _     _   []     = [] 
fileList fName ext (x:xs) = (fName ++ show x ++ ext) : fileList fName ext xs